CRTM_VIS_Ice_SfcOptics.f90

Go to the documentation of this file.

!
! CRTM_VIS_Ice_SfcOptics
!
! Module to compute the surface optical properties for ICE surfaces at
! visible frequencies required for determining the ICE surface
! contribution to the radiative transfer.
!
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 31-Jan-2012
!                       paul.vandelst@noaa.gov
!

MODULE crtm_vis_ice_sfcoptics

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds               , ONLY: fp
  USE message_handler          , ONLY: success, display_message
  USE spectral_units_conversion, ONLY: inverse_cm_to_micron
  USE crtm_parameters          , ONLY: zero, one, max_n_angles
  USE crtm_spccoeff            , ONLY: sc
  USE crtm_surface_define      , ONLY: crtm_surface_type
  USE crtm_geometryinfo_define , ONLY: crtm_geometryinfo_type
  USE crtm_sfcoptics_define    , ONLY: crtm_sfcoptics_type
  USE crtm_secategory          , ONLY: sevar_type => ivar_type, &
                                       secategory_emissivity
  USE crtm_visicecoeff         , ONLY: visicec
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Data types
  PUBLIC :: ivar_type
  ! Science routines
  PUBLIC :: compute_vis_ice_sfcoptics
  PUBLIC :: compute_vis_ice_sfcoptics_tl
  PUBLIC :: compute_vis_ice_sfcoptics_ad


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: CRTM_VIS_Ice_SfcOptics.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Message string length
  INTEGER, PARAMETER :: ml = 256


  ! --------------------------------------
  ! Structure definition to hold forward
  ! variables across FWD, TL, and AD calls
  ! --------------------------------------
  TYPE :: ivar_type
    PRIVATE
    TYPE(sevar_type) :: sevar
  END TYPE ivar_type


CONTAINS


!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_VIS_Ice_SfcOptics
!
! PURPOSE:
!       Function to compute the surface emissivity and reflectivity at UV/visible
!       frequencies over an ice surface.
!
! CALLING SEQUENCE:
!       Error_Status = Compute_VIS_Ice_SfcOptics(
!                        Surface      , &
!                        SensorIndex  , &
!                        Channel_Index, &
!                        SfcOptics    , &
!                        iVar           )
!
! INPUTS:
!       Surface:         CRTM_Surface structure containing the surface state
!                        data.
!                        UNITS:      N/A
!                        TYPE:       CRTM_Surface_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       SensorIndex:     Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
!       Channel_Index:   Channel index id. This is a unique index associated
!                        with a (supported) sensor channel used to access the
!                        shared coefficient data.
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       SfcOptics:       CRTM_SfcOptics structure containing the surface
!                        optical properties required for the radiative
!                        transfer calculation. On input the Angle component
!                        is assumed to contain data.
!                        UNITS:      N/A
!                        TYPE:       CRTM_SfcOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
!       iVar:            Structure containing internal variables required for
!                        subsequent tangent-linear or adjoint model calls.
!                        The contents of this structure are NOT accessible
!                        outside of the module containing this procedure.
!                        UNITS:      N/A
!                        TYPE:       iVar_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(OUT)
!
! FUNCTION RESULT:
!       Error_Status:    The return value is an integer defining the error status.
!                        The error codes are defined in the Message_Handler module.
!                        If == SUCCESS the computation was sucessful
!                           == FAILURE an unrecoverable error occurred
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!
! COMMENTS:
!       Note the INTENT on the output SfcOptics argument is IN OUT rather
!       than just OUT as it is assumed to contain some data upon input.
!
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION compute_vis_ice_sfcoptics( &
    Surface     , &  ! Input
    SensorIndex , &  ! Input
    ChannelIndex, &  ! Input
    SfcOptics   , &  ! Output
    iVar        ) &  ! Internal variable output
  result( err_stat )
    ! Arguments
    TYPE(crtm_surface_type),   INTENT(IN)     :: surface
    INTEGER,                   INTENT(IN)     :: sensorindex
    INTEGER,                   INTENT(IN)     :: channelindex
    TYPE(crtm_sfcoptics_type), INTENT(IN OUT) :: sfcoptics
    TYPE(ivar_type),           INTENT(IN OUT) :: ivar
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'Compute_VIS_Ice_SfcOptics'
    ! Local variables
    CHARACTER(ML) :: msg
    INTEGER  :: j
    REAL(fp) :: frequency, emissivity

    ! Set up
    err_stat = success
    frequency = sc(sensorindex)%Wavenumber(channelindex)


    ! Compute Lambertian surface emissivity
    err_stat = secategory_emissivity( &
                 visicec         , &  ! Input
                 frequency       , &  ! Input
                 surface%Ice_Type, &  ! Input
                 emissivity      , &  ! Output
                 ivar%sevar        )  ! Internal variable output
    IF ( err_stat /= success ) THEN
      msg = 'Error occurred in SEcategory_Emissivity()'
      CALL display_message( routine_name, msg, err_stat ); RETURN
    END IF


    ! Solar direct component
    sfcoptics%Direct_Reflectivity(:,1) = one - emissivity


    ! Fill the return emissivity and reflectivity arrays
    sfcoptics%Emissivity(1:sfcoptics%n_Angles,1) = emissivity
    DO j = 1, sfcoptics%n_Angles
      sfcoptics%Reflectivity(1:sfcoptics%n_Angles,1,j,1) = (one - sfcoptics%Emissivity(j,1))*sfcoptics%Weight(j)
    END DO

  END FUNCTION compute_vis_ice_sfcoptics


!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_VIS_Ice_SfcOptics_TL
!
! PURPOSE:
!       Function to compute the tangent-linear surface emissivity and
!       reflectivity at UV/visible frequencies over an ice surface.
!
!       This function is a wrapper for third party code.
!
!       NB: CURRENTLY THIS IS A STUB FUNCTION AS THERE ARE NO TL
!           COMPONENTS IN THE VIS ICE SFCOPTICS COMPUTATIONS.
!
! CALLING SEQUENCE:
!       Error_Status = Compute_VIS_Ice_SfcOptics_TL( SfcOptics_TL )
!
! OUTPUTS:
!       SfcOptics_TL:    CRTM_SfcOptics structure containing the tangent-linear
!                        surface optical properties required for the tangent-
!                        linear radiative transfer calculation.
!                        UNITS:      N/A
!                        TYPE:       CRTM_SfcOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! FUNCTION RESULT:
!       Error_Status:    The return value is an integer defining the error status.
!                        The error codes are defined in the Message_Handler module.
!                        If == SUCCESS the computation was sucessful
!                           == FAILURE an unrecoverable error occurred
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!
! COMMENTS:
!       Note the INTENT on the output SfcOptics_TL argument is IN OUT rather
!       than just OUT as it may be defined upon input.
!
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION compute_vis_ice_sfcoptics_tl( &
    SfcOptics_TL ) &  ! Output
  result( err_stat )
    ! Arguments
    TYPE(crtm_sfcoptics_type), INTENT(IN OUT) :: sfcoptics_tl
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'Compute_VIS_Ice_SfcOptics_TL'
    ! Local variables


    ! Set up
    err_stat = success


    ! Compute the tangent-linear surface optical parameters
    ! ***No TL models yet, so default TL output is zero***
    sfcoptics_tl%Reflectivity        = zero
    sfcoptics_tl%Direct_Reflectivity = zero
    sfcoptics_tl%Emissivity          = zero

  END FUNCTION compute_vis_ice_sfcoptics_tl


!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_VIS_Ice_SfcOptics_AD
!
! PURPOSE:
!       Function to compute the adjoint surface emissivity and
!       reflectivity at UW/visible frequencies over an ice surface.
!
!       This function is a wrapper for third party code.
!
!       NB: CURRENTLY THIS IS A STUB FUNCTION AS THERE ARE NO AD
!           COMPONENTS IN THE VIS ICE SFCOPTICS COMPUTATIONS.
!
! CALLING SEQUENCE:
!       Error_Status = Compute_VIS_Ice_SfcOptics_AD( SfcOptics_AD )
!
! INPUTS:
!       SfcOptics_AD:    Structure containing the adjoint surface optical
!                        properties required for the adjoint radiative
!                        transfer calculation.
!                        *** COMPONENTS MODIFIED UPON OUTPUT ***
!                        UNITS:      N/A
!                        TYPE:       CRTM_SfcOptics_type
!                        DIMENSION:  Scalar
!                        ATTRIBUTES: INTENT(IN OUT)
!
! FUNCTION RESULT:
!       Error_Status:    The return value is an integer defining the error status.
!                        The error codes are defined in the Message_Handler module.
!                        If == SUCCESS the computation was sucessful
!                           == FAILURE an unrecoverable error occurred
!                        UNITS:      N/A
!                        TYPE:       INTEGER
!                        DIMENSION:  Scalar
!
! COMMENTS:
!       Note the INTENT on the input adjoint arguments are IN OUT regardless
!       of their specification as "input" or "output". This is because these
!       arguments may contain information on input, or need to be zeroed on
!       output (or both).
!
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION compute_vis_ice_sfcoptics_ad( &
    SfcOptics_AD ) &  ! Input
  result( err_stat )
    ! Arguments
    TYPE(crtm_sfcoptics_type), INTENT(IN OUT) :: sfcoptics_ad
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'Compute_VIS_Ice_SfcOptics_AD'
    ! Local variables


    ! Set up
    err_stat = success


    ! Compute the adjoint surface optical parameters
    ! ***No AD models yet, so there is no impact on AD result***
    sfcoptics_ad%Reflectivity        = zero
    sfcoptics_ad%Direct_Reflectivity = zero
    sfcoptics_ad%Emissivity          = zero

  END FUNCTION compute_vis_ice_sfcoptics_ad

END MODULE crtm_vis_ice_sfcoptics