ACCoeff_Binary_IO.f90

Go to the documentation of this file.

!
! ACCoeff_Binary_IO
!
! Module containing routines to read and write Binary format
! ACCoeff data files.
!
!
! CREATION HISTORY:
!       Written by:  Paul van Delst, 08-Jun-2007
!                    paul.vandelst@noaa.gov
!

MODULE accoeff_binary_io

  ! ------------------
  ! Environment set up
  ! ------------------
  ! Module use
  USE type_kinds         , ONLY: long, double
  USE file_utility       , ONLY: file_open, file_exists
  USE message_handler    , ONLY: success, failure, information, display_message
  USE binary_file_utility, ONLY: open_binary_file
  USE accoeff_define     , ONLY: accoeff_type          , &
                                 accoeff_associated    , &
                                 accoeff_destroy       , &
                                 accoeff_create        , &
                                 accoeff_validrelease  , &
                                 accoeff_info
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  PRIVATE
  PUBLIC :: accoeff_binary_inquirefile
  PUBLIC :: accoeff_binary_readfile
  PUBLIC :: accoeff_binary_writefile
  PUBLIC :: accoeff_binary_ioversion


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PRIVATE, PARAMETER :: module_version_id = &
    '$Id: ACCoeff_Binary_IO.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  CHARACTER(*), PARAMETER :: write_error_status = 'DELETE'
  ! Default message length
  INTEGER, PARAMETER :: ml = 256


CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                         ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################

!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ACCoeff_Binary_InquireFile
!
! PURPOSE:
!       Function to inquire a Binary format ACCoeff file.
!
! CALLING SEQUENCE:
!       Error_Status = ACCoeff_Binary_InquireFile( &
!                        Filename                           , &
!                        n_FOVs           = n_FOVs          , &
!                        n_Channels       = n_Channels      , &
!                        Release          = Release         , &
!                        Version          = Version         , &
!                        Sensor_Id        = Sensor_Id       , &
!                        WMO_Satellite_Id = WMO_Satellite_Id, &
!                        WMO_Sensor_Id    = WMO_Sensor_Id     )
!
! INPUTS:
!       Filename:           Character string specifying the name of the binary
!                           antenna correction data file to inquire.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
! OPTIONAL OUTPUTS:
!       n_FOVs:             Number of sensor fields-of-view (FOVs).
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!       n_Channels:         Number of sensor channels.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!       Release:            The data/file release number. Used to check
!                           for data/software mismatch.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Version:            The data/file version number. Used for
!                           purposes only in identifying the dataset for
!                           a particular release.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Sensor_Id:          Character string sensor/platform identifier.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       WMO_Satellite_Id:   The WMO code used to identify satellite platforms.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       WMO_Sensor_Id:      The WMO code used to identify sensors.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(OUT), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:       The return value is an integer defining the error
!                           status. The error codes are defined in the
!                           Message_Handler module.
!                           If == SUCCESS the file inquire was successful
!                              == FAILURE an unrecoverable error occurred.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION accoeff_binary_inquirefile( &
    Filename        , &  ! Input
    n_FOVs          , &  ! Optional output  
    n_Channels      , &  ! Optional output  
    Release         , &  ! Optional Output
    Version         , &  ! Optional Output
    Sensor_Id       , &  ! Optional Output
    WMO_Satellite_Id, &  ! Optional Output
    WMO_Sensor_Id   ) &  ! Optional Output
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: filename
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_fovs
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_channels
    INTEGER     , OPTIONAL, INTENT(OUT) :: release
    INTEGER     , OPTIONAL, INTENT(OUT) :: version
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: sensor_id       
    INTEGER     , OPTIONAL, INTENT(OUT) :: wmo_satellite_id
    INTEGER     , OPTIONAL, INTENT(OUT) :: wmo_sensor_id   
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ACCoeff_InquireFile(Binary)'
    ! Function variables
    CHARACTER(ML) :: msg
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(accoeff_type) :: accoeff

 
    ! Setup
    err_stat = success
    ! ...Check that the file exists
    IF ( .NOT. file_exists( filename ) ) THEN
      msg = 'File '//trim(filename)//' not found.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Open the file
    err_stat = open_binary_file( filename, fid )
    IF ( err_stat /= success ) THEN
      msg = 'Error opening '//trim(filename)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the release and version
    READ( fid,iostat=io_stat ) accoeff%Release, accoeff%Version
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading Release/Version. IOSTAT = ",i0)' ) io_stat
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat ) &
      accoeff%n_FOVs    , &
      accoeff%n_Channels
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading dimension values from ",a,". IOSTAT = ",i0)' ) &
             trim(filename), io_stat
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the sensor ids
    READ( fid, iostat=io_stat ) &
      accoeff%Sensor_Id       , &
      accoeff%WMO_Satellite_Id, &
      accoeff%WMO_Sensor_Id    
    IF ( io_stat /= 0 ) THEN
      WRITE( msg, '("Error reading sensor information from ",a,". IOSTAT = ",i0)' ) &
             trim(filename), io_stat
      CALL inquire_cleanup(); RETURN
    END IF


    ! Close the file
    CLOSE( fid, iostat=io_stat )
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error closing ",a,". IOSTAT = ",i0)' ) trim(filename), io_stat
      CALL inquire_cleanup(); RETURN
    END IF


    ! Assign the return arguments
    IF ( PRESENT(n_fovs          ) ) n_fovs           = accoeff%n_FOVs
    IF ( PRESENT(n_channels      ) ) n_channels       = accoeff%n_Channels    
    IF ( PRESENT(release         ) ) release          = accoeff%Release
    IF ( PRESENT(version         ) ) version          = accoeff%Version
    IF ( PRESENT(sensor_id       ) ) sensor_id        = trim(accoeff%Sensor_Id)
    IF ( PRESENT(wmo_satellite_id) ) wmo_satellite_id = accoeff%WMO_Satellite_Id
    IF ( PRESENT(wmo_sensor_id   ) ) wmo_sensor_id    = accoeff%WMO_Sensor_Id   
    
  CONTAINS
  
    SUBROUTINE inquire_cleanup()
      ! Close file if necessary
      IF ( file_open(fid) ) THEN
        CLOSE( fid,iostat=io_stat )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup'
      END IF
      ! Set error status and print error message
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE inquire_cleanup
    
  END FUNCTION accoeff_binary_inquirefile


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ACCoeff_Binary_ReadFile
!
! PURPOSE:
!       Function to read ACCoeff object files in Binary format.
!
! CALLING SEQUENCE:
!       Error_Status = ACCoeff_Binary_ReadFile( &
!                        Filename           , &
!                        ACCoeff            , &
!                        No_Close = No_Close, &
!                        Quiet    = Quiet     )
!
! INPUTS:
!       Filename:       Character string specifying the name of a
!                       ACCoeff format data file to read.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       ACCoeff:        ACCoeff object containing the antenna correction
!                       coefficient data.
!                       UNITS:      N/A
!                       TYPE:       ACCoeff_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT)
!
! OPTIONAL INPUTS:
!       No_Close:       Set this logical argument to *NOT* close the datafile
!                       upon exiting this routine. This option is required if
!                       the ACCoeff data is embedded within another file
!                       (e.g. SpcCoeff file.)
!                       If == .FALSE., File is closed upon function exit [DEFAULT].
!                          == .TRUE.,  File is NOT closed upon function exit
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:          Set this logical argument to suppress INFORMATION
!                       messages being printed to stdout
!                       If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                          == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:   The return value is an integer defining the error status.
!                       The error codes are defined in the Message_Handler module.
!                       If == SUCCESS, the file read was successful
!                          == FAILURE, an unrecoverable error occurred.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION accoeff_binary_readfile( &
    Filename, &  ! Input
    ACCoeff , &  ! Output
    No_Close, &  ! Optional input
    Quiet   , &  ! Optional input
    Debug   ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    CHARACTER(*),       INTENT(IN)  :: filename
    TYPE(accoeff_type), INTENT(OUT) :: accoeff
    LOGICAL,  OPTIONAL, INTENT(IN)  :: no_close
    LOGICAL,  OPTIONAL, INTENT(IN)  :: quiet
    LOGICAL,  OPTIONAL, INTENT(IN)  :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ACCoeff_ReadFile(Binary)'
    ! Function variables
    CHARACTER(ML) :: msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(accoeff_type) :: dummy
    

    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL read_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file if it exists
      IF ( file_exists( filename ) ) THEN
        err_stat = open_binary_file( filename, fid )
        IF ( err_stat /= success ) THEN
          msg = 'Error opening '//trim(filename)
          CALL read_cleanup(); RETURN
        END IF
      ELSE
        msg = 'File '//trim(filename)//' not found.'
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Read and check the release and version
    READ( fid,iostat=io_stat ) dummy%Release, dummy%Version
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading Release/Version. IOSTAT = ",i0)' ) io_stat
      CALL read_cleanup(); RETURN
    END IF
    IF ( .NOT. accoeff_validrelease( dummy ) ) THEN
      msg = 'ACCoeff Release check failed.'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the antenna correction coefficient data
    ! ...Read the dimensions
    READ( fid, iostat=io_stat ) dummy%n_FOVs    , &
                                dummy%n_Channels
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading data dimensions. IOSTAT = ",i0)' ) io_stat
      CALL read_cleanup(); RETURN
    END IF
    ! ...Allocate the object
    CALL accoeff_create( accoeff         , &
                         dummy%n_FOVs    , &        
                         dummy%n_Channels  )                  
    IF ( .NOT. accoeff_associated( accoeff ) ) THEN
      msg = 'ACCoeff object allocation failed.'
      CALL read_cleanup(); RETURN
    END IF
    ! ...Read the sensor ids
    READ( fid, iostat=io_stat ) accoeff%Sensor_Id       , &
                                accoeff%WMO_Satellite_Id, &
                                accoeff%WMO_Sensor_Id   
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading sensor ids. IOSTAT = ",i0)' ) io_stat
      CALL read_cleanup(); RETURN
    END IF
    ! ...Read the sensor channels
    READ( fid, iostat=io_stat ) accoeff%Sensor_Channel
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading sensor channels. IOSTAT = ",i0)' ) io_stat
      CALL read_cleanup(); RETURN
    END IF
    ! ...Read the antenna correction coefficients
    READ( fid, iostat=io_stat ) accoeff%A_earth   , &
                                accoeff%A_space   , &
                                accoeff%A_platform
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error reading antenna correction coefficients. IOSTAT = ",i0)' ) io_stat
      CALL read_cleanup(); RETURN
    END IF


    ! Explicitly assign the version number
    accoeff%Version = dummy%Version
    
    
    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid,iostat=io_stat )
      IF ( io_stat /= 0 ) THEN
        WRITE( msg,'("Error closing ",a,". IOSTAT = ",i0)' ) trim(filename), io_stat
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL accoeff_info( accoeff, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE read_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid,iostat=io_stat )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing input file during error cleanup.'
       END IF
       CALL accoeff_destroy( accoeff )
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE read_cleanup

  END FUNCTION accoeff_binary_readfile


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ACCoeff_Binary_WriteFile
!
! PURPOSE:
!       Function to write ACCoeff object files in Binary format.
!
! CALLING SEQUENCE:
!       Error_Status = ACCoeff_Binary_WriteFile( &
!                        Filename           , &
!                        ACCoeff            , &
!                        No_Close = No_Close, &
!                        Quiet    = Quiet     )
!
! INPUTS:
!       Filename:       Character string specifying the name of a
!                       ACCoeff format data file to read.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       ACCoeff:        ACCoeff object containing the antenna correction
!                       coefficient data.
!                       UNITS:      N/A
!                       TYPE:       ACCoeff_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT)
!
! OPTIONAL INPUTS:
!       No_Close:       Set this logical argument to *NOT* close the datafile
!                       upon exiting this routine. This option is required if
!                       the ACCoeff data is to be embedded within another file
!                       (e.g. SpcCoeff file.)
!                       If == .FALSE., File is closed upon function exit [DEFAULT].
!                          == .TRUE.,  File is NOT closed upon function exit
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:          Set this logical argument to suppress INFORMATION
!                       messages being printed to stdout
!                       If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                          == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                       If not specified, default is .FALSE.
!                       UNITS:      N/A
!                       TYPE:       LOGICAL
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:   The return value is an integer defining the error status.
!                       The error codes are defined in the Message_Handler module.
!                       If == SUCCESS, the file write was successful
!                          == FAILURE, an unrecoverable error occurred.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION accoeff_binary_writefile( &
    Filename, &  ! Input
    ACCoeff , &  ! Input
    No_Close, &  ! Optional input
    Quiet   , &  ! Optional input
    Debug   ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    CHARACTER(*),       INTENT(IN) :: filename
    TYPE(accoeff_type), INTENT(IN) :: accoeff
    LOGICAL,  OPTIONAL, INTENT(IN) :: no_close
    LOGICAL,  OPTIONAL, INTENT(IN) :: quiet
    LOGICAL,  OPTIONAL, INTENT(IN) :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ACCoeff_WriteFile(Binary)'
    ! Function variables
    CHARACTER(ML) :: msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    

    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF
    ! ...Check there is data to write
    IF ( .NOT. accoeff_associated( accoeff ) ) THEN
      msg = 'ACCoeff object is empty.'
      CALL write_cleanup(); RETURN
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL write_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file for output
      err_stat = open_binary_file( filename, fid, for_output=.true. )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Write the release and version
    WRITE( fid,iostat=io_stat ) accoeff%Release, accoeff%Version
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error writing Release/Version. IOSTAT = ",i0)' ) io_stat
      CALL write_cleanup(); RETURN
    END IF


    ! Write the antenna correction coefficient data
    ! ...Write the dimensions
    WRITE( fid, iostat=io_stat ) accoeff%n_FOVs    , &
                                 accoeff%n_Channels
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error writing data dimensions. IOSTAT = ",i0)' ) io_stat
      CALL write_cleanup(); RETURN
    END IF
    ! ...Write the sensor info
    WRITE( fid, iostat=io_stat ) accoeff%Sensor_Id       , &
                                 accoeff%WMO_Satellite_Id, &
                                 accoeff%WMO_Sensor_Id   
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error writing sensor ids. IOSTAT = ",i0)' ) io_stat
      CALL write_cleanup(); RETURN
    END IF
    ! ...Write the sensor channels
    WRITE( fid, iostat=io_stat ) accoeff%Sensor_Channel
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error writing sensor channels. IOSTAT = ",i0)' ) io_stat
      CALL write_cleanup(); RETURN
    END IF
    ! ...Write the antenna correction coefficients
    WRITE( fid, iostat=io_stat ) accoeff%A_earth   , &
                                 accoeff%A_space   , &
                                 accoeff%A_platform
    IF ( io_stat /= 0 ) THEN
      WRITE( msg,'("Error writing antenna correction coefficients. IOSTAT = ",i0)' ) io_stat
      CALL write_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid,iostat=io_stat )
      IF ( io_stat /= 0 ) THEN
        WRITE( msg,'("Error closing ",a,". IOSTAT = ",i0)' ) trim(filename), io_stat
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL accoeff_info( accoeff, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE write_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid,iostat=io_stat )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing input file during error cleanup.'
       END IF
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE write_cleanup

  END FUNCTION accoeff_binary_writefile


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       ACCoeff_Binary_IOVersion
!
! PURPOSE:
!       Subroutine to return the module version information.
!
! CALLING SEQUENCE:
!       CALL ACCoeff_Binary_IOVersion( Id )
!
! OUTPUT ARGUMENTS:
!       Id:   Character string containing the version Id information
!             for the module.
!             UNITS:      N/A
!             TYPE:       CHARACTER(*)
!             DIMENSION:  Scalar
!             ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE accoeff_binary_ioversion( Id )
    CHARACTER(*), INTENT(OUT) :: id
    id = module_version_id
  END SUBROUTINE accoeff_binary_ioversion
  
END MODULE accoeff_binary_io