ODSSU_AtmAbsorption.f90

Go to the documentation of this file.

!
! ODSSU_AtmAbsorption
!
! Module containing routines to compute the optical depth profile for SSUs
!
!
! CREATION HISTORY:
!       Based on CRTM_AtmAbsorption_ssu     by:  Quanhua Liu, JCSDA,      Dec  1, 2007
!       Rewritten for CRTMv2.0              by:  Yong Han, NOAA/NESDIS,   Oct  6, 2009
!       Revised                             by:  Paul van Delst, , JCSDA, Oct 26, 2009
!       Revised                             by:  Quanhua Liu, JCSDA,      Oct 29, 2009
!       Revised                             by:  Yong Chen, JCSDA,        Nov  9, 2009
!

MODULE odssu_atmabsorption

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds,               ONLY: fp
  USE message_handler,          ONLY: success, failure, warning, display_message
  USE search_utility,           ONLY: bisection_search
  USE crtm_parameters,          ONLY: zero, one
  USE crtm_geometryinfo_define, ONLY: crtm_geometryinfo_type
  USE crtm_atmoptics_define,    ONLY: crtm_atmoptics_type
  USE ssu_input_define,         ONLY: ssu_input_type, &
                                      ssu_input_getvalue, &
                                      ssu_input_cellpressureisset
  USE odssu_taucoeff,           ONLY: tc
  ! ...ODAS modules
  USE odas_predictor_define,    ONLY: odas_predictor_type
  USE odas_atmabsorption,       ONLY: odas_aavar_type => ivar_type , &
                                      odas_compute_atmabsorption   , &
                                      odas_compute_atmabsorption_tl, &
                                      odas_compute_atmabsorption_ad
  ! ...ODPS modules
  USE odps_predictor_define,    ONLY: odps_predictor_type
  USE odps_atmabsorption,       ONLY: odps_compute_atmabsorption   , &
                                      odps_compute_atmabsorption_tl, &
                                      odps_compute_atmabsorption_ad
  ! Disable implicit typing
  IMPLICIT NONE

  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Datatypes
  PUBLIC :: ivar_type
  ! Procedures
  PUBLIC :: odssu_compute_weights
  PUBLIC :: odssu_compute_atmabsorption
  PUBLIC :: odssu_compute_atmabsorption_tl
  PUBLIC :: odssu_compute_atmabsorption_ad


  ! -------------------
  ! Procedure overloads
  ! -------------------
  INTERFACE odssu_compute_atmabsorption
    MODULE PROCEDURE compute_odas_atmabsorption
    MODULE PROCEDURE compute_odps_atmabsorption
  END INTERFACE odssu_compute_atmabsorption

  INTERFACE odssu_compute_atmabsorption_tl
    MODULE PROCEDURE compute_odas_atmabsorption_tl
    MODULE PROCEDURE compute_odps_atmabsorption_tl
  END INTERFACE odssu_compute_atmabsorption_tl

  INTERFACE odssu_compute_atmabsorption_ad
    MODULE PROCEDURE compute_odas_atmabsorption_ad
    MODULE PROCEDURE compute_odps_atmabsorption_ad
  END INTERFACE odssu_compute_atmabsorption_ad


  ! ----------
  ! Parameters
  ! ----------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: ODSSU_AtmAbsorption.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Message string length
  INTEGER, PARAMETER :: ml = 256


  ! ------------------------------------------
  ! Structure definition to hold forward model
  ! variables across FWD, TL, and AD calls
  ! ------------------------------------------
  TYPE :: ivar_type
    PRIVATE
    TYPE(odas_aavar_type) :: odas(2)
    REAL(fp) :: weight(2) = zero
    REAL(fp) :: co2_cell = zero
    INTEGER  :: index_low = 1
  END TYPE ivar_type



CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                         ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################

!------------------------------------------------------------------------------
!
! NAME:
!       ODSSU_Compute_Weights
!
! PURPOSE:
!       Subroutine to calculate ODSSU algorithm linear interpolation weighting
!       factors for the SSU CO2 cell pressure.
!
! CALLING SEQUENCE:
!       CALL ODSSU_Compute_Weights( SSU_Input   , &
!                                   SensorIndex , &
!                                   ChannelIndex, &
!                                   iVar          )
!
! INPUTS:
!       SSU_Input:       Structure containing the SSU input data.
!                        UNITS:      N/A
!                        TYPE:       SSU_Input_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       SensorIndex:     Sensor index id. This is a unique index associated
!                        with a (supported) sensor used to access the
!                        shared coefficient data for a particular sensor.
!                        See the ChannelIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE odssu_compute_weights( &
    SSU_Input   , &  ! Input
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    iVar          )  ! Internal variable output
    ! Arguments
    TYPE(ssu_input_type), INTENT(IN)     :: ssu_input
    INTEGER             , INTENT(IN)     :: sensorindex
    INTEGER             , INTENT(IN)     :: channelindex
    TYPE(ivar_type)     , INTENT(IN OUT) :: ivar
    ! Parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ODSSU_Compute_Weights'
    ! Variables
    CHARACTER(ML) :: msg
    REAL(fp) :: time, cell_pressure

    ! Compute the CO2 cell pressure
    IF( ssu_input_cellpressureisset(ssu_input) ) THEN
      ! ...Interpolate the cell pressure data
      CALL ssu_input_getvalue( ssu_input, &
                               channel = channelindex, &
                               cell_pressure = cell_pressure )
      ivar%CO2_Cell  = cell_pressure
      ivar%Index_low = bisection_search( tc(sensorindex)%TC_CellPressure(:,channelindex), ivar%CO2_Cell )
    ELSE
      ! ...Get the mission time
      CALL ssu_input_getvalue( ssu_input, time=time )
      IF( time < tc(sensorindex)%Ref_Time(1) )THEN
        time = tc(sensorindex)%Ref_Time(1)
        WRITE( msg,'("Invalid time. Reset to ",f8.2)' ) time
        CALL display_message( routine_name, trim(msg), warning )
      END IF
      ! ...Obtain CO2 cell pressure for given time
      CALL get_co2_cell_p( sensorindex, channelindex, time, ivar%CO2_Cell )
      ivar%Index_low = bisection_search( tc(sensorindex)%TC_CellPressure(:,channelindex), ivar%CO2_Cell )
    END IF


    ! Compute the interpolation weights
    ivar%Weight(1) = (ivar%CO2_Cell - tc(sensorindex)%TC_CellPressure(ivar%Index_low,channelindex))/ &
                      (tc(sensorindex)%TC_CellPressure(ivar%Index_low+1,channelindex) - &
                       tc(sensorindex)%TC_CellPressure(ivar%Index_low  ,channelindex)   )
    ivar%Weight(2) = one - ivar%Weight(1)

  END SUBROUTINE odssu_compute_weights
  

!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODSSU_Compute_AtmAbsorption
!
! PURPOSE:
!       Subroutine to calculate the layer optical depths due to gaseous
!       absorption for the SSU sensor for a given channel and atmospheric
!       profile.
!
! CALLING SEQUENCE:
!       CALL ODSSU_Compute_AtmAbsorption( SensorIndex , &
!                                         ChannelIndex, &
!                                         Predictor   , &
!                                         AtmOptics   , &
!                                         iVar          )
!
! INPUTS:
!       SensorIndex:     Sensor index id. This is a unique index associated
!                        with a (supported) sensor used to access the
!                        shared coefficient data for a particular sensor.
!                        See the ChannelIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! *********** INTENT NEEDS TO BE CORRECTED TO JUST (IN) ***********
! *********** PREDICTOR CAN BE MODIFIED IN ODPS_AtmAbsorption MODULE ************
!       Predictor:       Structure containing the integrated absorber and
!                        predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                                      or
!                                    ODPS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
! *********** INTENT NEEDS TO BE CORRECTED TO JUST (IN) ***********
! *********** PREDICTOR CAN BE MODIFIED IN ODPS_AtmAbsorption MODULE ************
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!        AtmOptics:      Structure containing the computed optical depth
!                        profile.
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! COMMENTS:
!       Note the INTENT on the output structure arguments are IN OUT rather
!       than just OUT. This is to prevent default reinitialisation upon entry.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE compute_odas_atmabsorption( &
    SensorIndex  , &  ! Input
    ChannelIndex , &  ! Input
    Predictor    , &  ! Input
    AtmOptics    , &  ! Output
    iVar           )  ! Internal variable In/output
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODAS_Predictor_type), INTENT(IN)     :: Predictor
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics
    TYPE(iVar_type)          , INTENT(IN OUT) :: iVar
    ! Variables
    REAL(fp) :: optical_depth( AtmOptics%n_Layers )


    ! Compute the optical depths
    ! ...At cell pressure 1
    CALL odas_compute_atmabsorption( &
           tc(sensorindex)%ODAS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           atmoptics                           , &
           ivar%ODAS(1)                          )
    optical_depth = atmoptics%Optical_Depth
    ! ...At cell pressure 2
    CALL odas_compute_atmabsorption( &
           tc(sensorindex)%ODAS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           atmoptics                             , &
           ivar%ODAS(2)                            )
    ! ...Weighted average
    atmoptics%Optical_Depth = ivar%Weight(1)*atmoptics%Optical_Depth + &
                              ivar%Weight(2)*optical_depth

  END SUBROUTINE compute_odas_atmabsorption


  SUBROUTINE compute_odps_atmabsorption( &
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! Input
    AtmOptics   , &  ! Output
    iVar          )  ! Internal variable In/output
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODPS_Predictor_type), INTENT(IN OUT) :: Predictor    ! INTENT! PREDICTOR CAN BE MODIFIED IN ODPS_AtmAbsorption MODULE
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics
    TYPE(iVar_type)          , INTENT(IN OUT) :: iVar
    ! Variables
    REAL(fp) :: optical_depth( AtmOptics%n_Layers )

    ! Compute the optical depths
    ! ...At cell pressure 1
    CALL odps_compute_atmabsorption( &
           tc(sensorindex)%ODPS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           atmoptics                             )
    optical_depth = atmoptics%Optical_Depth
    ! ...At cell pressure 2
    CALL odps_compute_atmabsorption( &
           tc(sensorindex)%ODPS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           atmoptics                               )
    ! ...Weighted average
    atmoptics%Optical_Depth = ivar%Weight(1)*atmoptics%Optical_Depth + &
                              ivar%Weight(2)*optical_depth

  END SUBROUTINE compute_odps_atmabsorption


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODSSU_Compute_AtmAbsorption_TL
!
! PURPOSE:
!       Subroutine to calculate the tangent-linear layer optical depths due
!       to gaseous absorption for the SSU sensor for a given channel and
!       atmospheric profile.
!
! CALLING SEQUENCE:
!       CALL ODSSU_Compute_AtmAbsorption_TL( SensorIndex , &
!                                            ChannelIndex, &
!                                            Predictor   , &
!                                            Predictor_TL, &
!                                            AtmOptics_TL, &
!                                            iVar          )
!
! INPUTS:
!       SensorIndex:     Sensor index id. This is a unique index associated
!                        with a (supported) sensor used to access the
!                        shared coefficient data for a particular sensor.
!                        See the ChannelIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor:       Structure containing the integrated absorber and
!                        predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                                      or
!                                    ODPS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! *********** INTENT NEEDS TO BE CORRECTED TO JUST (IN) ***********
! *********** PREDICTOR_TL IS SPECIFIED AS INTENT(IN OUT) IN ODPS_AtmAbsorption MODULE ************
!       Predictor_TL:    Structure containing the tangent-linear integrated
!                        absorber and predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                                      or
!                                    ODPS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
! *********** PREDICTOR_TL IS SPECIFIED AS INTENT(IN OUT) IN ODPS_AtmAbsorption MODULE ************
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!        AtmOptics_TL:   Structure containing the computed tangent-linear
!                        optical depth profile.
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! COMMENTS:
!       Note the INTENT on the output structure arguments are IN OUT rather
!       than just OUT. This is to prevent default reinitialisation upon entry.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE compute_odas_atmabsorption_tl( &
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! FWD Input
    Predictor_TL, &  ! TL  Input
    AtmOptics_TL, &  ! TL  Output
    iVar          )  ! Internal variable input
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODAS_Predictor_type), INTENT(IN)     :: Predictor
    TYPE(ODAS_Predictor_type), INTENT(IN)     :: Predictor_TL
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics_TL
    TYPE(iVar_type)          , INTENT(IN)     :: iVar
    ! Variables
    REAL(fp) :: optical_depth_TL(AtmOptics_TL%n_Layers)

    ! Compute the tangent-linear optical depths
    ! ...At cell pressure 1
    CALL odas_compute_atmabsorption_tl( &
           tc(sensorindex)%ODAS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           predictor_tl                        , &
           atmoptics_tl                        , &
           ivar%ODAS(1)                          )
    optical_depth_tl = atmoptics_tl%Optical_Depth
    ! ...At cell pressure 2
    CALL odas_compute_atmabsorption_tl( &
           tc(sensorindex)%ODAS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           predictor_tl                          , &
           atmoptics_tl                          , &
           ivar%ODAS(2)                            )
    ! ...Weighted average
    atmoptics_tl%Optical_Depth = ivar%Weight(1)*atmoptics_tl%Optical_Depth + &
                                 ivar%Weight(2)*optical_depth_tl

  END SUBROUTINE compute_odas_atmabsorption_tl


  SUBROUTINE compute_odps_atmabsorption_tl( &
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! FWD Input
    Predictor_TL, &  ! TL  Input
    AtmOptics_TL, &  ! TL  Output
    iVar          )  ! Internal variable input
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODPS_Predictor_type), INTENT(IN)     :: Predictor
    TYPE(ODPS_Predictor_type), INTENT(IN OUT) :: Predictor_TL    ! INTENT! IS SPECIFIED AS (IN OUT) IN ODPS_AtmAbsorption MODULE
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics_TL
    TYPE(iVar_type)          , INTENT(IN)     :: iVar
    ! Variables
    REAL(fp) :: optical_depth_TL(AtmOptics_TL%n_Layers)

    ! Compute the tangent-linear optical depths
    ! ...At cell pressure 1
    CALL odps_compute_atmabsorption_tl( &
           tc(sensorindex)%ODPS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           predictor_tl                        , &
           atmoptics_tl                          )
    optical_depth_tl = atmoptics_tl%Optical_Depth
    ! ...At cell pressure 2
    CALL odps_compute_atmabsorption_tl( &
           tc(sensorindex)%ODPS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           predictor_tl                          , &
           atmoptics_tl                            )
    ! ...Weighted average
    atmoptics_tl%Optical_Depth = ivar%Weight(1)*atmoptics_tl%Optical_Depth + &
                                 ivar%Weight(2)*optical_depth_tl

  END SUBROUTINE compute_odps_atmabsorption_tl


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ODSSU_Compute_AtmAbsorption_AD
!
! PURPOSE:
!       Subroutine to calculate the adjoint of the layer optical depths due
!       to gaseous absorption for the SSU sensor for a given channel and
!       atmospheric profile.
!
! CALLING SEQUENCE:
!       CALL ODSSU_Compute_AtmAbsorption_AD( SensorIndex , &
!                                            ChannelIndex, &
!                                            Predictor   , &
!                                            AtmOptics_AD, &
!                                            Predictor_AD, &
!                                            iVar          )
!
! INPUTS:
!       SensorIndex:     Sensor index id. This is a unique index associated
!                        with a (supported) sensor used to access the
!                        shared coefficient data for a particular sensor.
!                        See the ChannelIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       ChannelIndex:    Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data for a particular sensor's
!                        channel.
!                        See the SensorIndex argument.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Predictor:       Structure containing the integrated absorber and
!                        predictor profile data.
!                        UNITS:      N/A
!                        TYPE:       ODAS_Predictor_type
!                                      or
!                                    ODPS_Predictor_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       AtmOptics_AD:    Structure containing the adjoint optical
!                        depth profile.
!                        *** NOTE: Optical depth component may be set to
!                                  zero upon exit.
!                        UNITS:      N/A
!                        TYPE:       CRTM_AtmOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of this module.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Predictor_AD:    Structure containing the adjoint integrated
!                        absorber and predictor profile data.
!                        *** NOTE: Must be defined upon entry.
!                        UNITS:      N/A
!                        TYPE:       Same as Predictor input argument.
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! COMMENTS:
!       The contents of the input adjoint arguments are modified upon exit.
!
!:sdoc-:
!------------------------------------------------------------------------------

  SUBROUTINE compute_odas_atmabsorption_ad( &
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    Predictor   , &  ! FWD Input
    AtmOptics_AD, &  ! AD  Input
    Predictor_AD, &  ! AD  Output
    iVar          )  ! Internal variable input
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODAS_Predictor_type), INTENT(IN)     :: Predictor
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics_AD
    TYPE(ODAS_Predictor_type), INTENT(IN OUT) :: Predictor_AD
    TYPE(iVar_type)          , INTENT(IN)     :: iVar
    ! Variables
    REAL(fp) :: optical_depth_AD( AtmOptics_AD%n_Layers)

    ! Adjoint of weighted average optical depth
    optical_depth_ad           = ivar%Weight(2)*atmoptics_ad%Optical_Depth
    atmoptics_ad%Optical_Depth = ivar%Weight(1)*atmoptics_ad%Optical_Depth

    ! Compute the adjoint of the optical depths
    ! ...At cell pressure #2
    CALL odas_compute_atmabsorption_ad( &
           tc(sensorindex)%ODAS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           atmoptics_ad                          , &
           predictor_ad                          , &
           ivar%ODAS(2)                            )
    atmoptics_ad%Optical_Depth = atmoptics_ad%Optical_Depth + optical_depth_ad
    ! ...At cell pressure #1
    CALL odas_compute_atmabsorption_ad( &
           tc(sensorindex)%ODAS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           atmoptics_ad                        , &
           predictor_ad                        , &
           ivar%ODAS(1)                          )

  END SUBROUTINE compute_odas_atmabsorption_ad


  SUBROUTINE compute_odps_atmabsorption_ad( &
    SensorIndex , &
    ChannelIndex, &
    Predictor   , &
    AtmOptics_AD, &
    Predictor_AD, &
    iVar          )
    ! Arguments
    INTEGER                  , INTENT(IN)     :: SensorIndex
    INTEGER                  , INTENT(IN)     :: ChannelIndex
    TYPE(ODPS_Predictor_type), INTENT(IN)     :: Predictor
    TYPE(CRTM_AtmOptics_type), INTENT(IN OUT) :: AtmOptics_AD
    TYPE(ODPS_Predictor_type), INTENT(IN OUT) :: Predictor_AD
    TYPE(iVar_type)          , INTENT(IN)     :: iVar
    ! Variables
    REAL(fp) :: optical_depth_AD( AtmOptics_AD%n_Layers)

    ! Adjoint of weighted average optical depth
    optical_depth_ad           = ivar%Weight(2)*atmoptics_ad%Optical_Depth
    atmoptics_ad%Optical_Depth = ivar%Weight(1)*atmoptics_ad%Optical_Depth

    ! Compute the adjoint of the optical depths
    ! ...At cell pressure #2
    CALL odps_compute_atmabsorption_ad( &
           tc(sensorindex)%ODPS(ivar%Index_low+1), &
           channelindex                          , &
           predictor                             , &
           atmoptics_ad                          , &
           predictor_ad                            )
    atmoptics_ad%Optical_Depth = atmoptics_ad%Optical_Depth + optical_depth_ad
    ! ...At cell pressure #1
    CALL odps_compute_atmabsorption_ad( &
           tc(sensorindex)%ODPS(ivar%Index_low), &
           channelindex                        , &
           predictor                           , &
           atmoptics_ad                        , &
           predictor_ad                          )

  END SUBROUTINE compute_odps_atmabsorption_ad



    SUBROUTINE get_co2_cell_p(SensorIndex,ChannelIndex,u,y0)
! -------------------------------------------------------------------
!  Using an sensor "SensorIndex" and time "u" to find CO2 cell pressure "y0".
! -------------------------------------------------------------------
       INTEGER, INTENT( IN ) :: SensorIndex, ChannelIndex
       REAL(fp), INTENT( IN ) :: u
       REAL(fp), INTENT( OUT ) :: y0
       INTEGER :: n, jLower, jUpper, indx

       n = SIZE(tc(sensorindex)%Ref_Time)
       jlower = 1
       jupper = n

       if(u.ge.tc(sensorindex)%Ref_Time(n)) then
         y0 = tc(sensorindex)%Ref_CellPressure(n,channelindex)
       return
       else if(u.le.tc(sensorindex)%Ref_Time(1)) then
         y0 = tc(sensorindex)%Ref_CellPressure(1,channelindex)
       return
       endif

       indx = bisection_search( tc(sensorindex)%Ref_Time, u )

       y0 = tc(sensorindex)%Ref_CellPressure(indx,channelindex) + &
          (tc(sensorindex)%Ref_CellPressure(indx+1,channelindex)- &
          tc(sensorindex)%Ref_CellPressure(indx,channelindex))/  &
          (tc(sensorindex)%Ref_Time(indx+1)-tc(sensorindex)%Ref_Time(indx))* &
          (u-tc(sensorindex)%Ref_Time(indx))
       RETURN
    END SUBROUTINE get_co2_cell_p
!

END MODULE odssu_atmabsorption