ODAS_AtmAbsorption.f90

Go to the documentation of this file.

!
! ODAS_AtmAbsorption
!
! Module containing routines to compute the optical depth profile
! due to gaseous absorption for the Optical Depth Absorber Space (ODAS)
! model.
!
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 13-May-2004
!                       paul.vandelst@noaa.gov
!
!       Modifed by:     Yong Han, 25-June-2008
!                       yong.han@noaa.gov
!

MODULE odas_atmabsorption

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds,                ONLY: fp
  USE message_handler,           ONLY: success, failure, warning, display_message
  USE crtm_parameters,           ONLY: zero,         &
                                       max_n_layers, &
                                       limit_exp,    &
                                       limit_log
  USE crtm_atmosphere_define,    ONLY: crtm_atmosphere_type
  USE crtm_geometryinfo_define,  ONLY: crtm_geometryinfo_type
  USE crtm_atmoptics_define,     ONLY: crtm_atmoptics_type
  USE odas_predictor_define,     ONLY: odas_predictor_type
  USE odas_predictor,            ONLY: max_n_absorbers,       &
                                       max_n_orders,          &
                                       max_n_predictors_used, &
                                       max_n_orders
  USE odas_taucoeff,             ONLY: tc, &
                                       odas_taucoeff_type

  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Science routines in this modules
  PUBLIC :: odas_compute_atmabsorption
  PUBLIC :: odas_compute_atmabsorption_tl
  PUBLIC :: odas_compute_atmabsorption_ad
  ! Internal variable structure
  PUBLIC :: ivar_type

  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: ODAS_AtmAbsorption.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'


  ! ------------------------------------------
  ! Structure definition to hold forward model
  ! variables across FWD, TL, and AD calls
  ! ------------------------------------------
  TYPE :: ivar_type
    PRIVATE
    REAL(fp), DIMENSION(MAX_N_LAYERS, &
                        0:MAX_N_PREDICTORS_USED, &
                        MAX_N_ABSORBERS)              :: b
    REAL(fp), DIMENSION(MAX_N_LAYERS,MAX_N_ABSORBERS) :: ln_chi
    REAL(fp), DIMENSION(MAX_N_LAYERS,MAX_N_ABSORBERS) :: chi
  END TYPE ivar_type

CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                         ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################

!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODAS_Compute_AtmAbsorption
!
! PURPOSE:
!       Subroutine to calculate the layer optical depths due to gaseous
!       absorption for a given sensor and channel and atmospheric profile
!       using the Optical Depth in Absorber Space (ODAS) algorithm).
!
! CALLING SEQUENCE:
!       CALL ODAS_Compute_AtmAbsorption( TC          , &
!                                        ChannelIndex, &
!                                        Predictor   , &
!                                        AtmOptics   , &
!                                        iVar   )
!
! INPUTS:
!       TC:              Structure containing ODAS model coefficient data
!                        for a sensor.
!                        UNITS:      N/A
!                        TYPE:       ODAS_TauCoeff_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor:       Structure containing the ODAS model integrated
!                        absorber and predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       AtmOptics:       Structure containing computed optical depth
!                        profile data.
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! COMMENTS:
!       Note the INTENT on the output structure arguments are IN OUT to prevent
!       reinitialisation upon entry.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE odas_compute_atmabsorption( &
    TC          , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! Input
    AtmOptics   , &  ! Output
    iVar          )  ! Internal variable output
    ! Arguments
    TYPE(odas_taucoeff_type) , INTENT(IN)     :: tc
    INTEGER                  , INTENT(IN)     :: channelindex
    TYPE(odas_predictor_type), INTENT(IN)     :: predictor
    TYPE(crtm_atmoptics_type), INTENT(IN OUT) :: atmoptics
    TYPE(ivar_type)          , INTENT(IN OUT) :: ivar
    ! Local variables
    INTEGER  :: l        ! Channel index
    INTEGER  :: k        ! Layer index
    INTEGER  :: j        ! Absorber index
    INTEGER  :: i, ip    ! Predictor index
    INTEGER  :: np       ! # of predictors
    INTEGER  :: ps       ! starting position of the coefficient subset for given j and l
    INTEGER  :: n_orders ! order of the polynomial function
    INTEGER  :: ic_0     ! the index of the first coefficient in the C coeff subset for deriving the B coeff.
    INTEGER  :: ic       ! the index of the coefficients
    REAL(fp) :: c        ! a coefficient
    INTEGER  :: n_layers


    ! Set up
    ! ...Assign the indices to a short name
    l = channelindex
    n_layers = predictor%n_Layers
    ! ...Initilise the optical depth
    atmoptics%Optical_Depth = zero  !! *** DOES THIS MAKE ROUTINE ORDER DEPENDENT? ***


    ! Loop over each absorber for optical depth calculation
    absorber_loop: DO j = 1, predictor%n_Absorbers


      ! Check if there is any absorption for this
      ! absorber/channel combination.
      np = tc%Pre_Index(0,j,l)
      IF ( np < 0 ) cycle absorber_loop


      ! Compute the coefficients for use with the atmospheric predictors
      !
      ! For every atmospheric predictor, Pred(i), the coefficient
      ! associated with it, b(i), at a particular absorber amount
      ! level, k, is given by an N'th order polynomial,
      !
      !           __ N
      !          \           np
      !   b(i) =  > c(np,i).k
      !          /__
      !             np=0
      !
      ps = tc%Pos_Index(j,l)  ! starting position of the coefficient subset for given j and l
      n_orders = tc%Order(j,l)
      ! ...Compute b(0)
      ic_0 = ps
      ivar%b(1:n_layers,0,j) = tc%C(ic_0)
      DO ic = 1, n_orders
        c = tc%C(ic_0 + ic)
        DO k = 1, n_layers
          ivar%b(k,0,j) = ivar%b(k,0,j) + (c * predictor%Ap(k, ic, j))
        END DO
      END DO


      ! compute b(i) coefficients (i > 0)
      ! Compute the logarithm of the absorption coefficient
      !
      ! The logarithm of the absorption coefficient, LN(chi), is
      ! determined from the regression equation,
      !
      !                     __Iuse
      !                    \
      !   LN(chi) = b(0) +  > b(i).X(i)
      !                    /__
      !                       i=1
      !
      ! ...The b(0) contribution
      ivar%LN_Chi(1:n_layers, j) = ivar%b(1:n_layers,0,j)
      DO i = 1, np
        ! ...b(i) term, i > 0
        ic_0 = ps + i*(n_orders+1)
        ivar%b(1:n_layers,i,j) = tc%C(ic_0)
        DO ic = 1, n_orders
          c = tc%C(ic_0 + ic)
          DO k = 1, n_layers
            ivar%b(k,i,j) = ivar%b(k,i,j) + (c * predictor%Ap(k, ic, j))
          END DO
        END DO
        ! ...b(i) term contribution
        ip = tc%Pre_Index(i,j,l)
        DO k = 1, n_layers
          ivar%LN_Chi(k,j) = ivar%LN_Chi(k,j) + (ivar%b(k, i, j) * predictor%X(k,ip))
        END DO
      END DO


      ! Compute the optical depth profile
      DO k = 1, n_layers
        ! ...Compute the absorption coefficient
        IF( ivar%LN_Chi(k,j) > limit_exp ) THEN
          ivar%Chi(k,j) = limit_log
        ELSE IF( ivar%LN_Chi(k,j) < -limit_exp ) THEN
          ivar%Chi(k,j) = zero
        ELSE
          ivar%Chi(k,j) = exp(ivar%LN_Chi(k,j))
        ENDIF

        atmoptics%Optical_Depth(k) = atmoptics%Optical_Depth(k) + (ivar%Chi(k,j) * predictor%dA(k,j))
      END DO

    END DO absorber_loop


    ! Scale the optical depth to nadir
    atmoptics%Optical_Depth = atmoptics%Optical_Depth / predictor%Secant_Sensor_Zenith

  END SUBROUTINE odas_compute_atmabsorption


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODAS_Compute_AtmAbsorption_TL
!
! PURPOSE:
!       Subroutine to calculate the tangent-linear layer optical depths due
!       to gaseous absorption for a given sensor and channel and atmospheric
!       profile using the Optical Depth in Absorber Space (ODAS) algorithm).
!
! CALLING SEQUENCE:
!       CALL ODAS_Compute_AtmAbsorption_TL( TC          , &
!                                           ChannelIndex, &
!                                           Predictor   , &
!                                           Predictor_TL, &
!                                           AtmOptics_TL, &
!                                           iVar   )
!
! INPUTS:
!       TC:              Structure containing ODAS model coefficient data
!                        for a sensor.
!                        UNITS:      N/A
!                        TYPE:       ODAS_TauCoeff_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor:       Structure containing the ODAS model integrated
!                        absorber and predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor_TL:    Structure containing the ODAS model tangent-linear
!                        integrated absorber and predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!        AtmOptics_TL:   Structure containing the computed tangent-linear
!                        optical depth profile data.
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       Note the INTENT on the output structure arguments are IN OUT to prevent
!       reinitialisation upon entry.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE odas_compute_atmabsorption_tl( &
    TC          , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! FWD Input
    Predictor_TL, &  ! TL  Input
    AtmOptics_TL, &  ! TL  Output
    iVar          )  ! Internal variable input
    ! Arguments
    TYPE(odas_taucoeff_type) , INTENT(IN)     :: tc
    INTEGER                  , INTENT(IN)     :: channelindex
    TYPE(odas_predictor_type), INTENT(IN)     :: predictor
    TYPE(odas_predictor_type), INTENT(IN)     :: predictor_tl
    TYPE(crtm_atmoptics_type), INTENT(IN OUT) :: atmoptics_tl
    TYPE(ivar_type)          , INTENT(IN)     :: ivar
    ! Local variables
    INTEGER  :: l        ! Channel index
    INTEGER  :: k        ! Layer index
    INTEGER  :: j        ! Absorber index
    INTEGER  :: i, ip    ! Predictor index
    INTEGER  :: np       ! # of predictors
    INTEGER  :: ps       ! starting position of the coefficient subset for given j and l
    INTEGER  :: n_orders ! order of the polynomial function
    INTEGER  :: ic_0     ! the index of the first coefficient in the b coeff subset for deriving the b coeff.
    INTEGER  :: ic       ! the index of the coefficients
    REAL(fp) :: c        ! a coefficient
    REAL(fp) :: b_tl(predictor%n_layers)
    REAL(fp) :: ln_chi_tl(predictor%n_layers)
    REAL(fp) :: chi_tl
    INTEGER  :: n_layers

    ! Set up
    ! ...Assign the indices to a short name
    l = channelindex
    n_layers = predictor%n_Layers
    ! ...Initilise the tangent-linear optical depth
    atmoptics_tl%Optical_Depth = zero


    ! Loop over each absorber for optical depth calculation
    absorber_loop: DO j = 1, predictor%n_Absorbers


      ! Check if there is any absorption for this
      ! absorber/channel combination.
      np = tc%Pre_Index(0,j,l)
      IF ( np < 0 ) cycle absorber_loop


      ! Compute the coefficients for use with the atmospheric predictors
      !
      ! For every atmospheric predictor, Pred(i), the coefficient
      ! associated with it, b(i), at a particular absorber amount
      ! level, k, is given by an N'th order polynomial,
      !
      !           __ N
      !          \          np
      !   b(i) =  > c(np,i).k
      !          /__
      !             np=0
      !
      ps = tc%Pos_Index(j,l)  ! starting position of the coefficient subset f  or given j and l
      n_orders = tc%Order(j,l)
      ! ...Compute b_TL(0)
      ic_0 = ps
      b_tl(1:n_layers) = zero
      DO ic = 1, n_orders
        c = tc%C(ic_0 + ic)
        DO k = 1, n_layers
          b_tl(k) = b_tl(k) + (c * predictor_tl%Ap(k, ic, j))
        END DO
      END DO


      ! Compute the logarithm of the absorption coefficient
      !
      ! The logarithm of the absorption coefficient, LN(chi), is
      ! determined from the regression equation,
      !
      !                     __Iuse
      !                    \
      !   LN(chi) = b(0) +  > b(i).X(i)
      !                    /__
      !                       i=1
      !
      ! ...b_TL(0) term contribution
      ln_chi_tl(1:n_layers) = b_tl(1:n_layers)
      DO i = 1, np
        ! ...b_TL(i) term, i > 0
        ic_0 = ps + i*(n_orders+1)
        b_tl(1:n_layers) = zero
        DO ic = 1, n_orders
          c = tc%C(ic_0 + ic)
          DO k = 1, n_layers
            b_tl(k) = b_tl(k) + (c * predictor_tl%Ap(k, ic, j))
          END DO
        END DO
        ! b_TL(i) term contribution
        ip = tc%Pre_Index(i,j,l)
        DO k = 1, n_layers
          ln_chi_tl(k) = ln_chi_tl(k) + (b_tl(k) * predictor%X(k,ip)) &
                                      + (ivar%b(k,i,j) * predictor_tl%X(k,ip))
        END DO
      END DO


      ! Compute the tangent-linear optical depth profile
      DO k = 1, n_layers
        ! ...Compute the tangent-linear absorption coefficient
        IF( ivar%LN_Chi(k,j) > limit_exp ) THEN
          chi_tl = zero
        ELSE IF( ivar%LN_Chi(k,j) < -limit_exp ) THEN
          chi_tl = zero
        ELSE
          chi_tl = ivar%Chi(k,j) * ln_chi_tl(k)
        ENDIF

        atmoptics_tl%Optical_Depth(k) = atmoptics_tl%Optical_Depth(k) &
                                          + (chi_tl * predictor%dA(k,j)) &
                                          + (ivar%Chi(k,j) * predictor_tl%dA(k,j))
      END DO

    END DO absorber_loop


    ! Scale the tangent-linear optical depth to nadir
    atmoptics_tl%Optical_Depth = atmoptics_tl%Optical_Depth / &
                                 predictor%Secant_Sensor_Zenith

  END SUBROUTINE odas_compute_atmabsorption_tl


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODAS_Compute_AtmAbsorption_AD
!
! PURPOSE:
!       Subroutine to calculate the adjoint of the layer optical depths due
!       to gaseous absorption for a given sensor and channel and atmospheric
!       profile using the Optical Depth in Absorber Space (ODAS) algorithm).
!
! CALLING SEQUENCE:
!       CALL ODAS_Compute_AtmAbsorption_AD( TC          , &
!                                           ChannelIndex, &
!                                           Predictor   , &
!                                           AtmOptics_AD, &
!                                           Predictor_AD, &
!                                           iVar   )
!
! INPUTS:
!       TC:              Structure containing ODAS model coefficient data
!                        for a sensor.
!                        UNITS:      N/A
!                        TYPE:       ODAS_TauCoeff_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor:       Structure containing the ODAS model integrated
!                        absorber and predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       AtmOptics_AD:    Structure containing the adjoint optical depth
!                        profile data.
!                        *** NOTE: Optical depth component set to zero on output. ***
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Predictor_AD:    Structure containing the ODAS model adjoint
!                        integrated absorber and predictor profile data.
!                        *** NOTE: Must contain a value upon input. ***
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! SIDE EFFECTS:
!       Components of the AtmOptics_AD structure argument are modified
!       in this function.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE odas_compute_atmabsorption_ad( &
    TC          , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! FWD Input
    AtmOptics_AD, &  ! AD  Input
    Predictor_AD, &  ! AD  Output
    iVar          )  ! Internal variable input
    ! Arguments
    TYPE(odas_taucoeff_type) , INTENT(IN)     :: tc
    INTEGER                  , INTENT(IN)     :: channelindex
    TYPE(odas_predictor_type), INTENT(IN)     :: predictor
    TYPE(crtm_atmoptics_type), INTENT(IN OUT) :: atmoptics_ad
    TYPE(odas_predictor_type), INTENT(IN OUT) :: predictor_ad
    TYPE(ivar_type)          , INTENT(IN)     :: ivar
    ! Local variables
    INTEGER  :: l        ! Channel index
    INTEGER  :: k        ! Layer index
    INTEGER  :: j        ! Absorber index
    INTEGER  :: i, ip    ! Predictor index
    INTEGER  :: np       ! # of predictors
    INTEGER  :: ps       ! starting position of the coefficient subset for given j and l
    INTEGER  :: n_orders ! order of the polynomial function
    INTEGER  :: ic_0     ! the index of the first coefficient in the b coeff subset for deriving the b coeff.
    INTEGER  :: ic       ! the index of the coefficients
    REAL(fp) :: c        ! a coefficient
    REAL(fp) :: b_ad(predictor%n_layers)
    REAL(fp) :: ln_chi_ad(predictor%n_layers)
    REAL(fp) :: chi_ad
    INTEGER  :: n_layers


    ! Set up
    ! ...Assign the indices to a short name
    l = channelindex
    n_layers = predictor%n_Layers
    ! ...Initialise local adjoint variables
    b_ad      = zero
    ln_chi_ad = zero
    chi_ad    = zero


    ! Compute adjoint nadir optical depth profile
    atmoptics_ad%Optical_Depth = atmoptics_ad%Optical_Depth / &
                                  predictor%Secant_Sensor_Zenith


    ! Loop over each absorber for optical depth calculation
    absorber_loop: DO j = 1, predictor%n_Absorbers


      ! Check if there is any absorption for this
      ! absorber/channel combination.
      np = tc%Pre_Index(0,j,l)
      IF ( np < 0 ) cycle absorber_loop

      ! Starting position of the coefficient subset for given absorber (j) and channels(l)
      ps = tc%Pos_Index(j,l)
      n_orders = tc%Order(j,l)


      ! Compute the adjoint of the optical depth profile
      DO k = n_layers, 1, -1
        predictor_ad%dA(k,j) = predictor_ad%dA(k,j) + &
                               (ivar%Chi(k,j) * atmoptics_ad%Optical_Depth(k))
        chi_ad = chi_ad + (predictor%dA(k,j) * atmoptics_ad%Optical_Depth(k))


        ! ...Compute the adjoint of the absorption coefficient
        IF( ivar%LN_Chi(k,j) > limit_exp ) THEN
          chi_ad = zero
        ELSE IF( ivar%LN_Chi(k,j) < -limit_exp ) THEN
          chi_ad = zero
        ELSE
          ln_chi_ad(k) = ln_chi_ad(k) + ivar%Chi(k,j) * chi_ad
          chi_ad       = zero
        ENDIF
      END DO


      ! Compute the adjoint of the logarithm of the absorption coefficient
      DO i = np, 1, -1
        ! ...b(i) term contribution
        ip = tc%Pre_Index(i,j,l)
        DO k = n_layers, 1, -1
          b_ad(k) = b_ad(k) + (ln_chi_ad(k) * predictor%X(k,ip))
          predictor_ad%X(k,ip) = predictor_ad%X(k,ip) + (ivar%b(k,i,j) * ln_chi_ad(k))
        END DO
        ! ...b(i) term, i > 0
        ic_0 = ps + i*(n_orders+1)
        DO ic = n_orders, 1, -1
          c = tc%C(ic_0 + ic)
          DO k = n_layers, 1, -1
            predictor_ad%Ap(k, ic, j) = predictor_ad%Ap(k, ic, j) + (c * b_ad(k))
          END DO
        END DO
        b_ad(1:n_layers) = zero
      END DO
      b_ad(1:n_layers) = b_ad(1:n_layers) + ln_chi_ad(1:n_layers)
      ln_chi_ad(1:n_layers) = zero


      ! Compute the adjoint of the b(i) coefficients
      ic_0 = ps
      DO ic = n_orders, 1, -1
        c = tc%C(ic_0 + ic)
        DO k = n_layers, 1, -1
          predictor_ad%Ap(k, ic, j) = predictor_ad%Ap(k, ic, j) + (c * b_ad(k))
        END DO
      END DO
      b_ad(1:n_layers) = zero

    END DO absorber_loop


    ! No more impact of optical depth on derivatives
    atmoptics_ad%Optical_Depth = zero

  END SUBROUTINE odas_compute_atmabsorption_ad

END MODULE odas_atmabsorption