CRTM_Geometry_Define.f90

Go to the documentation of this file.

!
! CRTM_Geometry_Define
!
! Module defining the CRTM Geometry data structure.
!
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 18-Nov-2009
!                       paul.vandelst@noaa.gov
!

MODULE crtm_geometry_define

  ! ------------------
  ! Environment set up
  ! ------------------
  ! Intrinsic modules
  USE iso_fortran_env      , ONLY: output_unit
  ! Module use
  USE type_kinds           , ONLY: fp
  USE message_handler      , ONLY: success, failure, warning, information, display_message
  USE compare_float_numbers, ONLY: default_n_sigfig, &
                                   OPERATOR(.equalto.), &
                                   compares_within_tolerance
  USE file_utility         , ONLY: file_open, file_exists
  USE binary_file_utility  , ONLY: open_binary_file      , &
                                   writegatts_binary_file, &
                                   readgatts_binary_file
  USE date_utility         , ONLY: daysinmonth
  USE crtm_parameters      , ONLY: min_surface_altitude    , &
                                   max_surface_altitude    , &
                                   max_sensor_scan_angle   , &
                                   max_sensor_zenith_angle , &
                                   max_sensor_azimuth_angle, &
                                   max_source_zenith_angle , &
                                   max_source_azimuth_angle, &
                                   max_flux_zenith_angle   , &
                                   diffusivity_angle
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Operators
  PUBLIC :: OPERATOR(==)
  PUBLIC :: OPERATOR(-)
  ! Geometry enitities
  ! ...Structures
  PUBLIC :: crtm_geometry_type
  ! ...Procedures
  PUBLIC :: crtm_geometry_associated
  PUBLIC :: crtm_geometry_destroy
  PUBLIC :: crtm_geometry_create
  PUBLIC :: crtm_geometry_setvalue
  PUBLIC :: crtm_geometry_getvalue
  PUBLIC :: crtm_geometry_isvalid
  PUBLIC :: crtm_geometry_inspect
  PUBLIC :: crtm_geometry_defineversion
  PUBLIC :: crtm_geometry_compare
  PUBLIC :: crtm_geometry_inquirefile
  PUBLIC :: crtm_geometry_readfile
  PUBLIC :: crtm_geometry_writefile
  PUBLIC :: crtm_geometry_readrecord
  PUBLIC :: crtm_geometry_writerecord


  ! ---------------------
  ! Procedure overloading
  ! ---------------------
  INTERFACE OPERATOR(==)
    MODULE PROCEDURE crtm_geometry_equal
  END INTERFACE OPERATOR(==)

  INTERFACE OPERATOR(-)
    MODULE PROCEDURE crtm_geometry_subtract
  END INTERFACE OPERATOR(-)
  
  
  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: CRTM_Geometry_Define.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Literal constants 
  REAL(fp), PARAMETER :: zero = 0.0_fp 
  ! Message string length 
  INTEGER, PARAMETER :: ml = 256
  ! File status on close after write error
  CHARACTER(*), PARAMETER :: write_error_status = 'DELETE'
  ! Invalid date values
  INTEGER, PARAMETER :: min_year = 1960  ! Vanguard 2, was launched on February 17, 1959
  
  
  ! ---------------------------------
  ! Geometry data type definition
  ! ---------------------------------
  !:tdoc+:
  TYPE :: crtm_geometry_type
    ! Allocation indicator
    LOGICAL :: is_allocated = .false.
    ! Field of view index (1-nFOV)
    INTEGER  :: ifov = 0
    ! Earth location
    REAL(fp) :: longitude        = zero
    REAL(fp) :: latitude         = zero
    REAL(fp) :: surface_altitude = zero
    ! Sensor angle information
    REAL(fp) :: sensor_scan_angle    = zero
    REAL(fp) :: sensor_zenith_angle  = zero
    REAL(fp) :: sensor_azimuth_angle = 999.9_fp  ! Invalid marker
    ! Source angle information
    REAL(fp) :: source_zenith_angle  = 100.0_fp  ! Below horizon
    REAL(fp) :: source_azimuth_angle = zero
    ! Flux angle information
    REAL(fp) :: flux_zenith_angle = diffusivity_angle
    ! Date for geometry calculations
    INTEGER :: year  = 2001
    INTEGER :: month = 1
    INTEGER :: day   = 1
  END TYPE crtm_geometry_type
  !:tdoc-:


CONTAINS


!##################################################################################
!##################################################################################
!##                                                                              ##
!##                           ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                              ##
!##################################################################################
!##################################################################################


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_Associated
!
! PURPOSE:
!       Elemental function to test the status of the allocatable components
!       of a CRTM Geometry object.
!
! CALLING SEQUENCE:
!       Status = CRTM_Geometry_Associated( geo )
!
! OBJECTS:
!       geo:          Geometry structure which is to have its member's
!                     status tested.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Scalar or any rank
!                     ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       Status:       The return value is a logical value indicating the
!                     status of the Geometry members.
!                       .TRUE.  - if the array components are allocated.
!                       .FALSE. - if the array components are not allocated.
!                     UNITS:      N/A
!                     TYPE:       LOGICAL
!                     DIMENSION:  Same as input Geometry argument
!
!:sdoc-:
!--------------------------------------------------------------------------------

  ELEMENTAL FUNCTION crtm_geometry_associated( Geometry ) RESULT( Status )
    TYPE(crtm_geometry_type), INTENT(IN) :: geometry
    LOGICAL :: status
    status = geometry%Is_Allocated
  END FUNCTION crtm_geometry_associated


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_Destroy
! 
! PURPOSE:
!       Elemental subroutine to re-initialize CRTM Geometry objects.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_Destroy( geo )
!
! OBJECTS:
!       geo:          Re-initialized Geometry structure.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Scalar or any rank
!                     ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  ELEMENTAL SUBROUTINE crtm_geometry_destroy( geo )
    TYPE(crtm_geometry_type), INTENT(OUT) :: geo
    geo%Is_Allocated = .false.  ! Placeholder for future expansion
  END SUBROUTINE crtm_geometry_destroy
  

!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_Create
!
! PURPOSE:
!       Elemental subroutine to create an instance of the CRTM Geometry object.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_Create( geo )
!
! OBJECTS:
!       geo:          Geometry structure.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Scalar or any rank
!                     ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  ELEMENTAL SUBROUTINE crtm_geometry_create( geo )
    ! Arguments
    TYPE(crtm_geometry_type), INTENT(OUT) :: geo

    ! NOTE: This is a stub routine for future expansion

    ! Set allocation indicator
    geo%Is_Allocated = .true.

  END SUBROUTINE crtm_geometry_create


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_SetValue
! 
! PURPOSE:
!       Elemental subroutine to set the values of CRTM Geometry
!       object components.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_SetValue( geo, &
!                                    iFOV                 = iFOV                , &
!                                    Longitude            = Longitude           , &
!                                    Latitude             = Latitude            , &
!                                    Surface_Altitude     = Surface_Altitude    , &
!                                    Sensor_Scan_Angle    = Sensor_Scan_Angle   , &
!                                    Sensor_Zenith_Angle  = Sensor_Zenith_Angle , &
!                                    Sensor_Azimuth_Angle = Sensor_Azimuth_Angle, &
!                                    Source_Zenith_Angle  = Source_Zenith_Angle , &
!                                    Source_Azimuth_Angle = Source_Azimuth_Angle, &
!                                    Flux_Zenith_Angle    = Flux_Zenith_Angle   , &
!                                    Year                 = Year                , &
!                                    Month                = Month               , &
!                                    Day                  = Day                   )
!
! OBJECTS:
!       geo:                  Geometry object for which component values
!                             are to be set.
!                             UNITS:      N/A
!                             TYPE:       CRTM_Geometry_type
!                             DIMENSION:  Scalar or any rank
!                             ATTRIBUTES: INTENT(IN OUT)
!
! OPTIONAL INPUTS:
!       iFOV:                 Sensor field-of-view index.
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Longitude:            Earth longitude
!                             UNITS:      degrees East (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Latitude:             Earth latitude.
!                             UNITS:      degrees North (-90->+90)
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Surface_Altitude:     Altitude of the Earth's surface at the specifed
!                             lon/lat location.
!                             UNITS:      metres (m)
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Sensor_Scan_Angle:    The sensor scan angle from nadir.
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Sensor_Zenith_Angle:  The zenith angle from the field-of-view
!                             to the sensor.
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Sensor_Azimuth_Angle: The azimuth angle subtended by the horizontal
!                             projection of a direct line from the satellite
!                             to the FOV and the North-South axis measured
!                             clockwise from North.
!                             UNITS:      degrees from North (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Source_Zenith_Angle:  The zenith angle from the field-of-view
!                             to a source (sun or moon).
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Source_Azimuth_Angle: The azimuth angle subtended by the horizontal
!                             projection of a direct line from the source
!                             to the FOV and the North-South axis measured
!                             clockwise from North.
!                             UNITS:      degrees from North (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Flux_Zenith_Angle:    The zenith angle used to approximate downwelling
!                             flux transmissivity
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Year:                 The year in 4-digit format, e.g. 1997.
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Month:                The month of the year (1-12).
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Day:                  The day of the month (1-28/29/30/31).
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(IN), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  ELEMENTAL SUBROUTINE crtm_geometry_setvalue( &
    geo                 , &  ! In/Output
    iFOV                , &  ! Optional input
    Longitude           , &  ! Optional input
    Latitude            , &  ! Optional input
    Surface_Altitude    , &  ! Optional input
    Sensor_Scan_Angle   , &  ! Optional input
    Sensor_Zenith_Angle , &  ! Optional input
    Sensor_Azimuth_Angle, &  ! Optional input
    Source_Zenith_Angle , &  ! Optional input
    Source_Azimuth_Angle, &  ! Optional input
    Flux_Zenith_Angle   , &  ! Optional input
    Year                , &  ! Optional input
    Month               , &  ! Optional input
    Day                   )  ! Optional input
    ! Arguments
    TYPE(crtm_geometry_type), INTENT(IN OUT) :: geo
    INTEGER ,       OPTIONAL, INTENT(IN)     :: ifov
    REAL(fp),       OPTIONAL, INTENT(IN)     :: longitude
    REAL(fp),       OPTIONAL, INTENT(IN)     :: latitude
    REAL(fp),       OPTIONAL, INTENT(IN)     :: surface_altitude
    REAL(fp),       OPTIONAL, INTENT(IN)     :: sensor_scan_angle
    REAL(fp),       OPTIONAL, INTENT(IN)     :: sensor_zenith_angle
    REAL(fp),       OPTIONAL, INTENT(IN)     :: sensor_azimuth_angle
    REAL(fp),       OPTIONAL, INTENT(IN)     :: source_zenith_angle
    REAL(fp),       OPTIONAL, INTENT(IN)     :: source_azimuth_angle
    REAL(fp),       OPTIONAL, INTENT(IN)     :: flux_zenith_angle
    INTEGER,        OPTIONAL, INTENT(IN)     :: year 
    INTEGER,        OPTIONAL, INTENT(IN)     :: month
    INTEGER,        OPTIONAL, INTENT(IN)     :: day  
    
    ! Set values
    IF ( PRESENT(ifov                ) ) geo%iFOV = ifov
    IF ( PRESENT(longitude           ) ) geo%Longitude            = longitude
    IF ( PRESENT(latitude            ) ) geo%Latitude             = latitude
    IF ( PRESENT(surface_altitude    ) ) geo%Surface_Altitude     = surface_altitude
    IF ( PRESENT(sensor_scan_angle   ) ) geo%Sensor_Scan_Angle    = sensor_scan_angle
    IF ( PRESENT(sensor_zenith_angle ) ) geo%Sensor_Zenith_Angle  = sensor_zenith_angle
    IF ( PRESENT(sensor_azimuth_angle) ) geo%Sensor_Azimuth_Angle = sensor_azimuth_angle
    IF ( PRESENT(source_zenith_angle ) ) geo%Source_Zenith_Angle  = source_zenith_angle
    IF ( PRESENT(source_azimuth_angle) ) geo%Source_Azimuth_Angle = source_azimuth_angle
    IF ( PRESENT(flux_zenith_angle   ) ) geo%Flux_Zenith_Angle    = flux_zenith_angle
    IF ( PRESENT(year                ) ) geo%Year                 = year 
    IF ( PRESENT(month               ) ) geo%Month                = month
    IF ( PRESENT(day                 ) ) geo%Day                  = day  
  
  END SUBROUTINE crtm_geometry_setvalue


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_GetValue
! 
! PURPOSE:
!       Elemental subroutine to get the values of CRTM Geometry
!       object components.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_GetValue( geo, &
!                                    iFOV                 = iFOV                , &
!                                    Longitude            = Longitude           , &
!                                    Latitude             = Latitude            , &
!                                    Surface_Altitude     = Surface_Altitude    , &
!                                    Sensor_Scan_Angle    = Sensor_Scan_Angle   , &
!                                    Sensor_Zenith_Angle  = Sensor_Zenith_Angle , &
!                                    Sensor_Azimuth_Angle = Sensor_Azimuth_Angle, &
!                                    Source_Zenith_Angle  = Source_Zenith_Angle , &
!                                    Source_Azimuth_Angle = Source_Azimuth_Angle, &
!                                    Flux_Zenith_Angle    = Flux_Zenith_Angle   , &
!                                    Year                 = Year                , &
!                                    Month                = Month               , &
!                                    Day                  = Day                   )
!
! OBJECTS:
!       geo:                  Geometry object from which component values
!                             are to be retrieved.
!                             UNITS:      N/A
!                             TYPE:       CRTM_Geometry_type
!                             DIMENSION:  Scalar or any rank
!                             ATTRIBUTES: INTENT(IN OUT)
!
! OPTIONAL OUTPUTS:
!       iFOV:                 Sensor field-of-view index.
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Longitude:            Earth longitude
!                             UNITS:      degrees East (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Latitude:             Earth latitude.
!                             UNITS:      degrees North (-90->+90)
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Surface_Altitude:     Altitude of the Earth's surface at the specifed
!                             lon/lat location.
!                             UNITS:      metres (m)
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Sensor_Scan_Angle:    The sensor scan angle from nadir.
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Sensor_Zenith_Angle:  The zenith angle from the field-of-view
!                             to the sensor.
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Sensor_Azimuth_Angle: The azimuth angle subtended by the horizontal
!                             projection of a direct line from the satellite
!                             to the FOV and the North-South axis measured
!                             clockwise from North.
!                             UNITS:      degrees from North (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Source_Zenith_Angle:  The zenith angle from the field-of-view
!                             to a source (sun or moon).
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Source_Azimuth_Angle: The azimuth angle subtended by the horizontal
!                             projection of a direct line from the source
!                             to the FOV and the North-South axis measured
!                             clockwise from North.
!                             UNITS:      degrees from North (0->360) 
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Flux_Zenith_Angle:    The zenith angle used to approximate downwelling
!                             flux transmissivity
!                             UNITS:      degrees
!                             TYPE:       REAL(fp)
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Year:                 The year in 4-digit format, e.g. 1997.
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Month:                The month of the year (1-12).
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!       Day:                  The day of the month (1-28/29/30/31).
!                             UNITS:      N/A
!                             TYPE:       INTEGER
!                             DIMENSION:  Scalar or same as geo input
!                             ATTRIBUTES: INTENT(OUT), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  ELEMENTAL SUBROUTINE crtm_geometry_getvalue( &
    geo                 , &  ! Input
    iFOV                , &  ! Optional output
    Longitude           , &  ! Optional output
    Latitude            , &  ! Optional output
    Surface_Altitude    , &  ! Optional output
    Sensor_Scan_Angle   , &  ! Optional output
    Sensor_Zenith_Angle , &  ! Optional output
    Sensor_Azimuth_Angle, &  ! Optional output
    Source_Zenith_Angle , &  ! Optional output
    Source_Azimuth_Angle, &  ! Optional output
    Flux_Zenith_Angle   , &  ! Optional output
    Year                , &  ! Optional output
    Month               , &  ! Optional output
    Day                   )  ! Optional output
    ! Arguments
    TYPE(crtm_geometry_type), INTENT(IN)  :: geo
    INTEGER ,       OPTIONAL, INTENT(OUT) :: ifov
    REAL(fp),       OPTIONAL, INTENT(OUT) :: longitude
    REAL(fp),       OPTIONAL, INTENT(OUT) :: latitude
    REAL(fp),       OPTIONAL, INTENT(OUT) :: surface_altitude
    REAL(fp),       OPTIONAL, INTENT(OUT) :: sensor_scan_angle
    REAL(fp),       OPTIONAL, INTENT(OUT) :: sensor_zenith_angle
    REAL(fp),       OPTIONAL, INTENT(OUT) :: sensor_azimuth_angle
    REAL(fp),       OPTIONAL, INTENT(OUT) :: source_zenith_angle
    REAL(fp),       OPTIONAL, INTENT(OUT) :: source_azimuth_angle
    REAL(fp),       OPTIONAL, INTENT(OUT) :: flux_zenith_angle
    INTEGER,        OPTIONAL, INTENT(OUT) :: year 
    INTEGER,        OPTIONAL, INTENT(OUT) :: month
    INTEGER,        OPTIONAL, INTENT(OUT) :: day  
    
    ! Get values
    IF ( PRESENT(ifov                ) ) ifov                 = geo%iFOV
    IF ( PRESENT(longitude           ) ) longitude            = geo%Longitude
    IF ( PRESENT(latitude            ) ) latitude             = geo%Latitude
    IF ( PRESENT(surface_altitude    ) ) surface_altitude     = geo%Surface_Altitude
    IF ( PRESENT(sensor_scan_angle   ) ) sensor_scan_angle    = geo%Sensor_Scan_Angle
    IF ( PRESENT(sensor_zenith_angle ) ) sensor_zenith_angle  = geo%Sensor_Zenith_Angle
    IF ( PRESENT(sensor_azimuth_angle) ) sensor_azimuth_angle = geo%Sensor_Azimuth_Angle
    IF ( PRESENT(source_zenith_angle ) ) source_zenith_angle  = geo%Source_Zenith_Angle
    IF ( PRESENT(source_azimuth_angle) ) source_azimuth_angle = geo%Source_Azimuth_Angle
    IF ( PRESENT(flux_zenith_angle   ) ) flux_zenith_angle    = geo%Flux_Zenith_Angle
    IF ( PRESENT(year                ) ) year                 = geo%Year 
    IF ( PRESENT(month               ) ) month                = geo%Month
    IF ( PRESENT(day                 ) ) day                  = geo%Day  
  
  END SUBROUTINE crtm_geometry_getvalue


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_IsValid
!
! PURPOSE:
!       Non-pure function to perform some simple validity checks on a
!       CRTM Geometry object. 
!
!       If invalid data is found, a message is printed to stdout.
!
! CALLING SEQUENCE:
!       result = CRTM_Geometry_IsValid( geo )
!
!         or
!
!       IF ( CRTM_Geometry_IsValid( geo ) ) THEN....
!
! OBJECTS:
!       geo:       CRTM Geometry object which is to have its
!                  contents checked.
!                  UNITS:      N/A
!                  TYPE:       CRTM_Geometry_type
!                  DIMENSION:  Scalar
!                  ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       result:    Logical variable indicating whether or not the input
!                  passed the check.
!                  If == .FALSE., Geometry object is unused or contains
!                                 invalid data.
!                     == .TRUE.,  Geometry object can be used in CRTM.
!                  UNITS:      N/A
!                  TYPE:       LOGICAL
!                  DIMENSION:  Scalar
!
!:sdoc-:
!--------------------------------------------------------------------------------

  FUNCTION crtm_geometry_isvalid( geo ) RESULT( IsValid )
    TYPE(crtm_geometry_type), INTENT(IN) :: geo
    LOGICAL :: isvalid
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_IsValid'
    CHARACTER(ML) :: msg
    
    ! Setup
    isvalid = .true.
    
    ! Field of view index (1-nFOV)
    IF ( geo%iFOV < 0 ) THEN
      msg = 'Invalid FOV index. Must be > 0.'
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF

    ! Earth location
    IF ( geo%Longitude < zero .OR. geo%Longitude > 360.0_fp ) THEN
      msg = 'Invalid longitude. Must be degrees East (0->360)'
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    IF ( geo%Latitude < -90.0_fp .OR. geo%Latitude > 90.0_fp ) THEN
      msg = 'Invalid latitude. Must be degrees North (-90->+90)'
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    IF ( geo%Surface_Altitude < min_surface_altitude .OR. &
         geo%Surface_Altitude > max_surface_altitude      ) THEN
      WRITE(msg,'("Invalid surface altitude. Must be metres (",f6.1,"->+",f6.1,")")') &
            min_surface_altitude, max_surface_altitude
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    
    ! Sensor angles
    IF ( abs(geo%Sensor_Scan_Angle) > max_sensor_scan_angle ) THEN
      WRITE(msg,'("Invalid sensor scan angle. Must be |thetas(i)|<=",f4.1)') &
            max_sensor_scan_angle
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    IF ( abs(geo%Sensor_Zenith_Angle) > max_sensor_zenith_angle ) THEN
      WRITE(msg,'("Invalid sensor zenith angle. Must be |thetaz(i)|<=",f4.1)') &
            max_sensor_zenith_angle
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
!    IF ( geo%Sensor_Azimuth_Angle < ZERO .OR. &
!         geo%Sensor_Azimuth_Angle > MAX_SENSOR_AZIMUTH_ANGLE ) THEN
!      WRITE(msg,'("Invalid sensor azimuth angle. Must be 0<=phi(i)<=",f5.1)') &
!            MAX_SENSOR_AZIMUTH_ANGLE
!      CALL Display_Message( ROUTINE_NAME, TRIM(msg), INFORMATION )
!      IsValid = .FALSE.
!    END IF
    
    ! Source angle information
    IF ( abs(geo%Source_Zenith_Angle) > 180.0_fp ) THEN
      msg = 'Invalid source zenith angle. Must be |thetaz(s)|<=180.0'
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    IF ( geo%Source_Azimuth_Angle < zero .OR. &
         geo%Source_Azimuth_Angle > max_source_azimuth_angle ) THEN
      WRITE(msg,'("Invalid source azimuth angle. Must be 0<=phi(s)<=",f5.1)') &
            max_source_azimuth_angle
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF

    ! Flux angle information
    IF ( abs(geo%Flux_Zenith_Angle) > max_flux_zenith_angle ) THEN
      WRITE(msg,'("Invalid flux zenith angle. Must be |thetaz(f)|<=",f4.1)') &
            max_flux_zenith_angle
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF

    ! Date information
    IF ( geo%Year < min_year ) THEN
      WRITE(msg,'("Invalid year. Must be > ",i0)') min_year
      CALL display_message( routine_name, trim(msg), information )
      isvalid = .false.
    END IF
    IF ( geo%Month < 1 .OR. geo%Month > 12 ) THEN
      CALL display_message( routine_name, 'Invalid month-of-year.', information )
      isvalid = .false.
    END IF
    ! ...Only test Day value if Month and Year are valid
    IF ( isvalid ) THEN
      IF ( geo%Day < 1 .OR. geo%Day > daysinmonth(geo%Month,geo%Year) ) THEN
        CALL display_message( routine_name, 'Invalid day-of-month.', information )
        isvalid = .false.
      END IF
    END IF

  END FUNCTION crtm_geometry_isvalid


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_Inspect
!
! PURPOSE:
!       Subroutine to print the contents of a CRTM Geometry object to stdout.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_Inspect( Geo, Unit=unit )
!
! INPUTS:
!       Geo:   CRTM Geometry object to display.
!              UNITS:      N/A
!              TYPE:       CRTM_Geometry_type
!              DIMENSION:  Scalar
!              ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       Unit:  Unit number for an already open file to which the output
!              will be written.
!              If the argument is specified and the file unit is not
!              connected, the output goes to stdout.
!              UNITS:      N/A
!              TYPE:       INTEGER
!              DIMENSION:  Scalar
!              ATTRIBUTES: INTENT(IN), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE crtm_geometry_inspect( geo, Unit )
    ! Arguments
    TYPE(crtm_geometry_type), INTENT(IN) :: geo
    INTEGER,        OPTIONAL, INTENT(IN) :: unit
    ! Local parameters
    CHARACTER(*), PARAMETER :: rfmt = 'es13.6'
    ! Local variables
    INTEGER :: fid
    
    ! Setup
    fid = output_unit
    IF ( PRESENT(unit) ) THEN
      IF ( file_open(unit) ) fid = unit
    END IF

    
    WRITE(fid, '(1x,"Geometry OBJECT")')
    ! Field of view index
    WRITE(fid, '(3x,"FOV index           :",1x,i0)') geo%iFOV
    ! Earth location
    WRITE(fid, '(3x,"Longitude           :",1x,'//rfmt//')') geo%Longitude       
    WRITE(fid, '(3x,"Latitude            :",1x,'//rfmt//')') geo%Latitude        
    WRITE(fid, '(3x,"Surface altitude    :",1x,'//rfmt//')') geo%Surface_Altitude
    ! Sensor angle information
    WRITE(fid, '(3x,"Sensor scan angle   :",1x,'//rfmt//')') geo%Sensor_Scan_Angle   
    WRITE(fid, '(3x,"Sensor zenith angle :",1x,'//rfmt//')') geo%Sensor_Zenith_Angle 
    WRITE(fid, '(3x,"Sensor azimuth angle:",1x,'//rfmt//')') geo%Sensor_Azimuth_Angle
    ! Source angle information
    WRITE(fid, '(3x,"Source zenith angle :",1x,'//rfmt//')') geo%Source_Zenith_Angle 
    WRITE(fid, '(3x,"Source azimuth angle:",1x,'//rfmt//')') geo%Source_Azimuth_Angle
    ! Flux angle information
    WRITE(fid, '(3x,"Flux zenith angle   :",1x,'//rfmt//')') geo%Flux_Zenith_Angle
    ! Date information
    WRITE(fid, '(3x,"Year                :",1x,i4)') geo%Year 
    WRITE(fid, '(3x,"Month               :",1x,i4)') geo%Month
    WRITE(fid, '(3x,"Day                 :",1x,i4)') geo%Day  

  END SUBROUTINE crtm_geometry_inspect


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_DefineVersion
!
! PURPOSE:
!       Subroutine to return the module version information.
!
! CALLING SEQUENCE:
!       CALL CRTM_Geometry_DefineVersion( Id )
!
! OUTPUT ARGUMENTS:
!       Id:            Character string containing the version Id information
!                      for the module.
!                      UNITS:      N/A
!                      TYPE:       CHARACTER(*)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE crtm_geometry_defineversion( Id )
    CHARACTER(*), INTENT(OUT) :: id
    id = module_version_id
  END SUBROUTINE crtm_geometry_defineversion


!------------------------------------------------------------------------------
!:sdoc+:
! NAME:
!       CRTM_Geometry_Compare
!
! PURPOSE:
!       Elemental function to compare two CRTM_Geometry objects to within
!       a user specified number of significant figures.
!
! CALLING SEQUENCE:
!       is_comparable = CRTM_Geometry_Compare( x, y, n_SigFig=n_SigFig )
!
! OBJECTS:
!       x, y:          Two CRTM Geometry objects to be compared.
!                      UNITS:      N/A
!                      TYPE:       CRTM_Geometry_type
!                      DIMENSION:  Scalar or any rank
!                      ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       n_SigFig:      Number of significant figure to compare floating point
!                      components.
!                      UNITS:      N/A
!                      TYPE:       INTEGER
!                      DIMENSION:  Scalar or same as input
!                      ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       is_equal:      Logical value indicating whether the inputs are equal.
!                      UNITS:      N/A
!                      TYPE:       LOGICAL
!                      DIMENSION:  Same as inputs.
!:sdoc-:
!------------------------------------------------------------------------------

  ELEMENTAL FUNCTION crtm_geometry_compare( &
    x, &
    y, &
    n_SigFig ) &
  result( is_comparable )
    ! Arguments
    TYPE(crtm_geometry_type), INTENT(IN) :: x, y
    INTEGER,        OPTIONAL, INTENT(IN) :: n_sigfig
    ! Function result
    LOGICAL :: is_comparable
    ! Variables
    INTEGER :: n

    ! Set up
    is_comparable = .false.
    IF ( PRESENT(n_sigfig) ) THEN
      n = abs(n_sigfig)
    ELSE
      n = default_n_sigfig
    END IF
   
    ! Check the structure association status
    IF ( (.NOT. crtm_geometry_associated(x)) .OR. &
         (.NOT. crtm_geometry_associated(y)) ) RETURN

    ! Check scalars
    IF ( (x%iFOV /= y%iFOV) .OR. &
         (.NOT. compares_within_tolerance(x%Longitude           , y%Longitude           , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Latitude            , y%Latitude            , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Surface_Altitude    , y%Surface_Altitude    , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Sensor_Scan_Angle   , y%Sensor_Scan_Angle   , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Sensor_Zenith_Angle , y%Sensor_Zenith_Angle , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Sensor_Azimuth_Angle, y%Sensor_Azimuth_Angle, n)) .OR. &
         (.NOT. compares_within_tolerance(x%Source_Zenith_Angle , y%Source_Zenith_Angle , n)) .OR. &
         (.NOT. compares_within_tolerance(x%Source_Azimuth_Angle, y%Source_Azimuth_Angle, n)) .OR. &
         (.NOT. compares_within_tolerance(x%Flux_Zenith_Angle   , y%Flux_Zenith_Angle   , n)) .OR. &
         (x%Year  /= y%Year ) .OR. &
         (x%Month /= y%Month) .OR. &
         (x%Day   /= y%Day  ) ) RETURN

    ! If we get here, the structures are comparable
    is_comparable = .true.
   
  END FUNCTION crtm_geometry_compare


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_InquireFile
!
! PURPOSE:
!       Function to inquire CRTM Geometry object files.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Geometry_InquireFile( Filename               , &
!                                                 n_Profiles = n_Profiles  )
!
! INPUTS:
!       Filename:       Character string specifying the name of a
!                       CRTM Geometry data file to read.
!                       UNITS:      N/A
!                       TYPE:       CHARACTER(*)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! OPTIONAL OUTPUTS:
!       n_Profiles:     The number of profiles for which their is geometry 
!                       information in the data file.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: OPTIONAL, INTENT(OUT)
!
! FUNCTION RESULT:
!       Error_Status:   The return value is an integer defining the error status.
!                       The error codes are defined in the Message_Handler module.
!                       If == SUCCESS, the file inquire was successful
!                          == FAILURE, an unrecoverable error occurred.
!                       UNITS:      N/A
!                       TYPE:       INTEGER
!                       DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_geometry_inquirefile( &
    Filename  , &  ! Input
    n_Profiles) &  ! Optional output
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: filename
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_profiles
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_InquireFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
    INTEGER :: fid
    INTEGER :: m
 
    ! Set up
    err_stat = success
    ! ...Check that the file exists
    IF ( .NOT. file_exists( trim(filename) ) ) THEN
      msg = 'File '//trim(filename)//' not found.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Open the file
    err_stat = open_binary_file( filename, fid )
    IF ( err_stat /= success ) THEN
      msg = 'Error opening '//trim(filename)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the number of profiles
    READ( fid,iostat=io_stat,iomsg=io_msg ) m
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading data dimension from '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Close the file
    CLOSE( fid,iostat=io_stat,iomsg=io_msg )
    IF ( io_stat /= 0 ) THEN
      msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Set the return arguments
    IF ( PRESENT(n_profiles) ) n_profiles = m

  CONTAINS
  
    SUBROUTINE inquire_cleanup()
      IF ( file_open(fid) ) THEN
        CLOSE( fid,iostat=io_stat,iomsg=io_msg )
        IF ( io_stat /= success ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE inquire_cleanup

  END FUNCTION crtm_geometry_inquirefile


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_ReadFile
!
! PURPOSE:
!       Function to read CRTM Geometry object files.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Geometry_ReadFile( Filename               , &
!                                              Geometry               , &
!                                              Quiet      = Quiet     , &
!                                              No_Close   = No_Close  , &
!                                              n_Profiles = n_Profiles  )
!
! INPUTS:
!       Filename:     Character string specifying the name of an
!                     a Geometry data file to read.
!                     UNITS:      N/A
!                     TYPE:       CHARACTER(*)
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Geometry:     CRTM Geometry object array containing the
!                     data read from file.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Rank-1
!                     ATTRIBUTES: INTENT(OUT), ALLOCATABLE
!
! OPTIONAL INPUTS:
!       Quiet:        Set this logical argument to suppress INFORMATION
!                     messages being printed to stdout
!                     If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                        == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                     If not specified, default is .FALSE.
!                     UNITS:      N/A
!                     TYPE:       LOGICAL
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       No_Close:     Set this logical argument to NOT close the file upon exit.
!                     If == .FALSE., the input file is closed upon exit [DEFAULT]
!                        == .TRUE.,  the input file is NOT closed upon exit.
!                     If not specified, default is .FALSE.
!                     UNITS:      N/A
!                     TYPE:       LOGICAL
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN), OPTIONAL
!
! OPTIONAL OUTPUTS:
!       n_Profiles:   The number of profiles for which data was read.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: OPTIONAL, INTENT(OUT)
!
! FUNCTION RESULT:
!       Error_Status: The return value is an integer defining the error status.
!                     The error codes are defined in the Message_Handler module.
!                     If == SUCCESS, the file read was successful
!                        == FAILURE, an unrecoverable error occurred.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_geometry_readfile( &
    Filename  , &  ! Input
    Geometry  , &  ! Output
    Quiet     , &  ! Optional input
    No_Close  , &  ! Optional input
    n_Profiles, &  ! Optional output
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    CHARACTER(*),                          INTENT(IN)  :: filename
    TYPE(crtm_geometry_type), ALLOCATABLE, INTENT(OUT) :: geometry(:)
    LOGICAL,        OPTIONAL,              INTENT(IN)  :: quiet
    LOGICAL,        OPTIONAL,              INTENT(IN)  :: no_close
    INTEGER,        OPTIONAL,              INTENT(OUT) :: n_profiles
    LOGICAL,        OPTIONAL,              INTENT(IN)  :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_ReadFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    CHARACTER(ML) :: alloc_msg
    INTEGER :: io_stat
    INTEGER :: alloc_stat
    LOGICAL :: noisy
    LOGICAL :: yes_close
    INTEGER :: fid
    INTEGER :: m, n_input_profiles
 

    ! Set up
    err_stat = success
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Check file close argument
    yes_close = .true.
    IF ( PRESENT(no_close) ) yes_close = .NOT. no_close
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) noisy = debug


    ! Check if the file is open
    IF ( file_open( filename ) ) THEN
      ! Yes, the file is already open
      ! ...Get the file id
      INQUIRE( file=filename,number=fid )
      IF ( fid == -1 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its unit number'
        CALL read_cleanup(); RETURN
      END IF
    ELSE
      ! No, the file is not open
      ! ...Check that the file exists
      IF ( .NOT. file_exists( filename ) ) THEN
        msg = 'File '//trim(filename)//' not found.'
        CALL read_cleanup(); RETURN
      END IF
      ! ...Open the file
      err_stat = open_binary_file( filename, fid )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Read the dimensions     
    READ( fid,iostat=io_stat,iomsg=io_msg ) n_input_profiles
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading dimension from '//trim(filename)//' - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Allocate the return structure array
    ALLOCATE(geometry(n_input_profiles), stat=alloc_stat, errmsg=alloc_msg)
    IF ( alloc_stat /= 0 ) THEN
      msg = 'Error allocating Geometry array - '//trim(alloc_msg)
      CALL read_cleanup(); RETURN
    END IF


    ! Read the geometry data
    geometry_loop: DO m = 1, n_input_profiles
      err_stat = crtm_geometry_readrecord( fid, geometry(m) )
      IF ( err_stat /= success ) THEN
        WRITE( msg,'("Error reading Geometry element #",i0," from ",a)' ) m, trim(filename)
        CALL read_cleanup(); RETURN
      END IF
    END DO geometry_loop


    ! Close the file
    IF ( yes_close ) THEN
      CLOSE( fid,iostat=io_stat,iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Set the return values
    IF ( PRESENT(n_profiles) ) n_profiles = n_input_profiles


    ! Output an info message
    IF ( noisy ) THEN
      WRITE( msg,'("Number of Geometry entries read from ",a,": ",i0)' ) &
             trim(filename), n_input_profiles
      CALL display_message( routine_name, msg, information )
    END IF

  CONTAINS
  
    SUBROUTINE read_cleanup()
      IF ( file_open(fid) ) THEN
        CLOSE( fid,iostat=io_stat,iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      IF ( ALLOCATED(geometry) ) THEN 
        DEALLOCATE(geometry, stat=alloc_stat, errmsg=alloc_msg)
        IF ( alloc_stat /= 0 ) &
          msg = trim(msg)//'; Error deallocating Geometry array during error cleanup - '//&
                trim(alloc_msg)
      END IF
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE read_cleanup
  
  END FUNCTION crtm_geometry_readfile


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_WriteFile
!
! PURPOSE:
!       Function to write CRTM Geometry object files.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Geometry_WriteFile( Filename           , &
!                                               Geometry           , &
!                                               Quiet    = Quiet   , &
!                                               No_Close = No_Close  )
!
! INPUTS:
!       Filename:     Character string specifying the name of the
!                     Geometry format data file to write.
!                     UNITS:      N/A
!                     TYPE:       CHARACTER(*)
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN)
!
!       Geometry:     CRTM Geometry object array containing the Geometry
!                     data to write.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Rank-1
!                     ATTRIBUTES: INTENT(IN)
!
! OPTIONAL INPUTS:
!       Quiet:        Set this logical argument to suppress INFORMATION
!                     messages being printed to stdout
!                     If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                        == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                     If not specified, default is .FALSE.
!                     UNITS:      N/A
!                     TYPE:       LOGICAL
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       No_Close:     Set this logical argument to NOT close the file upon exit.
!                     If == .FALSE., the input file is closed upon exit [DEFAULT]
!                        == .TRUE.,  the input file is NOT closed upon exit.
!                     If not specified, default is .FALSE.
!                     UNITS:      N/A
!                     TYPE:       LOGICAL
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status: The return value is an integer defining the error status.
!                     The error codes are defined in the Message_Handler module.
!                     If == SUCCESS, the file write was successful
!                        == FAILURE, an unrecoverable error occurred.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!
! SIDE EFFECTS:
!       - If the output file already exists, it is overwritten.
!       - If an error occurs during *writing*, the output file is deleted before
!         returning to the calling routine.
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_geometry_writefile( &
    Filename, &  ! Input
    Geometry, &  ! Input
    Quiet   , &  ! Optional input
    No_Close, &  ! Optional input
    Debug   ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    CHARACTER(*),             INTENT(IN) :: filename
    TYPE(crtm_geometry_type), INTENT(IN) :: geometry(:)
    LOGICAL,        OPTIONAL, INTENT(IN) :: quiet
    LOGICAL,        OPTIONAL, INTENT(IN)  :: no_close
    LOGICAL,        OPTIONAL, INTENT(IN) :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_WriteFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
    LOGICAL :: noisy
    LOGICAL :: yes_close
    INTEGER :: fid
    INTEGER :: m, ng
 
    ! Set up
    err_stat = success
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Check file close argument
    yes_close = .true.
    IF ( PRESENT(no_close) ) yes_close = .NOT. no_close
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) noisy = debug


    ! Check if the file is open
    IF ( file_open( filename ) ) THEN
      ! Yes, the file is already open
      INQUIRE( file=filename,number=fid )
      IF ( fid == -1 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its unit number'
        CALL write_cleanup(); RETURN
      END IF
    ELSE
      ! No, the file is not open
      err_stat = open_binary_file( filename, fid, for_output = .true. )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Write the dimensions
    ng = SIZE(geometry)
    WRITE( fid,iostat=io_stat,iomsg=io_msg ) ng
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing data dimension to '//trim(filename)//'- '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF

    
    ! Write the data
    geometry_loop: DO m = 1, ng
      err_stat = crtm_geometry_writerecord( fid, geometry(m) )
      IF ( err_stat /= success ) THEN
        WRITE( msg,'("Error writing Geometry element #",i0," to ",a)' ) m, trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END DO geometry_loop


    ! Close the file (if error, no delete)
    IF ( yes_close ) THEN
      CLOSE( fid,status='KEEP',iostat=io_stat,iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//'- '//trim(io_msg)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
    IF ( noisy ) THEN
      WRITE( msg,'("Number of geometry entries written to ",a,": ",i0)' ) trim(filename), ng
      CALL display_message( routine_name, msg, information )
    END IF

  CONTAINS
  
    SUBROUTINE write_cleanup()
      IF ( file_open(fid) ) THEN
        CLOSE( fid,status=write_error_status,iostat=io_stat,iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error deleting output file during error cleanup - '//trim(io_msg)
      END IF
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE write_cleanup

  END FUNCTION crtm_geometry_writefile


!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_ReadRecord
!
! PURPOSE:
!       Utility function to read a single Geometry data record
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Geometry_ReadRecord( FileID, Geometry )
!
! INPUTS:
!       FileID:       Logical unit number from which to read data.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Geometry:     CRTM Geometry object containing the data read in.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(OUT)
!
! FUNCTION RESULT:
!       Error_Status: The return value is an integer defining the error status.
!                     The error codes are defined in the Message_Handler module.
!                     If == SUCCESS, the read was successful
!                        == FAILURE, an unrecoverable error occurred.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION crtm_geometry_readrecord( fid, geo ) RESULT( err_stat )
    ! Arguments
    INTEGER,                  INTENT(IN)  :: fid
    TYPE(crtm_geometry_type), INTENT(OUT) :: geo
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_ReadRecord'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat

    ! Set up
    err_stat = success

    ! Read the data record
    READ( fid,iostat=io_stat,iomsg=io_msg ) &
      geo%iFOV                , &
      geo%Longitude           , &
      geo%Latitude            , &
      geo%Surface_Altitude    , &
      geo%Sensor_Scan_Angle   , &
      geo%Sensor_Zenith_Angle , &
      geo%Sensor_Azimuth_Angle, &
      geo%Source_Zenith_Angle , &
      geo%Source_Azimuth_Angle, &
      geo%Flux_Zenith_Angle   , &
      geo%Year                , &
      geo%Month               , &
      geo%Day  
           
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Geometry data - '//trim(io_msg)
      CALL read_record_cleanup(); RETURN
    END IF

  CONTAINS
  
    SUBROUTINE read_record_cleanup()
      CALL crtm_geometry_destroy( geo )
      CLOSE( fid,iostat=io_stat,iomsg=io_msg )
      IF ( io_stat /= success ) &
        msg = trim(msg)//'; Error closing file during error cleanup - '//trim(io_msg)
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE read_record_cleanup

  END FUNCTION crtm_geometry_readrecord


!----------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_Geometry_WriteRecord
!
! PURPOSE:
!       Function to write a single Geometry data record
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_Geometry_WriteRecord( FileID, Geometry )
!
! INPUTS:
!       FileID:       Logical unit number to which data is written
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN)
!
!       Geometry:     CRTM Geometry object containing the data to write.
!                     UNITS:      N/A
!                     TYPE:       CRTM_Geometry_type
!                     DIMENSION:  Scalar
!                     ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       Error_Status: The return value is an integer defining the error status.
!                     The error codes are defined in the Message_Handler module.
!                     If == SUCCESS the record write was successful
!                        == FAILURE an unrecoverable error occurred.
!                     UNITS:      N/A
!                     TYPE:       INTEGER
!                     DIMENSION:  Scalar
!:sdoc-:
!----------------------------------------------------------------------------------

  FUNCTION crtm_geometry_writerecord( fid, geo ) RESULT( err_stat )
    ! Arguments
    INTEGER,                  INTENT(IN)  :: fid
    TYPE(crtm_geometry_type), INTENT(IN)  :: geo
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_Geometry_WriteRecord'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
 
    ! Set up
    err_stat = success


    ! Write the data record
    WRITE( fid,iostat=io_stat,iomsg=io_msg ) &
      geo%iFOV                , &
      geo%Longitude           , &
      geo%Latitude            , &
      geo%Surface_Altitude    , &
      geo%Sensor_Scan_Angle   , &
      geo%Sensor_Zenith_Angle , &
      geo%Sensor_Azimuth_Angle, &
      geo%Source_Zenith_Angle , &
      geo%Source_Azimuth_Angle, &
      geo%Flux_Zenith_Angle   , &
      geo%Year                , &
      geo%Month               , &
      geo%Day     
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing Geometry data - '//trim(io_msg)
      CALL write_record_cleanup(); RETURN
    END IF

  CONTAINS
  
    SUBROUTINE write_record_cleanup()
      CLOSE( fid,status=write_error_status,iostat=io_stat,iomsg=io_msg )
      IF ( io_stat /= success ) &
        msg = trim(msg)//'; Error closing file during error cleanup - '//trim(io_msg)
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE write_record_cleanup
    
  END FUNCTION crtm_geometry_writerecord


!##################################################################################
!##################################################################################
!##                                                                              ##
!##                          ## PRIVATE MODULE ROUTINES ##                       ##
!##                                                                              ##
!##################################################################################
!##################################################################################

!--------------------------------------------------------------------------------
!
! NAME:
!       CRTM_Geometry_Equal
!
! PURPOSE:
!       Elemental function to test the equality of two CRTM_Geometry objects.
!       Used in OPERATOR(==) interface block.
!
! CALLING SEQUENCE:
!       is_equal = CRTM_Geometry_Equal( x, y )
!
!         or
!
!       IF ( x == y ) THEN
!         ...
!       END IF
!
! OBJECTS:
!       x, y:          Two CRTM Geometry objects to be compared.
!                      UNITS:      N/A
!                      TYPE:       CRTM_Geometry_type
!                      DIMENSION:  Scalar or any rank
!                      ATTRIBUTES: INTENT(IN)
!
! FUNCTION RESULT:
!       is_equal:      Logical value indicating whether the inputs are equal.
!                      UNITS:      N/A
!                      TYPE:       LOGICAL
!                      DIMENSION:  Same as inputs.
!
!--------------------------------------------------------------------------------

  ELEMENTAL FUNCTION crtm_geometry_equal( x, y ) RESULT( is_equal )
    TYPE(crtm_geometry_type) , INTENT(IN)  :: x, y
    LOGICAL :: is_equal

    is_equal = ( (x%iFOV                    ==     y%iFOV                ) .AND. &
                 (x%Longitude            .equalto. y%Longitude           ) .AND. &
                 (x%Latitude             .equalto. y%Latitude            ) .AND. &
                 (x%Surface_Altitude     .equalto. y%Surface_Altitude    ) .AND. &
                 (x%Sensor_Scan_Angle    .equalto. y%Sensor_Scan_Angle   ) .AND. &
                 (x%Sensor_Zenith_Angle  .equalto. y%Sensor_Zenith_Angle ) .AND. &
                 (x%Sensor_Azimuth_Angle .equalto. y%Sensor_Azimuth_Angle) .AND. &
                 (x%Source_Zenith_Angle  .equalto. y%Source_Zenith_Angle ) .AND. &
                 (x%Source_Azimuth_Angle .equalto. y%Source_Azimuth_Angle) .AND. &
                 (x%Flux_Zenith_Angle    .equalto. y%Flux_Zenith_Angle   ) .AND. &
                 (x%Year  == y%Year ) .AND. &
                 (x%Month == y%Month) .AND. &
                 (x%Day   == y%Day  )       )
    
  END FUNCTION crtm_geometry_equal


!--------------------------------------------------------------------------------
!
! NAME:
!       CRTM_Geometry_Subtract
!
! PURPOSE:
!       Elemental function to subtract two CRTM Geometry objects.
!       Used in OPERATOR(-) interface block.
!
! CALLING SEQUENCE:
!       gdiff = CRTM_Geometry_Subtract( g1, g2 )
!
!         or
!
!       gsum = g1 - g2
!
!
! INPUTS:
!       g1, g2:   The Geometry objects to difference.
!                   UNITS:      N/A
!                   TYPE:       CRTM_Geometry_type
!                   DIMENSION:  Scalar
!                   ATTRIBUTES: INTENT(IN OUT)
!
! RESULT:
!       gdiff:     Geometry object containing the differenced components.
!                   UNITS:      N/A
!                   TYPE:       CRTM_Geometry_type
!                   DIMENSION:  Scalar
!
!--------------------------------------------------------------------------------

  ELEMENTAL FUNCTION crtm_geometry_subtract( g1, g2 ) RESULT( gdiff )
    TYPE(crtm_geometry_type), INTENT(IN) :: g1, g2
    TYPE(crtm_geometry_type) :: gdiff

    ! Copy the first structure
    gdiff = g1

    ! And subtract the second one's components from it
    gdiff%iFOV                 = gdiff%iFOV                 - g2%iFOV
    gdiff%Longitude            = gdiff%Longitude            - g2%Longitude
    gdiff%Latitude             = gdiff%Latitude             - g2%Latitude
    gdiff%Surface_Altitude     = gdiff%Surface_Altitude     - g2%Surface_Altitude
    gdiff%Sensor_Scan_Angle    = gdiff%Sensor_Scan_Angle    - g2%Sensor_Scan_Angle
    gdiff%Sensor_Zenith_Angle  = gdiff%Sensor_Zenith_Angle  - g2%Sensor_Zenith_Angle
    gdiff%Sensor_Azimuth_Angle = gdiff%Sensor_Azimuth_Angle - g2%Sensor_Azimuth_Angle
    gdiff%Source_Zenith_Angle  = gdiff%Source_Zenith_Angle  - g2%Source_Zenith_Angle
    gdiff%Source_Azimuth_Angle = gdiff%Source_Azimuth_Angle - g2%Source_Azimuth_Angle
    gdiff%Flux_Zenith_Angle    = gdiff%Flux_Zenith_Angle    - g2%Flux_Zenith_Angle
    gdiff%Year                 = gdiff%Year                 - g2%Year
    gdiff%Month                = gdiff%Month                - g2%Month
    gdiff%Day                  = gdiff%Day                  - g2%Day

  END FUNCTION crtm_geometry_subtract

END MODULE crtm_geometry_define