CRTM_SpcCoeff.f90

Go to the documentation of this file.

!
! CRTM_SpcCoeff
!
! Module containing the shared CRTM spectral coefficients (SpcCoeff)
! and their load/destruction routines. 
!
! PUBLIC DATA:
!       SC:  Data structure array containing the spectral coefficient
!            data for the requested sensors.
!
! SIDE EFFECTS:
!       Routines in this module modify the contents of the public
!       data structure SC.
!
! RESTRICTIONS:
!       Routines in this module should only be called during the
!       CRTM initialisation.
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 12-Jun-2000
!                       paul.vandelst@noaa.gov
!

MODULE crtm_spccoeff

  ! ----------------
  ! Enviroment setup
  ! ----------------
  ! Module use
  USE message_handler      , ONLY: success, failure, warning, display_message
  USE sensorinfo_parameters, ONLY: n_polarization_types   , &
                                   invalid_polarization   , &
                                   unpolarized            , &
                                   intensity              , &
                                   first_stokes_component , &
                                   second_stokes_component, &
                                   third_stokes_component , &
                                   fourth_stokes_component, &
                                   vl_polarization        , &
                                   hl_polarization        , &
                                   plus45l_polarization   , &
                                   minus45l_polarization  , &
                                   vl_mixed_polarization  , &
                                   hl_mixed_polarization  , &
                                   rc_polarization        , &
                                   lc_polarization        , &
                                   polarization_type_name 
  USE spccoeff_define      , ONLY: spccoeff_type               , &
                                   spccoeff_associated         , &
                                   spccoeff_destroy            , &
                                   spccoeff_issolar            , &
                                   spccoeff_iszeeman           , &
                                   spccoeff_ismicrowavesensor  , &
                                   spccoeff_isinfraredsensor   , &
                                   spccoeff_isvisiblesensor    , &
                                   spccoeff_isultravioletsensor
  USE spccoeff_binary_io   , ONLY: spccoeff_binary_readfile
  USE crtm_parameters      , ONLY: crtm_set_max_nchannels  , &
                                   crtm_reset_max_nchannels
  ! Disable all implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! The shared data
  PUBLIC :: sc
  ! Public routines in this module
  PUBLIC :: crtm_spccoeff_load
  PUBLIC :: crtm_spccoeff_destroy
  PUBLIC :: crtm_spccoeff_isloaded
  ! Flag and sensor check procedures passed through from SpcCoeff_Define
  PUBLIC :: spccoeff_issolar
  PUBLIC :: spccoeff_iszeeman  
  PUBLIC :: spccoeff_ismicrowavesensor  
  PUBLIC :: spccoeff_isinfraredsensor   
  PUBLIC :: spccoeff_isvisiblesensor    
  PUBLIC :: spccoeff_isultravioletsensor
  ! Polarisation flag parameters passed through from SensorInfo_Parameters
  PUBLIC :: n_polarization_types   
  PUBLIC :: invalid_polarization   
  PUBLIC :: unpolarized            
  PUBLIC :: intensity              
  PUBLIC :: first_stokes_component 
  PUBLIC :: second_stokes_component
  PUBLIC :: third_stokes_component 
  PUBLIC :: fourth_stokes_component
  PUBLIC :: vl_polarization        
  PUBLIC :: hl_polarization        
  PUBLIC :: plus45l_polarization   
  PUBLIC :: minus45l_polarization  
  PUBLIC :: vl_mixed_polarization  
  PUBLIC :: hl_mixed_polarization  
  PUBLIC :: rc_polarization        
  PUBLIC :: lc_polarization        
  PUBLIC :: polarization_type_name
  

  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*),  PARAMETER :: module_version_id = &
  '$Id: CRTM_SpcCoeff.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Message string length
  INTEGER, PARAMETER :: ml = 256


  ! -------------------------------------
  ! The shared spectral coefficients data
  ! -------------------------------------
  TYPE(spccoeff_type), SAVE, ALLOCATABLE :: sc(:)


CONTAINS


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_SpcCoeff_Load
!
! PURPOSE:
!       Function to load the SpcCoeff spectral coefficient data into
!       the public data structure SC.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Load_SpcCoeff( &
!                        Sensor_ID                            , &
!                        File_Path         = File_Path        , &
!                        Quiet             = Quiet            , &
!                        Process_ID        = Process_ID       , &
!                        Output_Process_ID = Output_Process_ID  )
!
! INPUTS:
!       Sensor_ID:          List of the sensor IDs (e.g. hirs3_n17, amsua_n18,
!                           ssmis_f16, etc) with which the CRTM is to be
!                           initialised. These Sensor ID are used to construct
!                           the sensor specific SpcCoeff filenames containing
!                           the necessary coefficient data, i.e.
!                             <Sensor_ID>.SpcCoeff.bin
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Rank-1
!                           ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       File_Path:          Character string specifying a file path for the
!                           input data files. If not specified, the current
!                           directory is the default.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:              Set this logical argument to suppress INFORMATION
!                           messages being printed to stdout
!                           If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                              == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                           If not specified, default is .FALSE.
!                           UNITS:      N/A
!                           TYPE:       LOGICAL
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Process_ID:         Set this argument to the MPI process ID that this
!                           function call is running under. This value is used
!                           solely for controlling INFORMATIOn message output.
!                           If MPI is not being used, ignore this argument.
!                           This argument is ignored if the Quiet argument is set.
!                           UNITS:      None
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Output_Process_ID:  Set this argument to the MPI process ID in which
!                           all INFORMATION messages are to be output. If
!                           the passed Process_ID value agrees with this value
!                           the INFORMATION messages are output. 
!                           This argument is ignored if the Quiet argument
!                           is set.
!                           UNITS:      None
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:       The return value is an integer defining the error
!                           status. The error codes are defined in the
!                           Message_Handler module.
!                           If == SUCCESS the SpcCoeff data load was successful
!                              == FAILURE an unrecoverable error occurred.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!
! SIDE EFFECTS:
!       This function modifies the contents of the public data structure SC.
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_spccoeff_load( &
    Sensor_ID        , &  ! Input
    File_Path        , &  ! Optional input
    Quiet            , &  ! Optional input
    Process_ID       , &  ! Optional input
    Output_Process_ID) &  ! Optional input
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: sensor_id(:)
    CHARACTER(*), OPTIONAL, INTENT(IN)  :: file_path
    LOGICAL     , OPTIONAL, INTENT(IN)  :: quiet             
    INTEGER     , OPTIONAL, INTENT(IN)  :: process_id        
    INTEGER     , OPTIONAL, INTENT(IN)  :: output_process_id 
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_SpcCoeff_Load'
    ! Local variables
    CHARACTER(ML) :: msg, pid_msg
    CHARACTER(ML) :: path
    CHARACTER(ML) :: spccoeff_file
    LOGICAL :: noisy
    INTEGER :: alloc_stat
    INTEGER :: n, n_sensors

    ! Setup 
    err_stat = success
    ! ...Check the File_Path argument
    IF ( PRESENT(file_path) ) THEN
      path = adjustl(file_path)
    ELSE
      path = ''
    END IF
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Check the MPI Process Ids
    IF ( noisy .AND. PRESENT(process_id) .AND. PRESENT(output_process_id) ) THEN
      IF ( process_id /= output_process_id ) noisy = .false.
    END IF
    ! ...Create a process ID message tag for error messages
    IF ( PRESENT(process_id) ) THEN
      WRITE( pid_msg,'("; Process ID: ",i0)' ) process_id
    ELSE
      pid_msg = ''
    END IF

    
    ! Allocate the SpcCoeff shared data structure array
    n_sensors = SIZE(sensor_id)
    ALLOCATE( sc(n_sensors), stat = alloc_stat )
    IF ( alloc_stat /= 0 ) THEN
      err_stat = failure
      WRITE( msg,'("SpcCoeff structure array allocation failed. STAT=",i0)') alloc_stat
      CALL display_message( routine_name, trim(msg)//trim(pid_msg), err_stat ); RETURN
    END IF


    ! Read the SpcCoeff data files
    DO n = 1, n_sensors
      spccoeff_file = trim(path)//trim(adjustl(sensor_id(n)))//'.SpcCoeff.bin'
      err_stat = spccoeff_binary_readfile( &
        spccoeff_file      , &
        sc(n)              , &
        quiet = .NOT. noisy  )
      IF ( err_stat /= success ) THEN
        WRITE( msg,'("Error reading SpcCoeff file #",i0,", ",a)') n, trim(spccoeff_file)
        CALL display_message( routine_name, trim(msg)//trim(pid_msg), err_stat ); RETURN
      END IF
    END DO


    ! Set the protected variable MAX_N_CHANNELS
    CALL crtm_set_max_nchannels( sum(sc%n_Channels) )

  END FUNCTION crtm_spccoeff_load


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_SpcCoeff_Destroy
!
! PURPOSE:
!       Function to deallocate the public data structure array containing
!       the CRTM SpcCoeff spectral coefficient data.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Destroy_SpcCoeff( Process_ID = Process_ID )
!
! OPTIONAL INPUTS:
!       Process_ID:       Set this argument to the MPI process ID that this
!                         function call is running under. This value is used
!                         solely for controlling message output. If MPI is not
!                         being used, ignore this argument.
!                         UNITS:      N/A
!                         TYPE:       INTEGER
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:     The return value is an integer defining the error
!                         status. The error codes are defined in the
!                         Message_Handler module.
!                         If == SUCCESS the deallocation of the public SC data
!                                       structure was successful
!                            == FAILURE an unrecoverable error occurred.
!                         UNITS:      N/A
!                         TYPE:       INTEGER
!                         DIMENSION:  Scalar
!
! SIDE EFFECTS:
!       This function modifies the contents of the public shared data
!       structures in this module.
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_spccoeff_destroy( Process_ID ) RESULT( err_stat )
    ! Arguments
    INTEGER, OPTIONAL, INTENT(IN) :: process_id
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_SpcCoeff_Destroy'
    ! Local variables
    CHARACTER(ML) :: msg, pid_msg
    INTEGER :: alloc_stat

    ! Setup
    err_stat = success
    ! ...Create a process ID message tag for error messages
    IF ( PRESENT(process_id) ) THEN
      WRITE( pid_msg,'("; Process ID: ",i0)' ) process_id
    ELSE
      pid_msg = ''
    END IF


    ! Destroy the structure array elements
    CALL spccoeff_destroy( sc )
    IF ( any(spccoeff_associated( sc )) )THEN
      err_stat = failure
      msg = 'Error deallocating SpcCoeff shared data structures'//trim(pid_msg)
      CALL display_message( routine_name, msg, err_stat )
      ! No return here...keep deallocating
    END IF


    ! Deallocate the structure array itself
    DEALLOCATE( sc, stat = alloc_stat )
    IF ( alloc_stat /= 0 ) THEN
      err_stat = failure
      WRITE( msg,'("Error deallocating SpcCoeff structure array. STAT=",i0)') alloc_stat
      CALL display_message( routine_name, trim(msg)//trim(pid_msg), err_stat ); RETURN
      ! Again, no return.
    END IF


    ! Reset the protected variable MAX_N_CHANNELS
    CALL crtm_reset_max_nchannels()

  END FUNCTION crtm_spccoeff_destroy


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_SpcCoeff_IsLoaded
!
! PURPOSE:
!       Function to test if the SpcCoeff spectral coefficient data has
!       been loaded into the public data structure array SC.
!
! CALLING SEQUENCE:
!       status = CRTM_SpcCoeff_IsLoaded()
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_spccoeff_isloaded() RESULT( IsLoaded )
    LOGICAL :: isloaded
    isloaded = ALLOCATED(sc)
    IF ( isloaded ) isloaded = isloaded .AND. all(spccoeff_associated( sc ))
  END FUNCTION crtm_spccoeff_isloaded

END MODULE crtm_spccoeff