CSvar_Define.f90

Go to the documentation of this file.

! 
! CSvar_Define
!
! Module defining the CRTM CloudScatter module internal
! variable object.
! 
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 14-Feb-2012
!                       paul.vandelst@noaa.gov
!                       

MODULE csvar_define

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds           , ONLY: fp
  USE message_handler      , ONLY: success, failure, information, display_message
  USE compare_float_numbers, ONLY: OPERATOR(.equalto.)
  USE file_utility         , ONLY: file_open, file_exists
  USE binary_file_utility  , ONLY: open_binary_file      , &
                                   writegatts_binary_file, &
                                   readgatts_binary_file
  USE crtm_interpolation   , ONLY: npts      , &
                                   lpoly_type
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Datatypes
  PUBLIC :: csvar_type
  PUBLIC :: csinterp_type
  ! Operators
  PUBLIC :: OPERATOR(==)
  ! Procedures
  PUBLIC :: csvar_associated
  PUBLIC :: csvar_destroy
  PUBLIC :: csvar_create
  PUBLIC :: csvar_inspect
  PUBLIC :: csvar_validrelease
  PUBLIC :: csvar_info
  PUBLIC :: csvar_defineversion
  PUBLIC :: csvar_inquirefile
  PUBLIC :: csvar_readfile
  PUBLIC :: csvar_writefile


  ! ---------------------
  ! Procedure overloading
  ! ---------------------
  INTERFACE OPERATOR(==)
    MODULE PROCEDURE csvar_equal
  END INTERFACE OPERATOR(==)


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
    '$Id: CSvar_Define.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Release and version
  INTEGER, PARAMETER :: csvar_release = 1  ! This determines structure and file formats.
  INTEGER, PARAMETER :: csvar_version = 1  ! This is just the default data version.
  ! Close status for write errors
  CHARACTER(*), PARAMETER :: write_error_status = 'DELETE'
  ! Literal constants
  REAL(fp), PARAMETER :: zero = 0.0_fp
  REAL(fp), PARAMETER :: one  = 1.0_fp
  ! String lengths
  INTEGER,  PARAMETER :: ml = 256 ! Message length
  INTEGER,  PARAMETER :: sl =  80 ! String length

  
  ! ---------------------
  ! Structure definitions
  ! ---------------------
  ! The interpolation routine structure
  TYPE :: csinterp_type
    ! The interpolating polynomials
    TYPE(lpoly_type) :: wlp  ! Frequency
    TYPE(lpoly_type) :: xlp  ! Effective radius
    TYPE(lpoly_type) :: ylp  ! Temperature
    ! The LUT interpolation indices
    INTEGER :: i1, i2        ! Frequency
    INTEGER :: j1, j2        ! Effective radius
    INTEGER :: k1, k2        ! Temperature
    ! The LUT interpolation boundary check
    LOGICAL :: f_outbound    ! Frequency
    LOGICAL :: r_outbound    ! Effective radius
    LOGICAL :: t_outbound    ! Temperature
    ! The interpolation input
    REAL(fp) :: f_int        ! Frequency
    REAL(fp) :: r_int        ! Effective radius
    REAL(fp) :: t_int        ! Temperature
    ! The data to be interpolated
    REAL(fp) :: f(npts)      ! Frequency
    REAL(fp) :: r(npts)      ! Effective radius
    REAL(fp) :: t(npts)      ! Temperature
  END TYPE csinterp_type
  
  
  ! The internal variable definition to hold information
  ! between FWD, TL, AD, and K-matrix calls
  TYPE :: csvar_type
    ! Allocation indicator
    LOGICAL :: is_allocated = .false.
    ! Release and version information
    INTEGER :: release = csvar_release
    INTEGER :: version = csvar_version
    ! Dimensions
    INTEGER :: n_legendre_terms = 0  ! I1
    INTEGER :: n_phase_elements = 0  ! I2
    INTEGER :: n_layers         = 0  ! I3
    INTEGER :: n_clouds         = 0  ! I4
    ! The interpolating data
    TYPE(csinterp_type), ALLOCATABLE :: csi(:,:)  ! I3 x I4
    ! The interpolation results
    REAL(fp), ALLOCATABLE :: ke(:,:)          ! I3 x I4  Mass extinction coefficient
    REAL(fp), ALLOCATABLE :: w(:,:)           ! I3 x I4  Single Scatter Albedo
    REAL(fp), ALLOCATABLE :: g(:,:)           ! I3 x I4  Asymmetry factor
    REAL(fp), ALLOCATABLE :: pcoeff(:,:,:,:)  ! 0:I1 x I2 x I3 x I4  Phase coefficients
    ! The accumulated scattering coefficient
    REAL(fp), ALLOCATABLE :: total_bs(:)      ! I3  Volume scattering coefficient
  END TYPE csvar_type


CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                           ## PUBLIC PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

  ELEMENTAL FUNCTION csvar_associated( self ) RESULT( Status )
    TYPE(csvar_type), INTENT(IN) :: self
    LOGICAL :: status
    status = self%Is_Allocated
  END FUNCTION csvar_associated

 
  ELEMENTAL SUBROUTINE csvar_destroy( self )
    TYPE(csvar_type), INTENT(OUT) :: self
    self%Is_Allocated = .false.
    self%n_Legendre_Terms = 0
    self%n_Phase_Elements = 0
    self%n_Layers         = 0
    self%n_Clouds         = 0
  END SUBROUTINE csvar_destroy
  
  
  ELEMENTAL SUBROUTINE csvar_create( &
    self            , &  ! Output
    n_Legendre_Terms, &  ! Input
    n_Phase_Elements, &  ! Input
    n_Layers        , &  ! Input
    n_Clouds          )  ! Input
    ! Arguments
    TYPE(csvar_type), INTENT(OUT) :: self
    INTEGER         , INTENT(IN)  :: n_legendre_terms        
    INTEGER         , INTENT(IN)  :: n_phase_elements             
    INTEGER         , INTENT(IN)  :: n_layers                
    INTEGER         , INTENT(IN)  :: n_clouds                   
    ! Local variables
    INTEGER :: alloc_stat

    ! Check input
    IF ( n_legendre_terms < 1 .OR. &
         n_phase_elements < 1 .OR. &
         n_layers         < 1 .OR. &
         n_clouds         < 1 ) RETURN

    ! Perform the allocation
    ALLOCATE( self%csi(n_layers, n_clouds), &
              self%ke(n_layers, n_clouds), &
              self%w(n_layers, n_clouds), &
              self%g(n_layers, n_clouds), &
              self%pcoeff(0:n_legendre_terms,n_phase_elements,n_layers, n_clouds), &
              self%total_bs(n_layers), &
              stat = alloc_stat )
    IF ( alloc_stat /= 0 ) RETURN


    ! Initialise dimensions only!
    self%n_Legendre_Terms = n_legendre_terms
    self%n_Phase_Elements = n_phase_elements
    self%n_Layers         = n_layers        
    self%n_Clouds       = n_clouds      

    ! Set allocation indicator
    self%Is_Allocated = .true.
  END SUBROUTINE csvar_create
  
  
  SUBROUTINE csvar_inspect( self)
    TYPE(csvar_type), INTENT(IN) :: self
    INTEGER :: i2, i3, i4
    WRITE(*,'(1x,"CSvar OBJECT")')

    ! Release/version info
    WRITE(*,'(3x,"Release.Version     :",1x,i0,".",i0)') self%Release, self%Version

    ! Dimensions
    WRITE(*,'(3x,"n_Legendre_Terms    :",1x,i0)') self%n_Legendre_Terms
    WRITE(*,'(3x,"n_Phase_Elements    :",1x,i0)') self%n_Phase_Elements
    WRITE(*,'(3x,"n_Layers            :",1x,i0)') self%n_Layers        
    WRITE(*,'(3x,"n_Clouds            :",1x,i0)') self%n_Clouds      
    IF ( .NOT. csvar_associated(self) ) RETURN

    ! Data
    WRITE(*,'(3x,"Mass extinction coefficient (ke) :")')
    DO i4 = 1, self%n_Clouds
      WRITE(*,'(5x,"ke Cloud index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%ke(:,i4)
    END DO
    WRITE(*,'(3x,"Single scatter albedo (w) :")')
    DO i4 = 1, self%n_Clouds
      WRITE(*,'(5x,"w Cloud index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%w(:,i4)
    END DO
    WRITE(*,'(3x,"Asymmetry factor (g) :")')
    DO i4 = 1, self%n_Clouds
      WRITE(*,'(5x,"g Cloud index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%g(:,i4)
    END DO
    WRITE(*,'(3x,"Phase coefficients (pcoeff) :")')
    DO i4 = 1, self%n_Clouds
      WRITE(*,'(5x,"pcoeff Cloud index #",i0)') i4
      DO i3 = 1, self%n_Layers
        WRITE(*,'(7x,"pcoeff Layer index #",i0)') i3
        DO i2 = 1, self%n_Phase_Elements
          WRITE(*,'(9x,"pcoeff Phase element index #",i0)') i2
          WRITE(*,'(5(1x,es13.6,:))') self%pcoeff(0:,i2,i3,i4)
        END DO
      END DO
    END DO
    WRITE(*,'(3x,"Volume scattering coefficient (total_bs) :")')
    WRITE(*,'(5(1x,es13.6,:))') self%total_bs
  END SUBROUTINE csvar_inspect


  FUNCTION csvar_validrelease( self ) RESULT( IsValid )
    ! Arguments
    TYPE(csvar_type), INTENT(IN) :: self
    ! Function result
    LOGICAL :: isvalid
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CSvar_ValidRelease'
    ! Local variables
    CHARACTER(ML) :: msg

    ! Set up
    isvalid = .true.

    ! Check release is not too old
    IF ( self%Release < csvar_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An CSvar data update is needed. ", &
                  &"CSvar release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, csvar_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF


    ! Check release is not too new
    IF ( self%Release > csvar_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An CSvar software update is needed. ", &
                  &"CSvar release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, csvar_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF
  END FUNCTION csvar_validrelease


  SUBROUTINE csvar_info( self, Info )
    ! Arguments
    TYPE(csvar_type), INTENT(IN)  :: self
    CHARACTER(*),     INTENT(OUT) :: info
    ! Parameters
    INTEGER, PARAMETER :: carriage_return = 13
    INTEGER, PARAMETER :: linefeed = 10
    ! Local variables
    CHARACTER(2000) :: long_string

    ! Write the required data to the local string
    WRITE( long_string, &
           '(a,1x,"CSvar RELEASE.VERSION: ",i2,".",i2.2,a,3x, &
           &"N_LEGENDRE_TERMS=",i0,2x,&
           &"N_PHASE_ELEMENTS=",i0,2x,&
           &"N_LAYERS=",i0,2x,&
           &"N_CLOUDS=",i0 )' ) &
           achar(carriage_return)//achar(linefeed), &
           self%Release, self%Version, &
           achar(carriage_return)//achar(linefeed), &
           self%n_Legendre_Terms, &
           self%n_Phase_Elements, &
           self%n_Layers        , &
           self%n_Clouds      
                       
    ! Trim the output based on the
    ! dummy argument string length
    info = long_string(1:min(len(info), len_trim(long_string)))
  END SUBROUTINE csvar_info


  SUBROUTINE csvar_defineversion( Id )
    CHARACTER(*), INTENT(OUT) :: id
    id = module_version_id
  END SUBROUTINE csvar_defineversion


  FUNCTION csvar_inquirefile( &
    Filename        , &  ! Input
    n_Legendre_Terms, &  ! Optional output  
    n_Phase_Elements, &  ! Optional output  
    n_Layers        , &  ! Optional output  
    n_Clouds        , &  ! Optional output  
    Release         , &  ! Optional output
    Version         , &  ! Optional output
    Title           , &  ! Optional output
    History         , &  ! Optional output
    Comment         ) &  ! Optional output
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: filename
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_legendre_terms
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_phase_elements
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_layers        
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_clouds      
    INTEGER     , OPTIONAL, INTENT(OUT) :: release        
    INTEGER     , OPTIONAL, INTENT(OUT) :: version        
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title           
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history         
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment         
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CSvar_InquireFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(csvar_type) :: csvar

 
    ! Setup
    err_stat = success
    ! ...Check that the file exists
    IF ( .NOT. file_exists( filename ) ) THEN
      msg = 'File '//trim(filename)//' not found.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Open the file
    err_stat = open_binary_file( filename, fid )
    IF ( err_stat /= success ) THEN
      msg = 'Error opening '//trim(filename)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%Release, &
      csvar%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF
    IF ( .NOT. csvar_validrelease( csvar ) ) THEN
      msg = 'CSvar Release check failed.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%n_Legendre_Terms, &
      csvar%n_Phase_Elements, &
      csvar%n_Layers        , &
      csvar%n_Clouds      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading dimension values from '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Close the file
    CLOSE( fid, iostat=io_stat, iomsg=io_msg )
    IF ( io_stat /= 0 ) THEN
      msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Assign the return arguments
    IF ( PRESENT(n_legendre_terms) ) n_legendre_terms = csvar%n_Legendre_Terms
    IF ( PRESENT(n_phase_elements) ) n_phase_elements = csvar%n_Phase_Elements    
    IF ( PRESENT(n_layers        ) ) n_layers         = csvar%n_Layers        
    IF ( PRESENT(n_clouds        ) ) n_clouds         = csvar%n_Clouds          
    IF ( PRESENT(release         ) ) release          = csvar%Release        
    IF ( PRESENT(version         ) ) version          = csvar%Version        
    
  CONTAINS
  
    SUBROUTINE inquire_cleanup()
      ! Close file if necessary
      IF ( file_open(fid) ) THEN
        CLOSE( fid, iostat=io_stat, iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      ! Set error status and print error message
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE inquire_cleanup
    
  END FUNCTION csvar_inquirefile


  FUNCTION csvar_readfile( &
    CSvar     , &  ! Output
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional output
    History   , &  ! Optional output
    Comment   , &  ! Optional output
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(csvar_type),       INTENT(OUT) :: csvar
    CHARACTER(*),           INTENT(IN)  :: filename
    LOGICAL,      OPTIONAL, INTENT(IN)  :: no_close
    LOGICAL,      OPTIONAL, INTENT(IN)  :: quiet
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment
    LOGICAL,      OPTIONAL, INTENT(IN)  :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CSvar_ReadFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(csvar_type) :: dummy
    
    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL read_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file if it exists
      IF ( file_exists( filename ) ) THEN
        err_stat = open_binary_file( filename, fid )
        IF ( err_stat /= success ) THEN
          msg = 'Error opening '//trim(filename)
          CALL read_cleanup(); RETURN
        END IF
      ELSE
        msg = 'File '//trim(filename)//' not found.'
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Read and check the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%Release, &
      dummy%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    IF ( .NOT. csvar_validrelease( dummy ) ) THEN
      msg = 'CSvar Release check failed.'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%n_Legendre_Terms, &
      dummy%n_Phase_Elements, &
      dummy%n_Layers        , &
      dummy%n_Clouds      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading data dimensions - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Allocate the object
    CALL csvar_create( &
           csvar                 , &
           dummy%n_Legendre_Terms, &        
           dummy%n_Phase_Elements, &        
           dummy%n_Layers        , &        
           dummy%n_Clouds        )                  
    IF ( .NOT. csvar_associated( csvar ) ) THEN
      msg = 'CSvar object allocation failed.'
      CALL read_cleanup(); RETURN
    END IF
    ! ...Explicitly assign the version number
    csvar%Version = dummy%Version
        

    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the data
    ! ...Mass extinction coefficient
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%ke
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading mass extinction coefficient - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Single scatter albedo
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%w
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading single scatter albedo - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Asymmetry factor
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%g
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading asymmetry factor - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Phase coefficients
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%pcoeff
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading phase coefficients - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Total volume scattering coefficient
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%total_bs
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading total volume scattering coefficient - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL csvar_info( csvar, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE read_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid, iostat=io_stat, iomsg=io_msg )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
       END IF
       CALL csvar_destroy( csvar )
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE read_cleanup

  END FUNCTION csvar_readfile


  FUNCTION csvar_writefile( &
    CSvar     , &  ! Input
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional input
    History   , &  ! Optional input
    Comment   , &  ! Optional input
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(csvar_type),  INTENT(IN) :: csvar
    CHARACTER(*),           INTENT(IN) :: filename
    LOGICAL,      OPTIONAL, INTENT(IN) :: no_close
    LOGICAL,      OPTIONAL, INTENT(IN) :: quiet
    CHARACTER(*), OPTIONAL, INTENT(IN) :: title
    CHARACTER(*), OPTIONAL, INTENT(IN) :: history
    CHARACTER(*), OPTIONAL, INTENT(IN) :: comment
    LOGICAL,      OPTIONAL, INTENT(IN) :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CSvar_WriteFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    

    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF
    ! ...Check there is data to write
    IF ( .NOT. csvar_associated( csvar ) ) THEN
      msg = 'CSvar object is empty.'
      CALL write_cleanup(); RETURN
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL write_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file for output
      err_stat = open_binary_file( filename, fid, for_output=.true. )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Write the release and version
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%Release, &
      csvar%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing Release/Version - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the dimensions
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%n_Legendre_Terms, &
      csvar%n_Phase_Elements, &
      csvar%n_Layers        , &
      csvar%n_Clouds      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing data dimensions - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the global attributes
    err_stat = writegatts_binary_file( &
                 fid, &
                 write_module = module_version_id, &
                 title        = title  , &
                 history      = history, &
                 comment      = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error writing global attributes'
      CALL write_cleanup(); RETURN
    END IF


    ! Write the data
    ! ...Mass extinction coefficient
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%ke
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing mass extinction coefficient - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Single scatter albedo
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%w
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing single scatter albedo - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Asymmetry factor
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%g
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing asymmetry factor - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Phase coefficients
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%pcoeff
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing phase coefficients - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Total volume scattering coefficient
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      csvar%total_bs
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing total volume scattering coefficient - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL csvar_info( csvar, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE write_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid, iostat=io_stat, iomsg=io_msg )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing output file during error cleanup - '//trim(io_msg)
       END IF
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE write_cleanup

  END FUNCTION csvar_writefile

  
!################################################################################
!################################################################################
!##                                                                            ##
!##                          ## PRIVATE PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

  ELEMENTAL FUNCTION csvar_equal( x, y ) RESULT( is_equal )
    TYPE(csvar_type), INTENT(IN) :: x, y
    LOGICAL :: is_equal

    ! Set up
    is_equal = .false.
   
    ! Check the object association status
    IF ( (.NOT. csvar_associated(x)) .OR. &
         (.NOT. csvar_associated(y))      ) RETURN

   ! Check contents
    ! ...Release/version info
    IF ( (x%Release /= y%Release) .OR. &
         (x%Version /= y%Version) ) RETURN
    ! ...Dimensions
    IF ( (x%n_Legendre_Terms /= y%n_Legendre_Terms ) .OR. &
         (x%n_Phase_Elements /= y%n_Phase_Elements ) .OR. &
         (x%n_Layers         /= y%n_Layers         ) .OR. &
         (x%n_Clouds         /= y%n_Clouds         ) ) RETURN
    ! ...Arrays
    IF ( all(x%ke       .equalto. y%ke       ) .AND. &
         all(x%w        .equalto. y%w        ) .AND. &
         all(x%g        .equalto. y%g        ) .AND. &
         all(x%pcoeff   .equalto. y%pcoeff   ) .AND. &
         all(x%total_bs .equalto. y%total_bs ) ) &
      is_equal = .true.
  END FUNCTION csvar_equal

END MODULE csvar_define