doxygen-example/_o_d_a_s___predictor_8f90_source.html

 !
 ! ODAS_Predictor
 !
 ! Module continaing routines to compute the predictors for the
 ! Optical Depth in Absorber Space (ODAS) .
 !
 !
 ! CREATION HISTORY:
 !       Written by:     Paul van Delst, 29-Aug-2006
 !                       paul.vandelst@noaa.gov
 !
 !       Modified by:    Yong Han, 25-June-2008
 !                       yong.han@noaa.gov
 !

 MODULE odas_predictor

   ! -----------------
   ! Environment setup
   ! -----------------
   ! Module use
   USE type_kinds              , ONLY: fp
   USE message_handler         , ONLY: success, failure, display_message
   USE crtm_parameters         , ONLY: zero                       , &
                                       point_25, point_5, point_75, &
                                       one, two, three, ten       , &
                                       minimum_absorber_amount    , &
                                       toa_pressure               , &
                                       reciprocal_gravity         , &
                                       max_n_layers
   USE crtm_atmosphere_define  , ONLY: crtm_atmosphere_type, &
                                       crtm_get_absorberidx, &
                                       h2o_id, o3_id
   USE crtm_geometryinfo_define, ONLY: crtm_geometryinfo_type, &
                                       crtm_geometryinfo_getvalue
   USE odas_predictor_define   , ONLY: odas_predictor_type      , &
                                       odas_predictor_associated, &
                                       odas_predictor_destroy   , &
                                       odas_predictor_create    , &
                                       odas_predictor_zero
   ! Disable implicit typing
   IMPLICIT NONE

   ! ------------
   ! Visibilities
   ! ------------
   ! Everything private by default
   PRIVATE
   ! Datatypes
   PUBLIC :: ivar_type
   ! Procedures
   PUBLIC :: odas_assemble_predictors
   PUBLIC :: odas_assemble_predictors_tl
   PUBLIC :: odas_assemble_predictors_ad
   ! Parameters
   PUBLIC :: max_n_absorbers
   PUBLIC :: wet_absorber_index
   PUBLIC :: dry_absorber_index
   PUBLIC :: ozo_absorber_index
   PUBLIC :: absorber_index
   PUBLIC :: absorber_name
   PUBLIC :: max_n_standard_predictors
   PUBLIC :: max_n_integrated_predictors
   PUBLIC :: max_n_predictors
   PUBLIC :: max_n_predictors_used
   PUBLIC :: max_n_orders


   ! -----------------
   ! Module parameters
   ! -----------------
   CHARACTER(*), PARAMETER :: module_version_id = &
   '$Id: ODAS_Predictor.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'


   ! Absorbers in the gas absorption model
   ! -------------------------------------
   ! The total number
   INTEGER, PARAMETER :: max_n_absorbers = 3
   ! The indexing order of the absorbers
   INTEGER, PARAMETER :: wet_absorber_index = 1
   INTEGER, PARAMETER :: dry_absorber_index = 2
   INTEGER, PARAMETER :: ozo_absorber_index = 3
   ! The absorber index and name arrays
   INTEGER, PARAMETER :: absorber_index(max_n_absorbers) = &
     (/ wet_absorber_index, &
        dry_absorber_index, &
        ozo_absorber_index /)
   CHARACTER(*), PARAMETER :: absorber_name(max_n_absorbers) = &
     (/ 'wet', &
        'dry', &
        'ozo' /)


   ! Predictors in the gas absorption model
   ! --------------------------------------
   ! Standard predictors are absorber independent
   INTEGER, PARAMETER :: max_n_standard_predictors   = 11
   ! Integrated predictors are defined for EACH absoreber
   INTEGER, PARAMETER :: max_n_integrated_predictors = 6
   ! The total number of predictors
   INTEGER, PARAMETER :: max_n_predictors = max_n_standard_predictors + &
                                            ( max_n_absorbers * max_n_integrated_predictors )
   ! The number selected from the total to be
   ! used in the gas absorption algorithm
   INTEGER, PARAMETER :: max_n_predictors_used = 6
   ! Maximum number of polynomial orders for
   ! reconstructing the gas absorption coefficients
   INTEGER, PARAMETER :: max_n_orders = 10


   ! ------------------------------------------
   ! Structure definition to hold forward model
   ! variables across FWD, TL, and AD calls
   ! ------------------------------------------
   TYPE :: ivar_type
     PRIVATE
     REAL(fp), DIMENSION(0:MAX_N_LAYERS,MAX_N_ABSORBERS) :: a_2 = zero
     REAL(fp), DIMENSION(MAX_N_LAYERS,MAX_N_ABSORBERS) :: factor_1 = zero
     REAL(fp), DIMENSION(MAX_N_LAYERS,MAX_N_ABSORBERS) :: factor_2 = zero
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS,0:MAX_N_LAYERS,MAX_N_ABSORBERS) :: s ! no need to initialized it to zero
     REAL(fp), DIMENSION(MAX_N_LAYERS,MAX_N_ABSORBERS) :: a_level ! no need to initialized it to zero
   END TYPE ivar_type


 CONTAINS


 !################################################################################
 !################################################################################
 !##                                                                            ##
 !##                        ## PUBLIC MODULE ROUTINES ##                        ##
 !##                                                                            ##
 !################################################################################
 !################################################################################

 !--------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       ODAS_Assemble_Predictors
 !
 ! PURPOSE:
 !       Subroutine to assemble all the gas absorption model predictors
 !       for the ODAS algorithm.
 !
 ! CALLING SEQUENCE:
 !       CALL ODAS_Assemble_Predictors( &
 !              Atmosphere  , &
 !              GeometryInfo, &
 !              Max_Order   , &
 !              Alpha       , &
 !              Predictor   , &
 !              iVar          )
 !
 ! INPUTS:
 !       Atmosphere:
 !         Structure containing the atmospheric state data.
 !         UNITS:      N/A
 !         TYPE:       CRTM_Atmosphere_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       GeometryInfo:
 !         Structure containing the view geometry information.
 !         UNITS:      N/A
 !         TYPE:       CRTM_GeometryInfo_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Max_Order:
 !         The maximum order of the polynomial function for each absorber
 !         UNITS:      N/A
 !         TYPE:       INTEGER
 !         DIMENSION:  1D array (n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Alpha:
 !         The alpha coefficients for absorber level calculations
 !         UNITS:      depends on the units of the absorber
 !         TYPE:       INTEGER
 !         DIMENSION:  2D array (n_Alphas x n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUTS:
 !       Predictor:
 !         Structure containing the integrated absorber and predictor profiles.
 !         UNITS:      N/A
 !         TYPE:       ODAS_Predictor_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN OUT)
 !
 !       iVar:
 !         Structure containing internal variables required for subsequent
 !         tangent-linear or adjoint model calls. The contents of this
 !         structure are NOT accessible outside of this module.
 !         UNITS:      N/A
 !         TYPE:       iVar_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(OUT)
 !
 ! COMMENTS:
 !       The predictors used in the gas absorption model are organised in
 !       the following manner:
 !
 ! ------------------------------------------------------------------------------
 ! | 1 | 2 | 3 | ... | 9 | 10 | 11 | 12 |....| 17 | 18 |....| 23 | 24 |....| 29 |
 ! ------------------------------------------------------------------------------
 !
 ! \                              /\             /\             /\             /
 !  \                            /  \           /  \           /  \           /
 !   ----------------------------    -----------    -----------    -----------
 !                 |                      |              |              |
 !                 v                      v              v              v
 !
 !             Standard               Integrated     Integrated     Integrated
 !            Predictors              predictors     predictors     predictors
 !                                       for            for            for
 !                                    Absorber 1     Absorber 2     Absorber 3
 !                                   (water vapor)   (dry gases)     (ozone)
 !
 !:sdoc-:
 !--------------------------------------------------------------------------------

   SUBROUTINE odas_assemble_predictors( &
     Atmosphere  , &  ! Input
     GeometryInfo, &  ! Input
     Max_Order   , &  ! Input
     Alpha       , &  ! Input
     Predictor   , &  ! Output
     iVar          )  ! Internal variable output
     ! Arguments
     TYPE(crtm_atmosphere_type),   INTENT(IN)     :: atmosphere
     TYPE(crtm_geometryinfo_type), INTENT(IN)     :: geometryinfo
     INTEGER,                      INTENT(IN)     :: max_order(:)
     REAL(fp),                     INTENT(IN)     :: alpha(:,:)
     TYPE(odas_predictor_type),    INTENT(IN OUT) :: predictor
     TYPE(ivar_type),              INTENT(OUT)    :: ivar
     ! Local variables
     INTEGER :: i,j,k,n_layers
     REAL(fp) :: secant_sensor_zenith

     ! Save the angle information
     CALL crtm_geometryinfo_getvalue( geometryinfo, &
                                      secant_trans_zenith = secant_sensor_zenith )
     predictor%Secant_Sensor_Zenith = secant_sensor_zenith

     ! Compute the nadir integrated absorber profiles
     CALL compute_intabsorber( atmosphere, predictor )

     ! Compute the predictors
     ! ...Standard predictors
     CALL standard_predictors( atmosphere, predictor )
     ! ...Integrated predictors
     CALL integrated_predictors( atmosphere, predictor, ivar )


     ! Calculate absorber space level associated with the average
     ! absorber amount
     !
     ! Absorber level, k, to amount
     !
     !     A(k) = C1.exp(Alpha * k) + C2
     !
     ! Absorber amount to level
     !
     !           1      A - C2
     !     k = ----- LN ------
     !         Alpha      C1
     !
     !     AP(k, i) = A(k)**(i), i = 1, Max_Order(j)
     !
     !   Alpha : absorber amount-level coordinate constant
     !   C1,C2 : scaling factors for level in the range of 0 to 1
     n_layers = atmosphere%n_Layers
     DO j = 1, predictor%n_Absorbers

       IF( max_order(j) < 0 )cycle

       DO k = 1, n_layers
         ivar%A_Level(k,j) = log((predictor%aveA(k,j) - alpha(3,j)) / alpha(2,j)) / &
         !                   ----------------------------------------------------
                                                 alpha(1,j)
       END DO

       predictor%Ap(1:n_layers, 1, j) = ivar%A_Level(1:n_layers,j)
       DO i = 2, max_order(j)
         DO k = 1, n_layers
           predictor%Ap(k, i, j) = predictor%Ap(k, i-1, j) * ivar%A_Level(k,j)
         END DO
       END DO
     END DO

   END SUBROUTINE odas_assemble_predictors


 !--------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       ODAS_Assemble_Predictors_TL
 !
 ! PURPOSE:
 !       Subroutine to assemble all the gas absorption model predictors
 !       for the tangent-linear ODAS algorithm.
 !
 ! CALLING SEQUENCE:
 !       CALL ODAS_Assemble_Predictors_TL ( &
 !              Atmosphere   , &  ! FWD Input
 !              Predictor    , &  ! FWD Input
 !              Atmosphere_TL, &  ! TL Input
 !              Max_Order    , &  ! Input
 !              Alpha        , &  ! Input
 !              Predictor_TL , &  ! TL Output
 !              iVar           )  ! Internal variable input
 !
 ! INPUTS:
 !       Atmosphere:
 !         Structure containing the atmospheric state data.
 !         UNITS:      N/A
 !         TYPE:       CRTM_Atmosphere_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Predictor:
 !         Structure containing the integrated absorber and predictor profiles.
 !         UNITS:      N/A
 !         TYPE:       ODAS_Predictor_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Atmosphere_TL:
 !         Structure containing the tanggent-linear atmospheric state data.
 !         UNITS:      N/A
 !         TYPE:       CRTM_Atmosphere_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       GeometryInfo:
 !         Structure containing the view geometry information.
 !         UNITS:      N/A
 !         TYPE:       CRTM_GeometryInfo_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Max_Order:
 !         The maximum order of the polynomial function for each absorber
 !         UNITS:      N/A
 !         TYPE:       INTEGER
 !         DIMENSION:  1D array (n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Alpha:
 !         The alpha coefficients for absorber level calculations
 !         UNITS:      depends on the units of the absorber
 !         TYPE:       INTEGER
 !         DIMENSION:  2D array (n_Alphas x n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 !       iVar:
 !         Structure containing internal variables required for subsequent
 !         tangent-linear or adjoint model calls. The contents of this
 !         structure are NOT accessible outside of this module.
 !         UNITS:      N/A
 !         TYPE:       iVar_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(OUT)
 !
 ! OUTPUTS:
 !       Predictor_TL:
 !         Structure containing the tangent-linear integrated absorber
 !         and predictor profiles.
 !         UNITS:      N/A
 !         TYPE:       ODAS_Predictor_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN OUT)
 !
 ! COMMENTS:
 !       The predictors used in the gas absorption model are organised in
 !       the following manner:
 !
 ! ------------------------------------------------------------------------------
 ! | 1 | 2 | 3 | ... | 9 | 10 | 11 | 12 |....| 17 | 18 |....| 23 | 24 |....| 29 |
 ! ------------------------------------------------------------------------------
 !
 ! \                              /\             /\             /\             /
 !  \                            /  \           /  \           /  \           /
 !   ----------------------------    -----------    -----------    -----------
 !                 |                      |              |              |
 !                 v                      v              v              v
 !
 !             Standard               Integrated     Integrated     Integrated
 !            Predictors              predictors     predictors     predictors
 !                                       for            for            for
 !                                    Absorber 1     Absorber 2     Absorber 3
 !                                   (water vapor)   (dry gases)     (ozone)
 !
 !:sdoc-:
 !--------------------------------------------------------------------------------

   SUBROUTINE odas_assemble_predictors_tl( &
     Atmosphere   , &  ! FWD Input
     Predictor    , &  ! FWD Input
     Atmosphere_TL, &  ! TL Input
     Max_Order    , &  ! Input
     Alpha        , &  ! Input
     Predictor_TL , &  ! TL Output
     iVar           )  ! Internal variable input
     ! Arguments
     TYPE(crtm_atmosphere_type), INTENT(IN)     :: atmosphere
     TYPE(odas_predictor_type),  INTENT(IN)     :: predictor
     TYPE(crtm_atmosphere_type), INTENT(IN)     :: atmosphere_tl
     INTEGER,                    INTENT(IN)     :: max_order(:)
     REAL(fp),                   INTENT(IN)     :: alpha(:,:)
     TYPE(odas_predictor_type),  INTENT(IN OUT) :: predictor_tl
     TYPE(ivar_type),            INTENT(IN)     :: ivar
     ! Local variables
     REAL(fp) :: a_level_tl(atmosphere%n_layers)
     INTEGER  :: i, j, k, n_layers

     ! Save the angle information
     predictor_tl%Secant_Sensor_Zenith = predictor%Secant_Sensor_Zenith

     ! Compute the tangent-linear nadir integrated absorber profiles
     CALL compute_intabsorber_tl( &
            atmosphere   , &  ! Input
            atmosphere_tl, &  ! Input
            predictor_tl   )  ! Output

     ! Compute the tangent-linear predictors
     ! ...Standard predictors
     CALL standard_predictors_tl( &
            atmosphere   , &  ! Input
            atmosphere_tl, &  ! Input
            predictor_tl   )  ! Output
     ! ...Integrated predictors
     CALL integrated_predictors_tl( &
            atmosphere   , &  ! Input
            predictor    , &  ! Input
            atmosphere_tl, &  ! Input
            predictor_tl , &  ! Output
            ivar           )  ! Internal variable input


     ! Calculate tangent-linear absorber space level associated
     ! with the average absorber amount
     n_layers = atmosphere%n_Layers
     DO j = 1, predictor%n_Absorbers

       IF( max_order(j) < 0 )cycle

       DO k = 1, n_layers

         a_level_tl(k) =             predictor_tl%aveA(k,j) / &
         !               -------------------------------------------------
                         (alpha(1,j) * (predictor%aveA(k,j) - alpha(3,j)))
       END DO

       predictor_tl%Ap(1:n_layers, 1, j) = a_level_tl(1:n_layers)
       DO i = 2, max_order(j)
         DO k = 1, n_layers
           predictor_tl%Ap(k, i, j) = (predictor_tl%Ap(k,i-1,j)*ivar%A_Level(k,j)) + &
                                      (predictor%Ap(k,i-1,j)   *a_level_tl(k))
         END DO
       END DO
     END DO

   END SUBROUTINE odas_assemble_predictors_tl


 !--------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       ODAS_Assemble_Predictors_AD
 !
 ! PURPOSE:
 !       Subroutine to assemble all the gas absorption model predictors
 !       for the adjoint ODAS algorithm.
 !
 ! CALLING SEQUENCE:
 !       CALL ODAS_Assemble_Predictors_AD ( &
 !              Atmosphere   , &  ! FWD Input
 !              Predictor    , &  ! FWD Input
 !              Predictor_AD , &  ! AD Input
 !              Max_Order    , &  ! Input
 !              Alpha        , &  ! Input
 !              Atmosphere_AD, &  ! AD Output
 !              iVar           )  ! Internal variable input
 !
 ! INPUTS:
 !       Atmosphere:
 !         Structure containing the atmospheric state data.
 !         UNITS:      N/A
 !         TYPE:       CRTM_Atmosphere_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Predictor:
 !         Structure containing the integrated absorber and predictor profiles.
 !         UNITS:      N/A
 !         TYPE:       ODAS_Predictor_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Predictor_AD:
 !         Structure containing the adjoint integrated absorber and
 !         predictor profiles.
 !         **NOTE: This structure is zeroed upon output
 !         UNITS:      N/A
 !         TYPE:       ODAS_Predictor_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN OUT)
 !
 !       Max_Order:
 !         The maximum order of the polynomial function for each absorber
 !         UNITS:      N/A
 !         TYPE:       INTEGER
 !         DIMENSION:  1D array (n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 !       Alpha:
 !         The alpha coefficients for absorber level calculations
 !         UNITS:      depends on the units of the absorber
 !         TYPE:       INTEGER
 !         DIMENSION:  2D array (n_Alphas x n_Absorbers)
 !         ATTRIBUTES: INTENT(IN)
 !
 !       iVar:
 !         Structure containing internal variables required for subsequent
 !         tangent-linear or adjoint model calls. The contents of this
 !         structure are NOT accessible outside of this module.
 !         UNITS:      N/A
 !         TYPE:       iVar_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(OUT)
 !
 ! OUTPUTS:
 !       Atmosphere_AD:
 !         Structure containing the adjoint atmospheric state data.
 !         UNITS:      N/A
 !         TYPE:       CRTM_Atmosphere_type
 !         DIMENSION:  Scalar
 !         ATTRIBUTES: INTENT(IN OUT)
 !
 ! COMMENTS:
 !       The predictors used in the gas absorption model are organised in
 !       the following manner:
 !
 ! ------------------------------------------------------------------------------
 ! | 1 | 2 | 3 | ... | 9 | 10 | 11 | 12 |....| 17 | 18 |....| 23 | 24 |....| 29 |
 ! ------------------------------------------------------------------------------
 !
 ! \                              /\             /\             /\             /
 !  \                            /  \           /  \           /  \           /
 !   ----------------------------    -----------    -----------    -----------
 !                 |                      |              |              |
 !                 v                      v              v              v
 !
 !             Standard               Integrated     Integrated     Integrated
 !            Predictors              predictors     predictors     predictors
 !                                       for            for            for
 !                                    water vapor    dry gases        ozone
 !:sdoc-:
 !--------------------------------------------------------------------------------

   SUBROUTINE odas_assemble_predictors_ad( &
     Atmosphere   , &  ! FWD Input
     Predictor    , &  ! FWD Input
     Predictor_AD , &  ! AD Input
     Max_Order    , &  ! Input
     Alpha        , &  ! Input
     Atmosphere_AD, &  ! AD Output
     iVar           )  ! Internal variable input
     ! Arguments
     TYPE(crtm_atmosphere_type),   INTENT(IN)     :: atmosphere
     TYPE(odas_predictor_type),    INTENT(IN)     :: predictor
     TYPE(odas_predictor_type),    INTENT(IN OUT) :: predictor_ad
     INTEGER,                      INTENT(IN)     :: max_order(:)
     REAL(fp),                     INTENT(IN)     :: alpha(:,:)
     TYPE(crtm_atmosphere_type),   INTENT(IN OUT) :: atmosphere_ad
     TYPE(ivar_type),              INTENT(IN)     :: ivar
     ! Local variables
     REAL(fp):: a_level_ad(atmosphere%n_layers)
     INTEGER :: i, j, k, n_layers

     ! Save the angle information
     predictor_ad%Secant_Sensor_Zenith = predictor%Secant_Sensor_Zenith

     ! Calculate adjoint absorber space level associated
     ! with the average absorber amount
     a_level_ad = zero
     n_layers = atmosphere%n_Layers
     DO j = 1, predictor%n_Absorbers

       IF( max_order(j) < 0 )cycle

       DO i = max_order(j), 2, -1
         DO k = n_layers, 1, -1

            predictor_ad%Ap(k, i-1, j) = predictor_ad%Ap(k,i-1,j) + &
                                         (predictor_ad%Ap(k,i,j)*ivar%A_Level(k,j))
            a_level_ad(k) = a_level_ad(k) + (predictor%Ap(k,i-1,j)*predictor_ad%Ap(k,i,j))
            predictor_ad%Ap(k,i,j) = zero

         END DO
       END DO

       a_level_ad(1:n_layers) = a_level_ad(1:n_layers) + predictor_ad%Ap(1:n_layers,1,j)
       predictor_ad%Ap(1:n_layers, 1, j) = zero

       DO k = n_layers, 1, -1
         predictor_ad%aveA(k,j) = predictor_ad%aveA(k,j) + &
                                  (a_level_ad(k) / (alpha(1,j) * (predictor%aveA(k,j) - alpha(3,j))))
         a_level_ad(k) = zero

       END DO
     END DO


     ! Calculate the predictor adjoints
     ! ...Integrated predictors
     CALL integrated_predictors_ad( &
            atmosphere   , &  ! Input
            predictor    , &  ! Input
            predictor_ad , &  ! In/Output
            atmosphere_ad, &  ! Output
            ivar           )  ! Internal variable input
     ! ...Standard predictors
     CALL standard_predictors_ad( &
            atmosphere   , &  ! Input
            predictor_ad , &  ! Input
            atmosphere_ad  )  ! Output


     ! Compute the nadir integrated absorber profile adjoint
     CALL compute_intabsorber_ad( &
            atmosphere   , &  ! Input
            predictor_ad , &  ! Output
            atmosphere_ad  )  ! Input


     ! Zero the adjoint predictor structure
     CALL odas_predictor_zero( predictor_ad )

   END SUBROUTINE odas_assemble_predictors_ad


 !################################################################################
 !################################################################################
 !##                                                                            ##
 !##                       ## PRIVATE MODULE ROUTINES ##                        ##
 !##                                                                            ##
 !################################################################################
 !################################################################################

 !================================================================================
 !                  -- INTEGRATED ABSORBER COMPUTATION ROUTINES --
 !================================================================================

 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Compute_IntAbsorber
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber profiles.
 !
 ! LANGUAGE:
 !       Fortran-95
 !
 ! CALLING SEQUENCE:
 !       CALL Compute_IntAbsorber( Atmosphere, &  ! Input
 !                                 Predictor   )  ! Output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:   CRTM Atmosphere structure containing the atmospheric
 !                     state data.
 !                     UNITS:      N/A
 !                     TYPE:       CRTM_Atmosphere_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor:    Predictor structure containing the calculated
 !                     integrated absorber profiles
 !                     UNITS:      N/A
 !                     TYPE:       ODAS_Predictor_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN OUT)
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE compute_intabsorber( Atm, &  ! Input
                                   Pred )  ! Output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred
     ! Local variables
     INTEGER  :: k, j
     REAL(fp) :: dPonG
     INTEGER  :: H2O_Idx
     INTEGER  ::  O3_Idx

     ! Initialise 0'th level amounts
     pred%A(0,wet_absorber_index) = zero
     pred%A(0,dry_absorber_index) = min(toa_pressure,atm%Level_Pressure(0))
     pred%A(0,ozo_absorber_index) = zero

     ! Get the atmosphere gaseous absorber indices
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)
     o3_idx  = crtm_get_absorberidx(atm, o3_id)

     ! Loop over layers, TOA -> SFC
     DO k = 1, atm%n_Layers

       ! Compute dP/g for the current layer
       dpong = reciprocal_gravity * (atm%Level_Pressure(k) - atm%Level_Pressure(k-1))

       ! Compute and accumulate the sum for the
       ! layer absorber amounts for each absorber
       pred%A( k, wet_absorber_index ) = pred%A(k-1,wet_absorber_index) + &
                                         (dpong * atm%Absorber(k,h2o_idx))
       pred%A( k, dry_absorber_index ) = atm%Level_Pressure(k)

       pred%A( k, ozo_absorber_index ) = pred%A(k-1,ozo_absorber_index) + &
                                         (dpong * atm%Absorber(k,o3_idx))

     END DO

     ! Modify absorber quantities by the angle secant
     pred%A = pred%Secant_Sensor_Zenith * pred%A

     ! Compute the integrated absorber level
     ! differences and average layer amount
     DO j = 1, pred%n_Absorbers
       DO k = 1, pred%n_Layers
         pred%dA(k,j)   = pred%A(k,j) - pred%A(k-1,j)
         pred%aveA(k,j) = point_5 * (pred%A(k,j) + pred%A(k-1,j))
       END DO
     END DO

   END SUBROUTINE compute_intabsorber


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Compute_IntAbsorber_TL
 !
 ! PURPOSE:
 !       Subroutine to compute the tangent-linear integrated absorber profiles.
 !
 ! CALLING SEQUENCE:
 !       CALL Compute_IntAbsorber_TL( Atmosphere,    &  ! Input
 !                                    Atmosphere_TL, &  ! Input
 !                                    Predictor_TL   )  ! Output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:     CRTM Atmosphere structure containing the atmospheric
 !                       state data.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 !       Atmosphere_TL:  CRTM Atmosphere structure containing the tangent-linear
 !                       atmospheric state data, i.e. the perturbations.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor_TL:   Predictor structure containing the calculated
 !                       tangent-linear integrated absorber profiles
 !                       UNITS:      N/A
 !                       TYPE:       ODAS_Predictor_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE compute_intabsorber_tl( Atm,    &  ! Input
                                      Atm_TL, &  ! Input
                                      Pred_TL )  ! Output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm_TL
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred_TL
     ! Local variables
     INTEGER  :: k, j
     REAL(fp) :: dPonG
     REAL(fp) :: dPonG_TL
     INTEGER  :: H2O_Idx
     INTEGER  ::  O3_Idx

     ! Initalise 0'th level amounts
     pred_tl%A(0,:) = zero

     ! Get the atmosphere gaseous absorber indices
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)
     o3_idx  = crtm_get_absorberidx(atm, o3_id)

     ! Loop over layers, TOA -> SFC
     DO k = 1, atm_tl%n_Layers

       ! Compute dP/g for the current layer
       dpong    = reciprocal_gravity * (atm%Level_Pressure(k)    - atm%Level_Pressure(k-1))
       dpong_tl = reciprocal_gravity * (atm_tl%Level_Pressure(k) - atm_tl%Level_Pressure(k-1))

       ! Compute and accumulate the sum for the
       ! layer absorber amounts for each absorber
       pred_tl%A(k,wet_absorber_index) = pred_tl%A(k-1,wet_absorber_index) + &
                                         (dpong * atm_tl%Absorber(k,h2o_idx)) + &
                                         (dpong_tl * atm%Absorber(k,h2o_idx))

       pred_tl%A(k,dry_absorber_index) = atm_tl%Level_Pressure(k)

       pred_tl%A(k,ozo_absorber_index) = pred_tl%A(k-1,ozo_absorber_index) + &
                                         (dpong * atm_tl%Absorber(k,o3_idx)) + &
                                         (dpong_tl * atm%Absorber(k,o3_idx))

     END DO

     ! Modify absorber quantities by the angle secant
     pred_tl%A = pred_tl%Secant_Sensor_Zenith * pred_tl%A

     ! Compute the tangent-linear integrated absorber level
     ! differences and average layer amount
     DO j = 1, pred_tl%n_Absorbers
       DO k = 1, pred_tl%n_Layers
         pred_tl%dA(k,j)   = pred_tl%A(k,j) - pred_tl%A(k-1,j)
         pred_tl%aveA(k,j) = point_5 * (pred_tl%A(k,j) + pred_tl%A(k-1,j))
       END DO
     END DO

   END SUBROUTINE compute_intabsorber_tl


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Compute_IntAbsorber_AD
 !
 ! PURPOSE:
 !       Subroutine to compute the adjoint of the integrated absorber profiles.
 !
 ! CALLING SEQUENCE:
 !       CALL Compute_IntAbsorber_AD( Atmosphere,   &  ! Input
 !                                    Predictor_AD, &  ! Input
 !                                    Atmosphere_AD )  ! Output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:     CRTM Atmosphere structure containing the atmospheric
 !                       state data.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 !       Predictor_AD:   Predictor structure that, on input, contains the
 !                       calculated adjoint integrated absorber profiles.
 !                       These values are set to zero on output.
 !                       UNITS:      N/A
 !                       TYPE:       ODAS_Predictor_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 ! OUTPUT ARGUMENTS:
 !       Atmosphere_AD:  CRTM Atmosphere structure containing the adjoint
 !                       atmospheric state data, i.e. the Jacobians.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 ! SIDE EFFECTS:
 !       Components of the input structure, Predictor_AD, are set to zero
 !       on output.
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE compute_intabsorber_ad( Atm,     &  ! Input
                                      Pred_AD, &  ! Input
                                      Atm_AD   )  ! Output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred_AD
     TYPE(CRTM_Atmosphere_type), INTENT(IN OUT) :: Atm_AD
     ! Local variables
     INTEGER  :: k, j
     REAL(fp) :: dPonG
     REAL(fp) :: dPonG_AD
     INTEGER  :: H2O_Idx
     INTEGER  ::  O3_Idx

     ! Get the atmosphere gaseous absorber indices
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)
     o3_idx  = crtm_get_absorberidx(atm, o3_id)

     ! Compute the adjoint integrated absorber level
     ! differences and average layer amount
     DO j = 1, pred_ad%n_Absorbers
       DO k = pred_ad%n_Layers, 1, -1
         pred_ad%A(k-1,j) = pred_ad%A(k-1,j) + (point_5*pred_ad%aveA(k,j))
         pred_ad%A(k-1,j) = pred_ad%A(k-1,j) - pred_ad%dA(k,j)
         pred_ad%A(k  ,j) = pred_ad%A(k  ,j) + (point_5*pred_ad%aveA(k,j))
         pred_ad%A(k  ,j) = pred_ad%A(k  ,j) + pred_ad%dA(k,j)
         pred_ad%dA(  k,j) = zero
         pred_ad%aveA(k,j) = zero
       END DO
     END DO

     ! Modify absorber quantities by the angle secant
     pred_ad%A = pred_ad%Secant_Sensor_Zenith * pred_ad%A

     ! Loop over layers, SFC -> TOA
     DO k = atm_ad%n_Layers, 1, -1

       ! Compute dP/g for the current layer
       dpong = reciprocal_gravity * (atm%Level_Pressure(k) - atm%Level_Pressure(k-1))

       ! Ozone amount adjoint
       atm_ad%Absorber(k,o3_idx) = atm_ad%Absorber(k,o3_idx) + &
                                   (dpong * pred_ad%A(k,ozo_absorber_index))

       ! Pressure adjoint
       atm_ad%Level_Pressure(k) = atm_ad%Level_Pressure(k) + pred_ad%A(k,dry_absorber_index)

       ! Water vapor amount adjoint
       atm_ad%Absorber(k,h2o_idx) = atm_ad%Absorber(k,h2o_idx) + &
                                      (dpong * pred_ad%A(k,wet_absorber_index))


       ! dP/g adjoint
       dpong_ad = ( atm%Absorber(k, o3_idx) * pred_ad%A(k,ozo_absorber_index)) + &
                  ( atm%Absorber(k,h2o_idx) * pred_ad%A(k,wet_absorber_index))

       atm_ad%Level_Pressure(k-1) = atm_ad%Level_Pressure(k-1) - (reciprocal_gravity * dpong_ad)
       atm_ad%Level_Pressure( k ) = atm_ad%Level_Pressure( k ) + (reciprocal_gravity * dpong_ad)

       ! Previous layer absorber amounts
       pred_ad%A(k-1,ozo_absorber_index) = pred_ad%A(k-1,ozo_absorber_index) + &
                                           pred_ad%A( k, ozo_absorber_index)
       pred_ad%A( k, ozo_absorber_index) = zero

       pred_ad%A( k, dry_absorber_index) = zero

       pred_ad%A(k-1,wet_absorber_index) = pred_ad%A(k-1,wet_absorber_index) + &
                                           pred_ad%A( k, wet_absorber_index)
       pred_ad%A( k, wet_absorber_index) = zero

     END DO

   END SUBROUTINE compute_intabsorber_ad


 !================================================================================
 !                      -- PREDICTOR COMPUTATION ROUTINES --
 !================================================================================

 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Standard_Predictors
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber INDEPENDENT
 !       predictors for the gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Standard_Predictors( Atmosphere, &  ! Input
 !                                 Predictor   )  ! Output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:   CRTM Atmosphere structure containing the atmospheric
 !                     state data.
 !                     UNITS:      N/A
 !                     TYPE:       CRTM_Atmosphere_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor:    Predictor structure containing the calculated
 !                     standard predictors.
 !                     UNITS:      N/A
 !                     TYPE:       ODAS_Predictor_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN OUT)
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE standard_predictors( Atm, &  ! Input
                                   Pred )  ! Output, Istd x K
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred
     ! Local variables
     INTEGER  :: k
     REAL(fp) :: p2
     REAL(fp) :: t2
     INTEGER  :: H2O_Idx

     ! Get the H2O absorber index
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)

     ! Compute the standard predictor set
     layer_loop: DO k = 1, atm%n_Layers

       ! Precalculate the squared terms
       p2 = atm%Pressure(k)    * atm%Pressure(k)
       t2 = atm%Temperature(k) * atm%Temperature(k)

       ! Calculate the standard predictors
       pred%X(k, 1) = atm%Temperature(k)
       pred%X(k, 2) = atm%Pressure(k)
       pred%X(k, 3) = t2
       pred%X(k, 4) = p2
       pred%X(k, 5) = atm%Temperature(k) * atm%Pressure(k)
       pred%X(k, 6) = t2 * atm%Pressure(k)
       pred%X(k, 7) = atm%Temperature(k) * p2
       pred%X(k, 8) = t2 * p2
       pred%X(k, 9) = atm%Pressure(k)**point_25
       pred%X(k,10) = atm%Absorber(k,h2o_idx)
       pred%X(k,11) = atm%Absorber(k,h2o_idx) / t2

     END DO layer_loop

   END SUBROUTINE standard_predictors


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Integrated_Predictors
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber DEPENDENT
 !       predictors for the gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Integrated_Predictors( Atmosphere, &  ! Input
 !                                   Predictor,  &  ! In/Output
 !                                   iVar        )  ! Internal variable output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:   CRTM Atmosphere structure containing the atmospheric
 !                     state data.
 !                     UNITS:      N/A
 !                     TYPE:       CRTM_Atmosphere_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor:    Predictor structure containing the calculated
 !                     integrated predictors.
 !                     UNITS:      N/A
 !                     TYPE:       ODAS_Predictor_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(IN OUT)
 !
 !       iVar:  Structure containing internal variables required for
 !                     subsequent tangent-linear or adjoint model calls.
 !                     The contents of this structure are NOT accessible
 !                     outside of the ODAS_Predictor module.
 !                     UNITS:      N/A
 !                     TYPE:       iVar_type
 !                     DIMENSION:  Scalar
 !                     ATTRIBUTES: INTENT(OUT)

 !--------------------------------------------------------------------------------

   SUBROUTINE integrated_predictors( Atm,  &  ! Input
                                     Pred, &  ! Input/output
                                     iVar  )  ! Internal variable output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred
     TYPE(iVar_type),            INTENT(OUT)    :: iVar
     ! Local variables
     INTEGER :: i, i1, j, k
     REAL(fp) :: Inverse_1
     REAL(fp) :: Inverse_2
     REAL(fp) :: Inverse_3
     ! LEVEL Predictor, Iint x 0:K
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS,0:Atm%n_Layers) :: xL

     ! Begin absorber loop
     absorber_loop: DO j = 1, pred%n_Absorbers

       ! Determine being index of current absorber predictors
       i1 = max_n_standard_predictors + ((j-1) * max_n_integrated_predictors) + 1

       ! Initialise values
       ivar%A_2(0,j) = pred%A(0,j) * pred%A(0,j)
       ivar%s(:,0,j) = zero
       xl(:,0) = zero

       ! Compute the integrated predictor set
       layer_loop: DO k = 1, pred%n_Layers

         ! Calculate Absorber multiplicative Factors
         ivar%A_2(k,j)      = pred%A(k,j)*pred%A(k,j)
         ivar%Factor_1(k,j) = (pred%A(k,j)  + pred%A(k-1,j) ) * pred%dA(k,j) ! For ** terms
         ivar%Factor_2(k,j) = (ivar%A_2(k,j) + ivar%A_2(k-1,j)) * pred%dA(k,j) ! For *** terms

         ! Calculate the intermediate sums
         ivar%s(1,k,j) = ivar%s(1,k-1,j) + ( atm%Temperature(k) * pred%dA(k,j) )      ! T*
         ivar%s(2,k,j) = ivar%s(2,k-1,j) + ( atm%Pressure(k)    * pred%dA(k,j) )      ! P*
         ivar%s(3,k,j) = ivar%s(3,k-1,j) + ( atm%Temperature(k) * ivar%Factor_1(k,j) ) ! T**
         ivar%s(4,k,j) = ivar%s(4,k-1,j) + ( atm%Pressure(k)    * ivar%Factor_1(k,j) ) ! P**
         ivar%s(5,k,j) = ivar%s(5,k-1,j) + ( atm%Temperature(k) * ivar%Factor_2(k,j) ) ! T***
         ivar%s(6,k,j) = ivar%s(6,k-1,j) + ( atm%Pressure(k)    * ivar%Factor_2(k,j) ) ! P***

         ! Calculate the normalising factors
         ! for the integrated predictors
         IF ( pred%A(k,j) > minimum_absorber_amount ) THEN
           inverse_1 = one / pred%A(k,j)
         ELSE
           inverse_1 = zero
         END IF
         inverse_2 = inverse_1 * inverse_1
         inverse_3 = inverse_2 * inverse_1

         ! Compute the LEVEL integrated predictors
         xl(1,k) = point_5  * ivar%s(1,k,j) * inverse_1  ! T*
         xl(2,k) = point_5  * ivar%s(2,k,j) * inverse_1  ! P*
         xl(3,k) = point_5  * ivar%s(3,k,j) * inverse_2  ! T**
         xl(4,k) = point_5  * ivar%s(4,k,j) * inverse_2  ! P**
         xl(5,k) = point_75 * ivar%s(5,k,j) * inverse_3  ! T***
         xl(6,k) = point_75 * ivar%s(6,k,j) * inverse_3  ! P***

         ! Sum predictors for current absorber across layers
         DO i = 1, max_n_integrated_predictors
           pred%X(k,i1+i-1) = xl(i,k) + xl(i,k-1)
         END DO

       END DO layer_loop
     END DO absorber_loop

   END SUBROUTINE integrated_predictors


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Standard_Predictors_TL
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber INDEPENDENT
 !       tangent-linear predictors for the gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Standard_Predictors_TL( Atmosphere,    &  ! Input
 !                                    Atmosphere_TL, &  ! Input
 !                                    Predictor_TL   )  ! Output
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:     CRTM Atmosphere structure containing the atmospheric
 !                       state data.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 !       Atmosphere_TL:  CRTM Atmosphere structure containing the tangent-linear
 !                       atmospheric state data, i.e. the perturbations.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor_TL:   Predictor structure containing the calculated
 !                       tangent-linear standard predictors.
 !                       UNITS:      N/A
 !                       TYPE:       ODAS_Predictor_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE standard_predictors_tl( Atm,    &  ! Input
                                      Atm_TL, &  ! Input
                                      Pred_TL )  ! Output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)  :: Atm
     TYPE(CRTM_Atmosphere_type), INTENT(IN)  :: Atm_TL
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT)  :: Pred_TL
     ! Local variables
     INTEGER  :: k
     REAL(fp) :: p2, p2_TL
     REAL(fp) :: t2, t2_TL
     INTEGER  :: H2O_Idx

     ! Get the H2O absorber index
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)

     ! Compute the tangent-linear standard predictor set
     layer_loop: DO k = 1, atm%n_Layers

       ! Precalculate the squared terms
       p2 = atm%Pressure(k)    * atm%Pressure(k)
       t2 = atm%Temperature(k) * atm%Temperature(k)

       ! Tangent-linear of squared terms
       p2_tl = two * atm%Pressure(k)    * atm_tl%Pressure(k)
       t2_tl = two * atm%Temperature(k) * atm_tl%Temperature(k)

       ! Calculate and assign the integrated absorber independent predictors
       pred_tl%X(k, 1) = atm_tl%Temperature(k)
       pred_tl%X(k, 2) = atm_tl%Pressure(k)
       pred_tl%X(k, 3) = t2_tl
       pred_tl%X(k, 4) = p2_tl
       pred_tl%X(k, 5) = ( atm%Temperature(k) * atm_tl%Pressure(k)    ) + &
                       ( atm%Pressure(k)    * atm_tl%Temperature(k) )
       pred_tl%X(k, 6) = ( atm%Pressure(k) * t2_tl ) + &
                       ( t2 * atm_tl%Pressure(k) )
       pred_tl%X(k, 7) = ( atm%Temperature(k) * p2_tl ) + &
                       ( p2 * atm_tl%Temperature(k) )
       pred_tl%X(k, 8) = ( t2 * p2_tl ) + &
                       ( p2 * t2_tl )
       pred_tl%X(k, 9) = point_25 * (atm%Pressure(k)**(-point_75)) * atm_tl%Pressure(k)
       pred_tl%X(k,10) = atm_tl%Absorber(k,h2o_idx)
       pred_tl%X(k,11) = ( atm_tl%Absorber(k,h2o_idx) - &
                         ( atm%Absorber(k,h2o_idx) * t2_tl / t2 ) ) / t2

     END DO layer_loop

   END SUBROUTINE standard_predictors_tl


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Integrated_Predictors_TL
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber amount DEPENDENT
 !       tangent-linear predictors for the gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Integrated_Predictors_TL( Atmosphere,    &  ! Input
 !                                      Predictor,     &  ! Input
 !                                      Atmosphere_TL, &  ! Input
 !                                      Predictor_TL,  &  ! In/Output
 !                                      iVar           )  ! Internal variable input
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:      CRTM Atmosphere structure containing the atmospheric
 !                        state data.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_Atmosphere_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       Predictor:       Predictor structure containing the calculated
 !                        integrated predictors.
 !                        UNITS:      N/A
 !                        TYPE:       ODAS_Predictor_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       Atmosphere_TL:   CRTM Atmosphere structure containing the tangent-linear
 !                        atmospheric state data, i.e. the perturbations.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_Atmosphere_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       iVar:            Structure containing internal variables required for
 !                        subsequent tangent-linear or adjoint model calls.
 !                        The contents of this structure are NOT accessible
 !                        outside of the Predictor module.
 !                        UNITS:      N/A
 !                        TYPE:       iVar_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 ! OUTPUT ARGUMENTS:
 !       Predictor_TL:    Predictor structure containing the calculated
 !                        tangent-linear integrated predictors.
 !                        UNITS:      N/A
 !                        TYPE:       ODAS_Predictor_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE integrated_predictors_tl( Atm,     &  ! Input
                                        Pred,    &  ! Input
                                        Atm_TL,  &  ! Input
                                        Pred_TL, &  ! Output
                                        iVar      )  ! Internal variable input
     ! Arguments
     TYPE(CRTM_Atmosphere_type),  INTENT(IN)      :: Atm
     TYPE(ODAS_Predictor_type),   INTENT(IN)      :: Pred
     TYPE(CRTM_Atmosphere_type),  INTENT(IN)      :: Atm_TL
     TYPE(ODAS_Predictor_type),   INTENT(IN OUT)  :: Pred_TL
     TYPE(iVar_type),             INTENT(IN)      :: iVar
     ! Local variables
     INTEGER :: i, i1, j, k
     REAL(fp) :: Factor_1_TL
     REAL(fp) :: Factor_2_TL
     REAL(fp) :: Inverse_1
     REAL(fp) :: Inverse_2
     REAL(fp) :: Inverse_3
     REAL(fp) :: Inverse_4
     REAL(fp) :: Inverse_1_TL
     REAL(fp) :: Inverse_2_TL
     REAL(fp) :: Inverse_3_TL
     ! Square of the Absorber amount. 0:K
     REAL(fp), DIMENSION(0:Atm%n_Layers) :: A_2_TL
     ! Intermediate summation arrays. Iint
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS) :: s_TL
     ! LEVEL Predictor, Iint x 0:K
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS,0:Atm%n_Layers) :: xL_TL

     ! Begin absorber loop
     absorber_loop: DO j = 1, pred_tl%n_Absorbers

       ! Determine being index of current absorber predictors
       i1 = max_n_standard_predictors + ((j-1) * max_n_integrated_predictors) + 1

       ! Initialise values
       a_2_tl(0) = two * pred%A(0,j) * pred_tl%A(0,j)
       s_tl(:)    = zero
       xl_tl(:,0) = zero

       ! Compute the integrated predictor set
       layer_loop: DO k = 1, atm%n_Layers

         ! Calculate absorber multiplicative Factors
         a_2_tl(k) = two * pred%A(k,j) * pred_tl%A(k,j)
         ! For the ** terms
         factor_1_tl = ( ( pred%A(k,j)    + pred%A(k-1,j)    ) * pred_tl%dA(k,j) ) + &
                       ( ( pred_tl%A(k,j) + pred_tl%A(k-1,j) ) *    pred%dA(k,j) )
         ! For the *** terms
         factor_2_tl = ( ( ivar%A_2(k,j) + ivar%A_2(k-1,j)) * pred_tl%dA(k,j) ) + &
                       ( ( a_2_tl(k)    + a_2_tl(k-1)   ) *    pred%dA(k,j) )

         ! Calculate the intermediate sums
         s_tl(1) = s_tl(1) + ( atm_tl%Temperature(k) *    pred%dA(k,j)) + &   ! T*
                             ( atm%Temperature(k)    * pred_tl%dA(k,j))
         s_tl(2) = s_tl(2) + ( atm_tl%Pressure(k)    *    pred%dA(k,j)) + &   ! P*
                             ( atm%Pressure(k)       * pred_tl%dA(k,j))
         s_tl(3) = s_tl(3) + ( atm_tl%Temperature(k) * ivar%Factor_1(k,j)) + & ! T**
                             ( atm%Temperature(k)    * factor_1_tl )
         s_tl(4) = s_tl(4) + ( atm_tl%Pressure(k)    * ivar%Factor_1(k,j)) + & ! P**
                             ( atm%Pressure(k)       * factor_1_tl )
         s_tl(5) = s_tl(5) + ( atm_tl%Temperature(k) * ivar%Factor_2(k,j)) + & ! T***
                             ( atm%Temperature(k)    * factor_2_tl )
         s_tl(6) = s_tl(6) + ( atm_tl%Pressure(k)    * ivar%Factor_2(k,j)) + & ! P***
                             ( atm%Pressure(k)       * factor_2_tl )

         ! Calculate the normalising factors
         ! for the integrated predictors
         IF ( pred%A(k,j) > minimum_absorber_amount ) THEN
           inverse_1 = one / pred%A(k,j)
         ELSE
           inverse_1 = zero
         END IF
         inverse_2 = inverse_1 * inverse_1
         inverse_3 = inverse_2 * inverse_1
         inverse_4 = inverse_3 * inverse_1
         inverse_1_tl = -inverse_2 * pred_tl%A(k,j)
         inverse_2_tl = -inverse_3 * pred_tl%A(k,j) * two
         inverse_3_tl = -inverse_4 * pred_tl%A(k,j) * three

         ! Compute the tangent-linear LEVEL integrated predictors
         xl_tl(1,k) = point_5  * ( ( s_tl(1)       * inverse_1    ) + &  ! T*
                                   ( ivar%s(1,k,j) * inverse_1_tl ) )
         xl_tl(2,k) = point_5  * ( ( s_tl(2)       * inverse_1    ) + &  ! P*
                                   ( ivar%s(2,k,j) * inverse_1_tl ) )
         xl_tl(3,k) = point_5  * ( ( s_tl(3)       * inverse_2    ) + &  ! T**
                                   ( ivar%s(3,k,j) * inverse_2_tl ) )
         xl_tl(4,k) = point_5  * ( ( s_tl(4)       * inverse_2    ) + &  ! P**
                                   ( ivar%s(4,k,j) * inverse_2_tl ) )
         xl_tl(5,k) = point_75 * ( ( s_tl(5)       * inverse_3    ) + &  ! T***
                                   ( ivar%s(5,k,j) * inverse_3_tl ) )
         xl_tl(6,k) = point_75 * ( ( s_tl(6)       * inverse_3    ) + &  ! P***
                                   ( ivar%s(6,k,j) * inverse_3_tl ) )

         ! Sum predictors across layers
         DO i = 1, max_n_integrated_predictors
           pred_tl%X(k,i1+i-1) = xl_tl(i,k) + xl_tl(i,k-1)
         END DO

       END DO layer_loop
     END DO absorber_loop

   END SUBROUTINE integrated_predictors_tl


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Standard_Predictors_AD
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber amount INDEPENDENT
 !       predictors for the adjoint gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Standard_Predictors_AD( Atmosphere,   &  ! Input
 !                                    Predictor_AD, &  ! Input
 !                                    Atmosphere_AD )  ! Output
 !
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:     CRTM Atmosphere structure containing the atmospheric
 !                       state data.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN)
 !
 !       Predictor_AD:   Predictor structure containing the calculated
 !                       adjoint integrated predictors.
 !                       UNITS:      N/A
 !                       TYPE:       ODAS_Predictor_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 ! OUTPUT ARGUMENTS:
 !       Atmosphere_AD:  CRTM Atmosphere structure containing the adjoints of
 !                       the standard predictors.
 !                       UNITS:      N/A
 !                       TYPE:       CRTM_Atmosphere_type
 !                       DIMENSION:  Scalar
 !                       ATTRIBUTES: INTENT(IN OUT)
 !
 ! COMMENTS:
 !       Note that the output adjoint argument, Atmosphere_AD, has INTENT of
 !       IN OUT. This is because the pressure, temperature, and absorber
 !       components of the Atmosphere_AD structure are assumed to have some
 !       initial value (which could simply be zero) that is added to when
 !       contructing the pressure, temperature and absorber adjoints.
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE standard_predictors_ad( Atm,     &  ! Input
                                      Pred_AD, &  ! Input
                                      Atm_AD   )  ! Output
     ! Arguments
     TYPE(CRTM_Atmosphere_type), INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),  INTENT(IN OUT) :: Pred_AD
     TYPE(CRTM_Atmosphere_type), INTENT(IN OUT) :: Atm_AD
     ! Local variables
     INTEGER  :: k
     REAL(fp) :: p2, p2_AD
     REAL(fp) :: t2, t2_AD
     REAL(fp) :: t4
     INTEGER  :: H2O_Idx

     ! Get the H2O absorber index
     h2o_idx = crtm_get_absorberidx(atm,h2o_id)

     ! Compute the standard predictor set
     ! Don't have to loop backwards here as this is a parallel loop
     layer_loop: DO k = 1, atm%n_Layers

       ! Precalculate the squared terms
       p2 = atm%Pressure(k)    * atm%Pressure(k)
       t2 = atm%Temperature(k) * atm%Temperature(k)
       t4 = t2 * t2

       ! Pressure squared adjoint
       p2_ad =                        pred_ad%X(k,4)   + &   ! Predictor #4, P^2
               ( atm%Temperature(k) * pred_ad%X(k,7) ) + &   ! Predictor #7, T.P^2
               ( t2                 * pred_ad%X(k,8) )       ! Predictor #8, T^2.P^2

       ! Temperature squared adjoint
       t2_ad =                             pred_ad%X(k,3)     + &  ! Predictor #3, T^2
               ( atm%Pressure(k)         * pred_ad%X(k,6) )   + &  ! Predictor #6, T^2.P
               ( p2                      * pred_ad%X(k,8) )   + &  ! Predictor #8, T^2.P^2
               (-atm%Absorber(k,h2o_idx) * pred_ad%X(k,11) / t4 )  ! Predictor #11, W/T^2

       ! Water vapor adjoint
       atm_ad%Absorber(k,h2o_idx) = atm_ad%Absorber(k,h2o_idx) + &
           pred_ad%X(k,10) + &     ! Predictor #10, W
         ( pred_ad%X(k,11) / t2 )  ! Predictor #11, W/T^2

       ! Temperature adjoint
       atm_ad%Temperature(k) = atm_ad%Temperature(k) + &
         ( two * atm%Temperature(k) * t2_ad ) + &  ! T^2 term
                             pred_ad%X(k,1)   + &  ! Predictor #1, T
         ( atm%Pressure(k) * pred_ad%X(k,5) ) + &  ! Predictor #5, T.P
         ( p2              * pred_ad%X(k,7) )      ! Predictor #7, T.P^2

       ! Pressure adjoint
       atm_ad%Pressure(k) = atm_ad%Pressure(k) + &
         ( two * atm%Pressure(k) * p2_ad )       + &                     ! P^2 term
                                pred_ad%X(k,2)   + &                     ! Predictor #2, P
         ( atm%Temperature(k) * pred_ad%X(k,5) ) + &                     ! Predictor #5, T.P
         ( t2                 * pred_ad%X(k,6) ) + &                     ! Predictor #6, T^2.P
         ( point_25 * (atm%Pressure(k)**(-point_75)) * pred_ad%X(k,9) )  ! Predictor #9, P^1/4

     END DO layer_loop

   END SUBROUTINE standard_predictors_ad


 !--------------------------------------------------------------------------------
 !
 ! NAME:
 !       Integrated_Predictors_AD
 !
 ! PURPOSE:
 !       Subroutine to compute the integrated absorber amount DEPENDENT
 !       predictors for the adjoint gas absorption model.
 !
 ! CALLING SEQUENCE:
 !       CALL Integrated_Predictors_AD( Atmosphere,    &  ! Input
 !                                      Predictor,     &  ! Input
 !                                      Predictor_AD,  &  ! In/Output
 !                                      Atmosphere_AD, &  ! Output
 !                                      iVar           )  ! Internal variable input
 !
 ! INPUT ARGUMENTS:
 !       Atmosphere:      CRTM Atmosphere structure containing the atmospheric
 !                        state data.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_Atmosphere_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       Predictor:       Predictor structure containing the calculated
 !                        integrated predictors.
 !                        UNITS:      N/A
 !                        TYPE:       ODAS_Predictor_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       Predictor_AD:    Predictor structure that, on input, contains
 !                        the adjoint integrated predictors.
 !                        UNITS:      N/A
 !                        TYPE:       ODAS_Predictor_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !
 ! OUTPUT ARGUMENTS:
 !       Predictor_AD:    Predictor structure that, on output, contains
 !                        the adjoint integrated absorber amounts.
 !                        UNITS:      N/A
 !                        TYPE:       ODAS_Predictor_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !
 !       Atmosphere_AD:   CRTM Atmosphere structure containing the adjoints of
 !                        the integrated predictors.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_Atmosphere_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !
 ! COMMENTS:
 !       Note that all the adjoint arguments have INTENTs of IN OUT. This is
 !       because they are assumed to have some value upon entry even if they
 !       are labeled as output arguments.
 !
 !--------------------------------------------------------------------------------

   SUBROUTINE integrated_predictors_ad( Atm,     &  ! Input
                                        Pred,    &  ! Input
                                        Pred_AD, &  ! In/Output
                                        Atm_AD,  &  ! Output
                                        iVar      )  ! Internal variable input
     ! Arguments
     TYPE(CRTM_Atmosphere_type),  INTENT(IN)     :: Atm
     TYPE(ODAS_Predictor_type),   INTENT(IN)     :: Pred
     TYPE(ODAS_Predictor_type),   INTENT(IN OUT) :: Pred_AD
     TYPE(CRTM_Atmosphere_type),  INTENT(IN OUT) :: Atm_AD
     TYPE(iVar_type),             INTENT(IN)     :: iVar
     ! Local variables
     INTEGER :: i, i1, j, k
     REAL(fp) :: d_A_AD
     REAL(fp) :: Factor_1_AD
     REAL(fp) :: Factor_2_AD
     REAL(fp) :: Inverse_1
     REAL(fp) :: Inverse_2
     REAL(fp) :: Inverse_3
     REAL(fp) :: Inverse_4
     REAL(fp) :: Inverse_1_AD
     REAL(fp) :: Inverse_2_AD
     REAL(fp) :: Inverse_3_AD
     REAL(fp) :: Multiplier
     REAL(fp) :: Add_Factor
     ! Square of the absorber amount. 0:K
     REAL(fp), DIMENSION(0:Atm%n_Layers) :: A_2_AD
     ! Intermediate summation array, Iint x 0:K and Iint
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS) :: s_AD
     ! LEVEL predictor, Iint x 0:K
     REAL(fp), DIMENSION(MAX_N_INTEGRATED_PREDICTORS,0:Atm%n_Layers ) :: xL_AD

     ! Begin absorber loop
     absorber_loop: DO j = 1, pred_ad%n_Absorbers

       ! Determine being index of current absorber predictors
       i1 = max_n_standard_predictors + ((j-1) * max_n_integrated_predictors) + 1

       ! Initialise values
       xl_ad(:,atm%n_Layers) = zero
       s_ad(:)               = zero
       a_2_ad(atm%n_Layers)  = zero

       ! Compute the integrated predictor set adjoints
       layer_loop: DO k = atm%n_Layers, 1, -1

         ! Calculate the normalising factors
         ! for the integrated predictors
         IF ( pred%A(k,j) > minimum_absorber_amount ) THEN
           inverse_1 = one / pred%A(k,j)
         ELSE
           inverse_1 = zero
         END IF

         inverse_2 = inverse_1 * inverse_1
         inverse_3 = inverse_2 * inverse_1
         inverse_4 = inverse_3 * inverse_1

         ! Adjoint of predictor summation across layers
         DO i = 1, max_n_integrated_predictors
           xl_ad(i,k)   = xl_ad(i,k) + pred_ad%X(k,i1+i-1)
           xl_ad(i,k-1) = pred_ad%X(k,i1+i-1)
         END DO

         ! Adjoint of the LEVEL integrated predictors intermediate sums
         !
         ! Note that the adjoint variables Inverse_X_AD are local to this
         ! loop iteration so they are simply assigned when they are first
         ! used.
         !
         ! P* and T*, Predictor indices #2 and 1
         ! Simply assign a value for Inverse_1_AD
         multiplier   = point_5 * inverse_1
         s_ad(1)    = s_ad(1) + ( multiplier * xl_ad(1,k) )
         s_ad(2)    = s_ad(2) + ( multiplier * xl_ad(2,k) )
         inverse_1_ad = point_5 * ( ( ivar%s(1,k,j) * xl_ad(1,k) ) + &
                                    ( ivar%s(2,k,j) * xl_ad(2,k) ) )
         ! P** and T**, Predictor indices #4 and 3
         multiplier   = point_5 * inverse_2
         s_ad(3)    = s_ad(3) + ( multiplier * xl_ad(3,k) )
         s_ad(4)    = s_ad(4) + ( multiplier * xl_ad(4,k) )
         inverse_2_ad = point_5 * ( ( ivar%s(3,k,j) * xl_ad(3,k) ) + &
                                    ( ivar%s(4,k,j) * xl_ad(4,k) ) )
         ! P*** and T***, Predictor indices #6 and 5
         multiplier   = point_75 * inverse_3
         s_ad(5)    = s_ad(5) + ( multiplier * xl_ad(5,k) )
         s_ad(6)    = s_ad(6) + ( multiplier * xl_ad(6,k) )
         inverse_3_ad = point_75 * ( ( ivar%s(5,k,j) * xl_ad(5,k) ) + &
                                     ( ivar%s(6,k,j) * xl_ad(6,k) ) )

         ! Adjoint of Inverse terms. Note that the Inverse_X_AD
         ! terms are *not* zeroed out as they are re-assigned values
         ! each loop iteration above.
         pred_ad%A(k,j) = pred_ad%A(k,j) - (inverse_2 * inverse_1_ad ) - &
                                           (two   * inverse_3 * inverse_2_ad ) - &
                                           (three * inverse_4 * inverse_3_ad )

         ! Pressure adjoint
         atm_ad%Pressure(k) = atm_ad%Pressure(k) + &
                              ( pred%dA(k,j)      * s_ad(2) ) + &  ! P*
                              ( ivar%Factor_1(k,j) * s_ad(4) ) + &  ! P**
                              ( ivar%Factor_2(k,j) * s_ad(6) )      ! P***


         ! Temperature adjoint
         atm_ad%Temperature(k) = atm_ad%Temperature(k) + &
                                 ( pred%dA(k,j)      * s_ad(1) ) + &  ! T*
                                 ( ivar%Factor_1(k,j) * s_ad(3) ) + &  ! T**
                                 ( ivar%Factor_2(k,j) * s_ad(5) )      ! T***

         ! Adjoint of the absorber amount
         !
         ! Note that the adjoint variables Factor_X_AD and
         ! d_A_AD are local to this loop iteration
         ! so they are simply assigned when they are first
         ! used (and thus not zeroed out at the end of each
         ! iteration)
         !
         ! Note there are no
         !   s_AD() = 0
         ! because all the tangent-linear forms are
         !   s_TL() = s_TL() + (...)
         ! summing from the previous Layer.
         !
         ! Multiplicative factors
         factor_1_ad = ( atm%Temperature(k) * s_ad(3) ) + &
                       ( atm%Pressure(k)    * s_ad(4) )

         factor_2_ad = ( atm%Temperature(k) * s_ad(5) ) + &
                       ( atm%Pressure(k)    * s_ad(6) )

         ! Adjoint of the square integrated absorber amount.
         !
         ! Note that A_2_AD() is a LOCAL adjoint variable,
         ! so the initialisation of A_2_AD(k-1) here for
         ! each "k-1" is o.k. rather than
         !   A_2_AD(k-1) = A_2_AD(k-1) + ( d_A(k) * Factor_2_AD )
         !   A_2_AD( k ) = A_2_AD( k ) + ( d_A(k) * Factor_2_AD )
         ! since only A_2_AD( n_Layers ) is initialised outside the
         ! current layer loop.
         a_2_ad(k-1) = pred%dA(k,j) * factor_2_ad
         a_2_ad( k ) = a_2_ad( k ) + a_2_ad(k-1)

         ! Adjoint of A(). Here, since Pred_AD%A() is NOT a local adjoint
         ! variable, we can't use the same form as for A_2_AD() above.
         d_a_ad = ( atm%Temperature(k) * s_ad(1) ) + &
                  ( atm%Pressure(k)    * s_ad(2) ) + &
                  ( ( pred%A(k,j)  + pred%A(k-1,j)  ) * factor_1_ad ) + &
                  ( ( ivar%A_2(k,j) + ivar%A_2(k-1,j) ) * factor_2_ad )

         add_factor = pred%dA(k,j) * factor_1_ad
         pred_ad%A(k-1,j) = pred_ad%A(k-1,j) + add_factor - d_a_ad
         pred_ad%A( k ,j) = pred_ad%A( k ,j) + add_factor + d_a_ad + &
                            ( two * pred%A(k,j) * a_2_ad(k) )
         a_2_ad(k) = zero

       END DO layer_loop

       ! Adjoint of level 0 A
       pred_ad%A(0,j)   = pred_ad%A(0,j) + ( two * pred%A(0,j) * a_2_ad(0) )
       a_2_ad(0) = zero

     END DO absorber_loop

   END SUBROUTINE integrated_predictors_ad

 END MODULE odas_predictor
crtm_parameters::point_25
real(fp), parameter, public point_25
Definition: CRTM_Parameters.f90:77

odas_predictor::module_version_id
character(*), parameter module_version_id
Definition: ODAS_Predictor.f90:72

message_handler::failure
integer, parameter, public failure
Definition: Message_Handler.f90:30

odas_predictor::max_n_standard_predictors
integer, parameter, public max_n_standard_predictors
Definition: ODAS_Predictor.f90:98

crtm_parameters::ten
real(fp), parameter, public ten
Definition: CRTM_Parameters.f90:76

odas_predictor_define::odas_predictor_zero
elemental subroutine, public odas_predictor_zero(self)
Definition: ODAS_Predictor_Define.f90:389

crtm_parameters::zero
real(fp), parameter, public zero
Definition: CRTM_Parameters.f90:70

odas_predictor::compute_intabsorber_tl
subroutine compute_intabsorber_tl(Atm, Atm_TL, Pred_TL)
Definition: ODAS_Predictor.f90:788

odas_predictor::standard_predictors
subroutine standard_predictors(Atm, Pred)
Definition: ODAS_Predictor.f90:999

odas_predictor_define::odas_predictor_create
elemental subroutine, public odas_predictor_create(self, n_Layers, n_Predictors, n_Absorbers, n_Orders)
Definition: ODAS_Predictor_Define.f90:250

odas_predictor::standard_predictors_ad
subroutine standard_predictors_ad(Atm, Pred_AD, Atm_AD)
Definition: ODAS_Predictor.f90:1448

type_kinds::fp
integer, parameter, public fp
Definition: Type_Kinds.f90:124

odas_predictor_define::odas_predictor_type
Definition: ODAS_Predictor_Define.f90:78

crtm_parameters::three
real(fp), parameter, public three
Definition: CRTM_Parameters.f90:73

odas_predictor::max_n_absorbers
integer, parameter, public max_n_absorbers
Definition: ODAS_Predictor.f90:79

crtm_parameters
Definition: CRTM_Parameters.f90:12

odas_predictor::compute_intabsorber_ad
subroutine compute_intabsorber_ad(Atm, Pred_AD, Atm_AD)
Definition: ODAS_Predictor.f90:888

odas_predictor::ozo_absorber_index
integer, parameter, public ozo_absorber_index
Definition: ODAS_Predictor.f90:83

crtm_atmosphere_define::h2o_id
integer, parameter, public h2o_id
Definition: CRTM_Atmosphere_Define.f90:250

crtm_parameters::toa_pressure
real(fp), parameter, public toa_pressure
Definition: CRTM_Parameters.f90:154

crtm_geometryinfo_define::crtm_geometryinfo_type
Definition: CRTM_GeometryInfo_Define.f90:104

odas_predictor::max_n_predictors
integer, parameter, public max_n_predictors
Definition: ODAS_Predictor.f90:102

odas_predictor::integrated_predictors
subroutine integrated_predictors(Atm, Pred, iVar)
Definition: ODAS_Predictor.f90:1080

odas_predictor::max_n_orders
integer, parameter, public max_n_orders
Definition: ODAS_Predictor.f90:109

crtm_parameters::minimum_absorber_amount
real(fp), parameter, public minimum_absorber_amount
Definition: CRTM_Parameters.f90:137

crtm_parameters::point_75
real(fp), parameter, public point_75
Definition: CRTM_Parameters.f90:79

message_handler
Definition: Message_Handler.f90:4

odas_predictor::max_n_predictors_used
integer, parameter, public max_n_predictors_used
Definition: ODAS_Predictor.f90:106

odas_predictor_define
Definition: ODAS_Predictor_Define.f90:16

odas_predictor::integrated_predictors_ad
subroutine integrated_predictors_ad(Atm, Pred, Pred_AD, Atm_AD, iVar)
Definition: ODAS_Predictor.f90:1572

crtm_parameters::one
real(fp), parameter, public one
Definition: CRTM_Parameters.f90:71

odas_predictor::integrated_predictors_tl
subroutine integrated_predictors_tl(Atm, Pred, Atm_TL, Pred_TL, iVar)
Definition: ODAS_Predictor.f90:1298

message_handler::display_message
recursive subroutine, public display_message(Routine_Name, Message, Error_State, Message_Log)
Definition: Message_Handler.f90:118

crtm_atmosphere_define::o3_id
integer, parameter, public o3_id
Definition: CRTM_Atmosphere_Define.f90:252

odas_predictor_define::odas_predictor_destroy
elemental subroutine, public odas_predictor_destroy(self)
Definition: ODAS_Predictor_Define.f90:178

crtm_parameters::two
real(fp), parameter, public two
Definition: CRTM_Parameters.f90:72

odas_predictor::compute_intabsorber
subroutine compute_intabsorber(Atm, Pred)
Definition: ODAS_Predictor.f90:696

odas_predictor::absorber_name
character(*), dimension(max_n_absorbers), parameter, public absorber_name
Definition: ODAS_Predictor.f90:89

odas_predictor::standard_predictors_tl
subroutine standard_predictors_tl(Atm, Atm_TL, Pred_TL)
Definition: ODAS_Predictor.f90:1190

odas_predictor::odas_assemble_predictors
subroutine, public odas_assemble_predictors(Atmosphere, GeometryInfo, Max_Order, Alpha, Predictor, iVar)
Definition: ODAS_Predictor.f90:232

crtm_parameters::max_n_layers
integer, parameter, public max_n_layers
Definition: CRTM_Parameters.f90:64

crtm_parameters::point_5
real(fp), parameter, public point_5
Definition: CRTM_Parameters.f90:78

odas_predictor::max_n_integrated_predictors
integer, parameter, public max_n_integrated_predictors
Definition: ODAS_Predictor.f90:100

odas_predictor::absorber_index
integer, dimension(max_n_absorbers), parameter, public absorber_index
Definition: ODAS_Predictor.f90:85

type_kinds
Definition: Type_Kinds.f90:12

odas_predictor_define::odas_predictor_associated
elemental logical function, public odas_predictor_associated(self)
Definition: ODAS_Predictor_Define.f90:148

crtm_parameters::reciprocal_gravity
real(fp), parameter, public reciprocal_gravity
Definition: CRTM_Parameters.f90:161

odas_predictor::ivar_type
Definition: ODAS_Predictor.f90:116

odas_predictor::dry_absorber_index
integer, parameter, public dry_absorber_index
Definition: ODAS_Predictor.f90:82

odas_predictor::wet_absorber_index
integer, parameter, public wet_absorber_index
Definition: ODAS_Predictor.f90:81

crtm_atmosphere_define::crtm_atmosphere_type
Definition: CRTM_Atmosphere_Define.f90:361

min
#define min(a, b)
Definition: mosaic_util.h:32

crtm_atmosphere_define::crtm_get_absorberidx
integer function, public crtm_get_absorberidx(Atm, AbsorberId)
Definition: CRTM_Atmosphere_Define.f90:1177

crtm_atmosphere_define
Definition: CRTM_Atmosphere_Define.f90:13

odas_predictor
Definition: ODAS_Predictor.f90:16

crtm_geometryinfo_define
Definition: CRTM_GeometryInfo_Define.f90:13

message_handler::success
integer, parameter, public success
Definition: Message_Handler.f90:27

crtm_geometryinfo_define::crtm_geometryinfo_getvalue
elemental subroutine, public crtm_geometryinfo_getvalue(gInfo, Geometry, iFOV, Longitude, Latitude, Surface_Altitude, Sensor_Scan_Angle, Sensor_Zenith_Angle, Sensor_Azimuth_Angle, Source_Zenith_Angle, Source_Azimuth_Angle, Flux_Zenith_Angle, Year, Month, Day, Distance_Ratio, Sensor_Scan_Radian, Sensor_Zenith_Radian, Sensor_Azimuth_Radian, Secant_Sensor_Zenith, Cosine_Sensor_Zenith, Source_Zenith_Radian, Source_Azimuth_Radian, Secant_Source_Zenith, Flux_Zenith_Radian, Secant_Flux_Zenith, Trans_Zenith_Radian, Secant_Trans_Zenith, AU_ratio2)
Definition: CRTM_GeometryInfo_Define.f90:421

odas_predictor::odas_assemble_predictors_tl
subroutine, public odas_assemble_predictors_tl(Atmosphere, Predictor, Atmosphere_TL, Max_Order, Alpha, Predictor_TL, iVar)
Definition: ODAS_Predictor.f90:409

odas_predictor::odas_assemble_predictors_ad
subroutine, public odas_assemble_predictors_ad(Atmosphere, Predictor, Predictor_AD, Max_Order, Alpha, Atmosphere_AD, iVar)
Definition: ODAS_Predictor.f90:575