MWwaterLUT_Define.f90

Go to the documentation of this file.

!
! MWwaterLUT_Define
!
! Module defining the MWwaterLUT object containing the
! Look-Up Table (LUT) for the microWave (MW) sea surface emissivity
! model.
!
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 10-Nov-2011
!                       paul.vandelst@noaa.gov
!

MODULE mwwaterlut_define

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds           , ONLY: fp, long, double
  USE message_handler      , ONLY: success, failure, information, display_message
  USE compare_float_numbers, ONLY: OPERATOR(.equalto.)
  USE file_utility         , ONLY: file_open, file_exists
  USE binary_file_utility  , ONLY: open_binary_file      , &
                                   writegatts_binary_file, &
                                   readgatts_binary_file
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Datatypes
  PUBLIC :: mwwaterlut_type
  ! Operators
  PUBLIC :: OPERATOR(==)
  ! Procedures
  PUBLIC :: mwwaterlut_associated
  PUBLIC :: mwwaterlut_destroy
  PUBLIC :: mwwaterlut_create
  PUBLIC :: mwwaterlut_inspect
  PUBLIC :: mwwaterlut_validrelease
  PUBLIC :: mwwaterlut_info
  PUBLIC :: mwwaterlut_defineversion
  PUBLIC :: mwwaterlut_inquirefile
  PUBLIC :: mwwaterlut_readfile
  PUBLIC :: mwwaterlut_writefile


  ! ---------------------
  ! Procedure overloading
  ! ---------------------
  INTERFACE OPERATOR(==)
    MODULE PROCEDURE mwwaterlut_equal
  END INTERFACE OPERATOR(==)


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
    '$Id: MWwaterLUT_Define.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Release and version
  INTEGER, PARAMETER :: mwwaterlut_release = 1  ! This determines structure and file formats.
  INTEGER, PARAMETER :: mwwaterlut_version = 1  ! This is just the default data version.
  ! Close status for write errors
  CHARACTER(*), PARAMETER :: write_error_status = 'DELETE'
  ! Literal constants
  REAL(fp), PARAMETER :: zero = 0.0_fp
  REAL(fp), PARAMETER :: one  = 1.0_fp
  ! String lengths
  INTEGER,  PARAMETER :: ml = 256 ! Message length
  INTEGER,  PARAMETER :: sl =  80 ! String length


  ! ----------------------------------
  ! MWwaterLUT data type definitions
  ! ----------------------------------
  !:tdoc+:
  TYPE :: mwwaterlut_type
    ! Allocation indicator
    LOGICAL :: is_allocated = .false.
    ! Release and version information
    INTEGER(Long) :: release = mwwaterlut_release
    INTEGER(Long) :: version = mwwaterlut_version
    ! Dimensions
    INTEGER(Long) :: n_angles       = 0   ! I1 dimension
    INTEGER(Long) :: n_frequencies  = 0   ! I2 dimension
    INTEGER(Long) :: n_temperatures = 0   ! I3 dimension
    INTEGER(Long) :: n_wind_speeds  = 0   ! I4 dimension
    ! Dimensional vectors
    REAL(Double),  ALLOCATABLE :: angle(:)        ! I1
    REAL(Double),  ALLOCATABLE :: frequency(:)    ! I2
    REAL(Double),  ALLOCATABLE :: temperature(:)  ! I3
    REAL(Double),  ALLOCATABLE :: wind_speed(:)   ! I4
    ! Large-scale correction emissivity data
    REAL(Double),  ALLOCATABLE :: ev(:,:,:,:)  ! I1 x I2 x I3 x I4
    REAL(Double),  ALLOCATABLE :: eh(:,:,:,:)  ! I1 x I2 x I3 x I4
  END TYPE mwwaterlut_type
  !:tdoc-:


CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                           ## PUBLIC PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_Associated
!
! PURPOSE:
!       Pure function to test the status of the allocatable components
!       of the MWwaterLUT structure.
!
! CALLING SEQUENCE:
!       Status = MWwaterLUT_Associated( MWwaterLUT )
!
! OBJECTS:
!       MWwaterLUT:    Structure which is to have its member's
!                      status tested.
!                      UNITS:      N/A
!                      TYPE:       MWwaterLUT_type
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       Status:        The return value is a logical value indicating the
!                      status of the components.
!                       .TRUE.  - if ANY of the MWwaterLUT allocatable members
!                                 are in use.
!                       .FALSE. - if ALL of the MWwaterLUT allocatable members
!                                 are not in use.
!                      UNITS:      N/A
!                      TYPE:       LOGICAL
!                      DIMENSION:  Same as input
!
!:sdoc-:
!--------------------------------------------------------------------------------

  PURE FUNCTION mwwaterlut_associated( self ) RESULT( Status )
    TYPE(mwwaterlut_type), INTENT(IN) :: self
    LOGICAL :: status
    status = self%Is_Allocated
  END FUNCTION mwwaterlut_associated


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_Destroy
!
! PURPOSE:
!       Pure subroutine to re-initialize MWwaterLUT objects.
!
! CALLING SEQUENCE:
!       CALL MWwaterLUT_Destroy( MWwaterLUT )
!
! OBJECTS:
!       MWwaterLUT:    Re-initialized MWwaterLUT structure.
!                      UNITS:      N/A
!                      TYPE:       MWwaterLUT_type
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  PURE SUBROUTINE mwwaterlut_destroy( self )
    TYPE(mwwaterlut_type), INTENT(OUT) :: self
    self%Is_Allocated = .false.
    self%n_Angles       = 0
    self%n_Frequencies  = 0
    self%n_Temperatures = 0
    self%n_Wind_Speeds  = 0
  END SUBROUTINE mwwaterlut_destroy


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_Create
!
! PURPOSE:
!       Pure subroutine to create an instance of an MWwaterLUT object.
!
! CALLING SEQUENCE:
!       CALL MWwaterLUT_Create( MWwaterLUT    , &
!                               n_Angles      , &
!                               n_Frequencies , &
!                               n_Temperatures, &
!                               n_Wind_Speeds   )
!
! OBJECTS:
!       MWwaterLUT:         MWwaterLUT object structure.
!                           UNITS:      N/A
!                           TYPE:       MWwaterLUT_type
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT)
!
! INPUTS:
!       n_Angles:           Number of zenith angles for which is are data.
!                           Must be > 0.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!       n_Frequencies:      Number of spectral frequencies for which there are
!                           data.
!                           Must be > 0.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!       n_Temperatures:     Number of surface temperatures for which there are
!                           data.
!                           Must be > 0.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!       n_Wind_Speeds:      Number of surface wind speeds for which there are
!                           data.
!                           Must be > 0.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  PURE SUBROUTINE mwwaterlut_create( &
    self          , &  ! Output
    n_Angles      , &  ! Input
    n_Frequencies , &  ! Input
    n_Temperatures, &  ! Input
    n_Wind_Speeds   )  ! Input
    ! Arguments
    TYPE(mwwaterlut_type), INTENT(OUT) :: self
    INTEGER              , INTENT(IN)  :: n_angles
    INTEGER              , INTENT(IN)  :: n_frequencies
    INTEGER              , INTENT(IN)  :: n_temperatures
    INTEGER              , INTENT(IN)  :: n_wind_speeds
    ! Local variables
    INTEGER :: alloc_stat

    ! Check input
    IF ( n_angles       < 1 .OR. &
         n_frequencies  < 1 .OR. &
         n_temperatures < 1 .OR. &
         n_wind_speeds  < 1 ) RETURN


    ! Perform the allocation
    ALLOCATE( self%Angle( n_angles ), &
              self%Frequency( n_frequencies ), &
              self%Temperature( n_temperatures ), &
              self%Wind_Speed( n_wind_speeds ), &
              self%ev( n_angles, n_frequencies, n_temperatures, n_wind_speeds ), &
              self%eh( n_angles, n_frequencies, n_temperatures, n_wind_speeds ), &
              stat = alloc_stat )
    IF ( alloc_stat /= 0 ) RETURN


    ! Initialise
    ! ...Dimensions
    self%n_Angles       = n_angles
    self%n_Frequencies  = n_frequencies
    self%n_Temperatures = n_temperatures
    self%n_Wind_Speeds  = n_wind_speeds
    ! ...Arrays
    self%Angle       = zero
    self%Frequency   = zero
    self%Temperature = zero
    self%Wind_Speed  = zero
    self%ev          = zero
    self%eh          = zero

    ! Set allocation indicator
    self%Is_Allocated = .true.

  END SUBROUTINE mwwaterlut_create


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_Inspect
!
! PURPOSE:
!       Subroutine to print the contents of a MWwaterLUT object to stdout.
!
! CALLING SEQUENCE:
!       CALL MWwaterLUT_Inspect( MWwaterLUT )
!
! OBJECTS:
!       MWwaterLUT:     MWwaterLUT object to display.
!                       UNITS:      N/A
!                       TYPE:       MWwaterLUT_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE mwwaterlut_inspect( self, pause )
    TYPE(mwwaterlut_type), INTENT(IN) :: self
    LOGICAL,     OPTIONAL, INTENT(IN) :: pause
    LOGICAL :: wait
    INTEGER :: i2, i3, i4

    wait = .false.
    IF ( PRESENT(pause) ) wait = pause

    WRITE(*,'(1x,"MWwaterLUT OBJECT")')
    ! Release/version info
    WRITE(*,'(3x,"Release.Version : ",i0,".",i0)') self%Release, self%Version
    ! Dimensions
    WRITE(*,'(3x,"n_Angles        : ",i0)') self%n_Angles
    WRITE(*,'(3x,"n_Frequencies   : ",i0)') self%n_Frequencies
    WRITE(*,'(3x,"n_Temperatures  : ",i0)') self%n_Temperatures
    WRITE(*,'(3x,"n_Wind_Speeds   : ",i0)') self%n_Wind_Speeds
    IF ( .NOT. mwwaterlut_associated(self) ) RETURN
    ! Dimension arrays
    WRITE(*,'(3x,"Angle :")')
    WRITE(*,'(5(1x,es13.6,:))') self%Angle
    WRITE(*,'(3x,"Frequency :")')
    WRITE(*,'(5(1x,es13.6,:))') self%Frequency
    WRITE(*,'(3x,"Temperature :")')
    WRITE(*,'(5(1x,es13.6,:))') self%Temperature
    WRITE(*,'(3x,"Wind_Speed :")')
    WRITE(*,'(5(1x,es13.6,:))') self%Wind_Speed

    ! Emissivity arrays
    WRITE(*,'(/3x,"Emissivity(vertical polarisation) :")')
    IF ( wait ) THEN
      WRITE(*,fmt='(/1x,"Paused. Press <ENTER> to continue...")',advance='NO')
      READ(*,*)
    END IF

    DO i4 = 1, self%n_Wind_Speeds
      WRITE(*,'(5x,"WIND_SPEED  :",es13.6)') self%Wind_Speed(i4)
      DO i3 = 1, self%n_Temperatures
        WRITE(*,'(5x,"TEMPERATURE :",es13.6)') self%Temperature(i3)
        DO i2 = 1, self%n_Frequencies
          WRITE(*,'(5x,"FREQUENCY   :",es13.6)') self%Frequency(i2)
          WRITE(*,'(5(1x,es13.6,:))') self%ev(:,i2,i3,i4)
        END DO
      END DO
    END DO

    WRITE(*,'(/3x,"Emissivity(horizontal polarisation) :")')
    IF ( wait ) THEN
      WRITE(*,fmt='(/1x,"Paused. Press <ENTER> to continue...")',advance='NO')
      READ(*,*)
    END IF

    DO i4 = 1, self%n_Wind_Speeds
      WRITE(*,'(5x,"WIND_SPEED  :",es13.6)') self%Wind_Speed(i4)
      DO i3 = 1, self%n_Temperatures
        WRITE(*,'(5x,"TEMPERATURE :",es13.6)') self%Temperature(i3)
        DO i2 = 1, self%n_Frequencies
          WRITE(*,'(5x,"FREQUENCY   :",es13.6)') self%Frequency(i2)
          WRITE(*,'(5(1x,es13.6,:))') self%eh(:,i2,i3,i4)
        END DO
      END DO
    END DO
  END SUBROUTINE mwwaterlut_inspect



!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_ValidRelease
!
! PURPOSE:
!       Function to check the MWwaterLUT Release value.
!
! CALLING SEQUENCE:
!       IsValid = MWwaterLUT_ValidRelease( MWwaterLUT )
!
! INPUTS:
!       MWwaterLUT:     MWwaterLUT object for which the Release component
!                       is to be checked.
!                       UNITS:      N/A
!                       TYPE:       MWwaterLUT_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       IsValid:        Logical value defining the release validity.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION mwwaterlut_validrelease( self ) RESULT( IsValid )
    ! Arguments
    TYPE(mwwaterlut_type), INTENT(IN) :: self
    ! Function result
    LOGICAL :: isvalid
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'MWwaterLUT_ValidRelease'
    ! Local variables
    CHARACTER(ML) :: msg

    ! Set up
    isvalid = .true.


    ! Check release is not too old
    IF ( self%Release < mwwaterlut_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An MWwaterLUT data update is needed. ", &
                  &"MWwaterLUT release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, mwwaterlut_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF


    ! Check release is not too new
    IF ( self%Release > mwwaterlut_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An MWwaterLUT software update is needed. ", &
                  &"MWwaterLUT release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, mwwaterlut_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF

  END FUNCTION mwwaterlut_validrelease


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_Info
!
! PURPOSE:
!       Subroutine to return a string containing version and dimension
!       information about a MWwaterLUT object.
!
! CALLING SEQUENCE:
!       CALL MWwaterLUT_Info( MWwaterLUT, Info )
!
! OBJECTS:
!       MWwaterLUT:      MWwaterLUT object about which info is required.
!                        UNITS:      N/A
!                        TYPE:       MWwaterLUT_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Info:            String containing version and dimension information
!                        about the MWwaterLUT object.
!                        UNITS:      N/A
!                        TYPE:       CHARACTER(*)
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE mwwaterlut_info( self, Info )
    ! Arguments
    TYPE(mwwaterlut_type), INTENT(IN)  :: self
    CHARACTER(*)         , INTENT(OUT) :: info
    ! Parameters
    INTEGER, PARAMETER :: carriage_return = 13
    INTEGER, PARAMETER :: linefeed = 10
    ! Local variables
    CHARACTER(2000) :: long_string

    ! Write the required data to the local string
    WRITE( long_string, &
           '(a,1x,"MWwaterLUT RELEASE.VERSION: ",i2,".",i2.2,a,3x, &
           &"N_ANGLES=",i0,2x,&
           &"N_FREQUENCIES=",i0,2x,&
           &"N_TEMPERATURES=",i0,2x,&
           &"N_WIND_SPEEDS=",i0 )' ) &
           achar(carriage_return)//achar(linefeed), &
           self%Release, self%Version, &
           achar(carriage_return)//achar(linefeed), &
           self%n_Angles      , &
           self%n_Frequencies , &
           self%n_Temperatures, &
           self%n_Wind_Speeds

    ! Trim the output based on the
    ! dummy argument string length
    info = long_string(1:min(len(info), len_trim(long_string)))

  END SUBROUTINE mwwaterlut_info


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_DefineVersion
!
! PURPOSE:
!       Subroutine to return the module version information.
!
! CALLING SEQUENCE:
!       CALL MWwaterLUT_DefineVersion( Id )
!
! OUTPUTS:
!       Id:    Character string containing the version Id information
!              for the module.
!              UNITS:      N/A
!              TYPE:       CHARACTER(*)
!              DIMENSION:  Scalar
!              ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE mwwaterlut_defineversion( Id )
    CHARACTER(*), INTENT(OUT) :: id
    id = module_version_id
  END SUBROUTINE mwwaterlut_defineversion


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_InquireFile
!
! PURPOSE:
!       Function to inquire MWwaterLUT object files.
!
! CALLING SEQUENCE:
!       Error_Status = MWwaterLUT_InquireFile( &
!                        Filename                       , &
!                        n_Angles       = n_Angles      , &
!                        n_Frequencies  = n_Frequencies , &
!                        n_Temperatures = n_Temperatures, &
!                        n_Wind_Speeds  = n_Wind_Speeds , &
!                        Release        = Release       , &
!                        Version        = Version       , &
!                        Title          = Title         , &
!                        History        = History       , &
!                        Comment        = Comment         )
!
! INPUTS:
!       Filename:           Character string specifying the name of the
!                           data file to inquire.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
! OPTIONAL OUTPUTS:
!       n_Angles:           Number of zenith angles for which is are data.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       n_Frequencies:      Number of spectral frequencies for which there are
!                           data.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       n_Temperatures:     Number of surface temperatures for which there are
!                           data.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       n_Wind_Speeds:      Number of surface wind speeds for which there are
!                           data.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Release:            The data/file release number. Used to check
!                           for data/software mismatch.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Version:            The data/file version number. Used for
!                           purposes only in identifying the dataset for
!                           a particular release.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Title:              Character string containing a succinct description
!                           of what is in the dataset.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       History:            Character string containing dataset creation
!                           history.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Comment:            Character string containing any comments about
!                           the dataset.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:       The return value is an integer defining the error
!                           status. The error codes are defined in the
!                           Message_Handler module.
!                           If == SUCCESS the file inquire was successful
!                              == FAILURE an unrecoverable error occurred.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION mwwaterlut_inquirefile( &
    Filename      , &  ! Input
    n_Angles      , &  ! Optional output
    n_Frequencies , &  ! Optional output
    n_Temperatures, &  ! Optional output
    n_Wind_Speeds , &  ! Optional output
    Release       , &  ! Optional output
    Version       , &  ! Optional output
    Title         , &  ! Optional output
    History       , &  ! Optional output
    Comment       ) &  ! Optional output
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: filename
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_angles
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_frequencies
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_temperatures
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_wind_speeds
    INTEGER     , OPTIONAL, INTENT(OUT) :: release
    INTEGER     , OPTIONAL, INTENT(OUT) :: version
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'MWwaterLUT_InquireFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(mwwaterlut_type) :: mwwaterlut


    ! Setup
    err_stat = success
    ! ...Check that the file exists
    IF ( .NOT. file_exists( filename ) ) THEN
      msg = 'File '//trim(filename)//' not found.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Open the file
    err_stat = open_binary_file( filename, fid )
    IF ( err_stat /= success ) THEN
      msg = 'Error opening '//trim(filename)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%Release, &
      mwwaterlut%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF
    IF ( .NOT. mwwaterlut_validrelease( mwwaterlut ) ) THEN
      msg = 'MWwaterLUT Release check failed.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%n_Angles      , &
      mwwaterlut%n_Frequencies , &
      mwwaterlut%n_Temperatures, &
      mwwaterlut%n_Wind_Speeds
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading dimension values from '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Close the file
    CLOSE( fid, iostat=io_stat, iomsg=io_msg )
    IF ( io_stat /= 0 ) THEN
      msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Assign the return arguments
    IF ( PRESENT(n_angles      ) ) n_angles       = mwwaterlut%n_Angles
    IF ( PRESENT(n_frequencies ) ) n_frequencies  = mwwaterlut%n_Frequencies
    IF ( PRESENT(n_temperatures) ) n_temperatures = mwwaterlut%n_Temperatures
    IF ( PRESENT(n_wind_speeds ) ) n_wind_speeds  = mwwaterlut%n_Wind_Speeds
    IF ( PRESENT(release       ) ) release        = mwwaterlut%Release
    IF ( PRESENT(version       ) ) version        = mwwaterlut%Version

  CONTAINS

    SUBROUTINE inquire_cleanup()
      ! Close file if necessary
      IF ( file_open(fid) ) THEN
        CLOSE( fid, iostat=io_stat, iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      ! Set error status and print error message
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE inquire_cleanup

  END FUNCTION mwwaterlut_inquirefile


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_ReadFile
!
! PURPOSE:
!       Function to read MWwaterLUT object files.
!
! CALLING SEQUENCE:
!       Error_Status = MWwaterLUT_ReadFile( &
!                        MWwaterLUT         , &
!                        Filename           , &
!                        No_Close = No_Close, &
!                        Quiet    = Quiet   , &
!                        Title    = Title   , &
!                        History  = History , &
!                        Comment  = Comment   )
!
! OBJECTS:
!       MWwaterLUT:     MWwaterLUT object containing the data read from file.
!                       UNITS:      N/A
!                       TYPE:       MWwaterLUT_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT)
!
! INPUTS:
!       Filename:       Character string specifying the name of a
!                       MWwaterLUT data file to read.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       No_Close:       Set this logical argument to *NOT* close the datafile
!                       upon exiting this routine. This option is required if
!                       the MWwaterLUT data is embedded within another file.
!                       If == .FALSE., File is closed upon function exit [DEFAULT].
!                          == .TRUE.,  File is NOT closed upon function exit
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:          Set this logical argument to suppress INFORMATION
!                       messages being printed to stdout
!                       If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                          == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
! OPTIONAL OUTPUTS:
!       Title:          Character string containing a succinct description
!                       of what is in the dataset.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       History:        Character string containing dataset creation
!                       history.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Comment:        Character string containing any comments about
!                       the dataset.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:   The return value is an integer defining the error status.
!                       The error codes are defined in the Message_Handler module.
!                       If == SUCCESS, the file read was successful
!                          == FAILURE, an unrecoverable error occurred.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION mwwaterlut_readfile( &
    MWwaterLUT, &  ! Output
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional output
    History   , &  ! Optional output
    Comment   , &  ! Optional output
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(mwwaterlut_type) , INTENT(OUT) :: mwwaterlut
    CHARACTER(*),           INTENT(IN)  :: filename
    LOGICAL     , OPTIONAL, INTENT(IN)  :: no_close
    LOGICAL     , OPTIONAL, INTENT(IN)  :: quiet
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment
    LOGICAL     , OPTIONAL, INTENT(IN)  :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'MWwaterLUT_ReadFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(mwwaterlut_type) :: dummy

    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF


    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL read_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file if it exists
      IF ( file_exists( filename ) ) THEN
        err_stat = open_binary_file( filename, fid )
        IF ( err_stat /= success ) THEN
          msg = 'Error opening '//trim(filename)
          CALL read_cleanup(); RETURN
        END IF
      ELSE
        msg = 'File '//trim(filename)//' not found.'
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Read and check the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%Release, &
      dummy%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    IF ( .NOT. mwwaterlut_validrelease( dummy ) ) THEN
      msg = 'MWwaterLUT Release check failed.'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%n_Angles      , &
      dummy%n_Frequencies , &
      dummy%n_Temperatures, &
      dummy%n_Wind_Speeds
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading data dimensions - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Allocate the object
    CALL mwwaterlut_create( &
           mwwaterlut       , &
           dummy%n_Angles      , &
           dummy%n_Frequencies , &
           dummy%n_Temperatures, &
           dummy%n_Wind_Speeds   )
    IF ( .NOT. mwwaterlut_associated( mwwaterlut ) ) THEN
      msg = 'MWwaterLUT object allocation failed.'
      CALL read_cleanup(); RETURN
    END IF
    ! ...Explicitly assign the version number
    mwwaterlut%Version = dummy%Version


    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the coefficient data
    ! ...Read the dimensional vectors
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%Angle      , &
      mwwaterlut%Frequency  , &
      mwwaterlut%Temperature, &
      mwwaterlut%Wind_Speed
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading dimensional vectors - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Read the emissivity data
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%ev, &
      mwwaterlut%eh
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading emissivity data - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
    IF ( noisy ) THEN
      CALL mwwaterlut_info( mwwaterlut, msg )
      CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
    END IF

  CONTAINS

    SUBROUTINE read_cleanup()
      IF ( file_open(filename) ) THEN
        CLOSE( fid, iostat=io_stat, iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      CALL mwwaterlut_destroy( mwwaterlut )
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE read_cleanup

  END FUNCTION mwwaterlut_readfile


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       MWwaterLUT_WriteFile
!
! PURPOSE:
!       Function to write MWwaterLUT object files.
!
! CALLING SEQUENCE:
!       Error_Status = MWwaterLUT_WriteFile( &
!                        MWwaterLUT         , &
!                        Filename           , &
!                        No_Close = No_Close, &
!                        Quiet    = Quiet     )
!
! OBJECTS:
!       MWwaterLUT:     Object containing the data to write to file.
!                       UNITS:      N/A
!                       TYPE:       MWwaterLUT_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! INPUTS:
!       Filename:       Character string specifying the name of a
!                       MWwaterLUT format data file to write.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       No_Close:       Set this logical argument to *NOT* close the datafile
!                       upon exiting this routine. This option is required if
!                       the MWwaterLUT data is to be embedded within another file.
!                       If == .FALSE., File is closed upon function exit [DEFAULT].
!                          == .TRUE.,  File is NOT closed upon function exit
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:          Set this logical argument to suppress INFORMATION
!                       messages being printed to stdout
!                       If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                          == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Title:          Character string containing a succinct description
!                       of what is in the dataset.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       History:        Character string containing dataset creation
!                       history.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Comment:        Character string containing any comments about
!                       the dataset.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:   The return value is an integer defining the error status.
!                       The error codes are defined in the Message_Handler module.
!                       If == SUCCESS, the file write was successful
!                          == FAILURE, an unrecoverable error occurred.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION mwwaterlut_writefile( &
    MWwaterLUT, &  ! Input
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional input
    History   , &  ! Optional input
    Comment   , &  ! Optional input
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(mwwaterlut_type) , INTENT(IN) :: mwwaterlut
    CHARACTER(*),           INTENT(IN) :: filename
    LOGICAL     , OPTIONAL, INTENT(IN) :: no_close
    LOGICAL     , OPTIONAL, INTENT(IN) :: quiet
    CHARACTER(*), OPTIONAL, INTENT(IN) :: title
    CHARACTER(*), OPTIONAL, INTENT(IN) :: history
    CHARACTER(*), OPTIONAL, INTENT(IN) :: comment
    LOGICAL     , OPTIONAL, INTENT(IN) :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'MWwaterLUT_WriteFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid


    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF
    ! ...Check there is data to write
    IF ( .NOT. mwwaterlut_associated( mwwaterlut ) ) THEN
      msg = 'MWwaterLUT object is empty.'
      CALL write_cleanup(); RETURN
    END IF


    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL write_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file for output
      err_stat = open_binary_file( filename, fid, for_output=.true. )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Write the release and version
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%Release, &
      mwwaterlut%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing Release/Version - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the dimensions
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%n_Angles      , &
      mwwaterlut%n_Frequencies , &
      mwwaterlut%n_Temperatures, &
      mwwaterlut%n_Wind_Speeds
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing data dimensions - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the global attributes
    err_stat = writegatts_binary_file( &
                 fid, &
                 write_module = module_version_id, &
                 title        = title  , &
                 history      = history, &
                 comment      = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error writing global attributes'
      CALL write_cleanup(); RETURN
    END IF


    ! Write the coefficient data
    ! ...Write the dimensional vectors
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%Angle      , &
      mwwaterlut%Frequency  , &
      mwwaterlut%Temperature, &
      mwwaterlut%Wind_Speed
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing dimensional vectors - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Write the emissivity data
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      mwwaterlut%ev, &
      mwwaterlut%eh
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing the emissivity data - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL mwwaterlut_info( mwwaterlut, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS

     SUBROUTINE write_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid, status=write_error_status, iostat=io_stat, iomsg=io_msg )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing output file during error cleanup - '//trim(io_msg)
       END IF
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE write_cleanup

  END FUNCTION mwwaterlut_writefile


!################################################################################
!################################################################################
!##                                                                            ##
!##                          ## PRIVATE PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

!--------------------------------------------------------------------------------
!
! NAME:
!       MWwaterLUT_Equal
!
! PURPOSE:
!       Pure function to test the equality of two MWwaterLUT objects.
!       Used in OPERATOR(==) interface block.
!
! CALLING SEQUENCE:
!       is_equal = MWwaterLUT_Equal( x, y )
!
!         or
!
!       IF ( x == y ) THEN
!         ...
!       END IF
!
! OBJECTS:
!       x, y:          Two MWwaterLUT objects to be compared.
!                      UNITS:      N/A
!                      TYPE:       MWwaterLUT_type
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       is_equal:      Logical value indicating whether the inputs are equal.
!                      UNITS:      N/A
!                      TYPE:       LOGICAL
!                      DIMENSION:  Same as inputs.
!
!--------------------------------------------------------------------------------

  PURE FUNCTION mwwaterlut_equal( x, y ) RESULT( is_equal )
    TYPE(mwwaterlut_type), INTENT(IN) :: x, y
    LOGICAL :: is_equal

    ! Set up
    is_equal = .false.

    ! Check the object association status
    IF ( (.NOT. mwwaterlut_associated(x)) .OR. &
         (.NOT. mwwaterlut_associated(y))      ) RETURN

   ! Check contents
    ! ...Release/version info
    IF ( (x%Release /= y%Release) .OR. &
         (x%Version /= y%Version) ) RETURN
    ! ...Dimensions
    IF ( (x%n_Angles       /= y%n_Angles       ) .OR. &
         (x%n_Frequencies  /= y%n_Frequencies  ) .OR. &
         (x%n_Temperatures /= y%n_Temperatures ) .OR. &
         (x%n_Wind_Speeds  /= y%n_Wind_Speeds  ) ) RETURN
    ! ...Arrays
    IF ( all(x%Angle       .equalto. y%Angle       ) .AND. &
         all(x%Frequency   .equalto. y%Frequency   ) .AND. &
         all(x%Temperature .equalto. y%Temperature ) .AND. &
         all(x%Wind_Speed  .equalto. y%Wind_Speed  ) .AND. &
         all(x%ev          .equalto. y%ev          ) .AND. &
         all(x%eh          .equalto. y%eh          ) ) &
      is_equal = .true.

  END FUNCTION mwwaterlut_equal

END MODULE mwwaterlut_define