CRTM_FastemX.f90

Go to the documentation of this file.

!
! CRTM_FastemX
!
! Module containing the Fastem4/5/6 procedures. The difference between the Fastem4
! and Fastem5 models is realised purely through the coefficients read during CRTM
! initialisation. For Fastem6, a different azimuth emissivity model is used.
!
! CREATION HISTORY:
!       Written by:     Quanhua (Mark) Liu, Quanhua.Liu@noaa.gov
!                       Stephen English, Stephen.English@metoffice.gov.uk
!                       Fuzhong Weng, Fuzhong.Weng@noaa.gov
!                       July, 2009
!
!       Refactored by:  Paul van Delst, paul.vandelst@noaa.gov
!                       October, 2010
!
!       Modified by:    Quanhua Liu, Quanhua.Liu@noaa.gov
!                       Stephen English, Stephen.English@metoffice.gov.uk
!                       August, 2011
!
!       Refactored by:  Paul van Delst, paul.vandelst@noaa.gov
!                       December, 2011
!
!       Renamed:        Separate Fastem4 and Fastem5 modules replaced with
!                       single module named "FastemX"
!                       Paul van Delst, paul.vandelst@noaa.gov
!                       March, 2012
!
!       Added:          M. Kazumori's azimuthal emissivity model for FASTEM6.
!                       Paul van Delst, paul.vandelst@noaa.gov
!                       January, 2015
!

MODULE crtm_fastemx

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds         , ONLY: fp
  USE mwwatercoeff_define, ONLY: mwwatercoeff_type

  USE crtm_parameters, &
    only: pi, degrees_to_radians, &
          zero, one, two, three, point_5

  USE fresnel, &
    only: fvar_type => ivar_type , &
          fresnel_reflectivity   , &
          fresnel_reflectivity_tl, &
          fresnel_reflectivity_ad

  USE liu, &
    only: pvar_type => ivar_type, &
          ocean_permittivity    => liu_ocean_permittivity   , &
          ocean_permittivity_tl => liu_ocean_permittivity_tl, &
          ocean_permittivity_ad => liu_ocean_permittivity_ad

  USE foam_utility_module, &
    only: foam_coverage, &
          foam_coverage_tl, &
          foam_coverage_ad, &
          foam_reflectivity

  USE small_scale_correction_module, &
    only: sscvar_type => ivar_type, &
          small_scale_correction, &
          small_scale_correction_tl, &
          small_scale_correction_ad

  USE large_scale_correction_module, &
    only: lscvar_type => ivar_type, &
          large_scale_correction, &
          large_scale_correction_tl, &
          large_scale_correction_ad

  USE reflection_correction_module, &
    only: rcvar_type => ivar_type, &
          reflection_correction   , &
          reflection_correction_tl, &
          reflection_correction_ad

  USE azimuth_emissivity_module, &
    only: aevar_type => ivar_type, &
          azimuth_emissivity   , &
          azimuth_emissivity_tl, &
          azimuth_emissivity_ad
  USE azimuth_emissivity_f6_module, &
    only: aef6var_type => ivar_type, &
          azimuth_emissivity_f6   , &
          azimuth_emissivity_f6_tl, &
          azimuth_emissivity_f6_ad

  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  PRIVATE
  ! Data types
  PUBLIC :: ivar_type
  ! Science routines
  PUBLIC :: compute_fastemx
  PUBLIC :: compute_fastemx_tl
  PUBLIC :: compute_fastemx_ad


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: CRTM_FastemX.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'

  ! FASTEM6 version number for use with azimuth model
  INTEGER, PARAMETER :: fastem6 = 6
  
  ! Stokes component information
  ! ...The number of Stokes components
  INTEGER, PARAMETER :: n_stokes = 4
  ! ...The vector indices
  INTEGER, PARAMETER :: iv_idx = 1 ! Describes vertical polarization
  INTEGER, PARAMETER :: ih_idx = 2 ! Describes horizontal polarization
  INTEGER, PARAMETER :: u_idx  = 3 ! Describes plane of polarization
  INTEGER, PARAMETER :: v_idx  = 4 ! Describes ellipticity of polarization

  ! Invalid indicators
  REAL(fp), PARAMETER :: invalid_azimuth_angle = -999.0_fp
  REAL(fp), PARAMETER :: invalid_transmittance = -999.0_fp  ! Disable non-specular correction


  ! --------------------------------------
  ! Structure definition to hold internal
  ! variables across FWD, TL, and AD calls
  ! --------------------------------------
  TYPE :: ivar_type
    PRIVATE
    ! Validity indicator
    LOGICAL :: is_valid = .false.
    ! Forward model input values
    REAL(fp) :: frequency    = zero
    REAL(fp) :: zenith_angle = zero
    REAL(fp) :: temperature  = zero
    REAL(fp) :: salinity     = zero
    REAL(fp) :: wind_speed   = zero
    ! ...Optional
    LOGICAL  :: azimuth_angle_valid = .false.
    REAL(fp) :: azimuth_angle       = zero
    LOGICAL  :: transmittance_valid = .false.
    REAL(fp) :: transmittance       = zero
    ! The zenith angle term
    REAL(fp) :: cos_z = one
    ! The permittivity term
    COMPLEX(fp) :: permittivity = zero
    ! The Fresnel reflectivity terms
    REAL(fp) :: rv_fresnel = zero
    REAL(fp) :: rh_fresnel = zero
    ! Foam Terms
    REAL(fp) :: rv_foam = zero
    REAL(fp) :: rh_foam = zero
    REAL(fp) :: foam_cover = zero
    ! Large scale correction reflectivities
    REAL(fp) :: rv_large = zero
    REAL(fp) :: rh_large = zero
    ! Small scale correction factor
    REAL(fp) :: f_small = zero
    ! Final reflectivities
    REAL(fp) :: rv = zero
    REAL(fp) :: rh = zero
    ! Azimuthal emissivity
    REAL(fp) :: e_azimuth(n_stokes) = zero
    ! Anisotropic downward radiation correction
    REAL(fp) :: rv_mod = zero
    REAL(fp) :: rh_mod = zero
    ! The final emissivity
    REAL(fp) :: e(n_stokes) = zero
    ! Internal variables for subcomponents
    TYPE(pvar_type)    :: pvar
    TYPE(fvar_type)    :: fvar
    TYPE(sscvar_type)  :: sscvar
    TYPE(lscvar_type)  :: lscvar
    TYPE(aevar_type)   :: aevar
    TYPE(aef6var_type) :: aef6var
    TYPE(rcvar_type)   :: rcvar
  END TYPE ivar_type


CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                         ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################

!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_FastemX
!
! PURPOSE:
!       Subroutine to compute the Fastem4 or Fastem5 microwave sea surface
!       emissivity and reflectivity.
!
! CALLING SEQUENCE:
!       CALL Compute_FastemX( &
!              MWwaterCoeff , &  ! Input
!              Frequency    , &  ! Input
!              Zenith_Angle , &  ! Input
!              Temperature  , &  ! Input
!              Salinity     , &  ! Input
!              Wind_Speed   , &  ! Input
!              iVar         , &  ! Internal variable output
!              Emissivity   , &  ! Output
!              Reflectivity , &  ! Output
!              Azimuth_Angle, &  ! Optional input
!              Transmittance  )  ! Optional input
!
!
! INPUTS:
!       MWwaterCoeff:   Microwave water emissivity model coefficient object.
!                       Load the object with the coefficients for the emissivity
!                       model to use (Fastem4 or Fastem5)
!                       UNITS:      N/A
!                       TYPE:       MWwaterCoeff_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       Frequency:      Microwave frequency.
!                       UNITS:      GHz
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       Zenith_Angle:   Sensor zenith angle at the sea surface
!                       UNITS:      Degrees
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       Temperature:    Sea surface temperature
!                       UNITS:      Kelvin, K
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       Salinity:       Water salinity
!                       UNITS:      ppt (parts per thousand)
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
!       Wind_Speed:     Sea surface wind speed
!                       UNITS:      m/s
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       iVar:           Structure containing internal variables required for
!                       subsequent tangent-linear or adjoint model calls.
!                       The contents of this structure are NOT accessible
!                       outside of this module.
!                       UNITS:      N/A
!                       TYPE:       iVar_type
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(OUT)
!
!       Emissivity:     The surface emissivity
!                       UNITS:      N/A
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                       ATTRIBUTES: INTENT(OUT)
!
!       Reflectivity:   The surface reflectivity.
!                       UNITS:      N/A
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                       ATTRIBUTES: INTENT(OUT)
!
! OPTIONAL INPUTS:
!       Azimuth_Angle:  Relative azimuth angle (wind direction - sensor azimuth)
!                       UNITS:      Degrees
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Transmittance:  Total atmospheric transmittance
!                       UNITS:      N/A
!                       TYPE:       REAL(fp)
!                       DIMENSION:  Scalar
!                       ATTRIBUTES: INTENT(IN), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE compute_fastemx( &
    MWwaterCoeff , &  ! Input
    Frequency    , &  ! Input
    Zenith_Angle , &  ! Input
    Temperature  , &  ! Input
    Salinity     , &  ! Input
    Wind_Speed   , &  ! Input
    iVar         , &  ! Internal variable output
    Emissivity   , &  ! Output
    Reflectivity , &  ! Output
    Azimuth_Angle, &  ! Optional Input
    Transmittance  )  ! Optional Input
    ! Arguments
    TYPE(mwwatercoeff_type), INTENT(IN)  :: mwwatercoeff
    REAL(fp),                INTENT(IN)  :: frequency
    REAL(fp),                INTENT(IN)  :: zenith_angle
    REAL(fp),                INTENT(IN)  :: temperature
    REAL(fp),                INTENT(IN)  :: salinity
    REAL(fp),                INTENT(IN)  :: wind_speed
    TYPE(ivar_type),         INTENT(OUT) :: ivar
    REAL(fp),                INTENT(OUT) :: emissivity(:)
    REAL(fp),                INTENT(OUT) :: reflectivity(:)
    REAL(fp),      OPTIONAL, INTENT(IN)  :: azimuth_angle
    REAL(fp),      OPTIONAL, INTENT(IN)  :: transmittance

    ! Setup
    ! ...Save forward input variables for TL and AD calculations
    ivar%Frequency    = frequency
    ivar%Zenith_Angle = zenith_angle
    ivar%Temperature  = temperature
    ivar%Salinity     = salinity
    ivar%Wind_Speed   = wind_speed
    ! ...Save derived variables
    ivar%cos_z = cos(zenith_angle*degrees_to_radians)

    ! Permittivity calculation
    CALL ocean_permittivity( temperature, salinity, frequency, &
                             ivar%Permittivity, &
                             ivar%pVar )


    ! Fresnel reflectivity calculation
    CALL fresnel_reflectivity( ivar%Permittivity, ivar%cos_z, &
                               ivar%Rv_Fresnel, ivar%Rh_Fresnel, &
                               ivar%fVar )


    ! Foam reflectivity calculation
    CALL foam_reflectivity( &
           mwwatercoeff%FRCoeff, &
           zenith_angle, &
           frequency   , &
           ivar%Rv_Foam, &
           ivar%Rh_Foam  )


    ! Foam coverage calculation
    CALL foam_coverage( &
           mwwatercoeff%FCCoeff, &
           wind_speed, &
           ivar%Foam_Cover )


    ! Large scale correction calculation
    CALL large_scale_correction( &
           mwwatercoeff%LSCCoeff, &
           ivar%Frequency , &
           ivar%cos_z     , &
           ivar%Wind_Speed, &
           ivar%Rv_Large  , &
           ivar%Rh_Large  , &
           ivar%lscVar      )

    ! Small scale correction calculation, Var%small_corr
    CALL small_scale_correction( &
           mwwatercoeff%SSCCoeff, &
           ivar%Frequency , &
           ivar%cos_z     , &
           ivar%Wind_Speed, &
           ivar%F_Small   , &
           ivar%sscVar      )

    ! Compute the first two Stokes components of the emissivity
    ivar%Rv = ivar%Rv_Fresnel*ivar%F_Small -ivar%Rv_Large
    ivar%Rh = ivar%Rh_Fresnel*ivar%F_Small -ivar%Rh_Large
    emissivity(iv_idx) = one - (one-ivar%Foam_Cover)*ivar%Rv - ivar%Foam_Cover*ivar%Rv_Foam
    emissivity(ih_idx) = one - (one-ivar%Foam_Cover)*ivar%Rh - ivar%Foam_Cover*ivar%Rh_Foam

    ! Azimuthal component calculation
    ivar%Azimuth_Angle_Valid = .false.
    ivar%e_Azimuth = zero
    IF ( PRESENT(azimuth_angle) ) THEN
      IF ( abs(azimuth_angle) <= 360.0_fp ) THEN
        IF ( mwwatercoeff%Version == fastem6 ) THEN
          CALL azimuth_emissivity_f6( &
                 mwwatercoeff%AZCoeff, &
                 ivar%Wind_Speed, &
                 azimuth_angle  , &
                 ivar%Frequency , &
                 zenith_angle   , &
                 ivar%e_Azimuth , &
                 ivar%aeF6Var     )
        ELSE
          CALL azimuth_emissivity( &
                 mwwatercoeff%AZCoeff, &
                 ivar%Wind_Speed, &
                 azimuth_angle  , &
                 ivar%Frequency , &
                 ivar%cos_z     , &
                 ivar%e_Azimuth , &
                 ivar%aeVar       )
        END IF
        ivar%Azimuth_Angle_Valid = .true.
        ivar%Azimuth_Angle       = azimuth_angle
      END IF
    END IF

    ! Anisotropic downward radiation correction calculation
    ivar%Transmittance_Valid = .false.
    ivar%Rv_Mod = one
    ivar%Rh_Mod = one
    IF ( PRESENT(transmittance) ) THEN
      IF ( transmittance > zero .AND. transmittance < one ) THEN
        CALL reflection_correction( &
               mwwatercoeff%RCCoeff, &
               ivar%Frequency , &
               ivar%cos_z     , &
               ivar%Wind_Speed, &
               transmittance  , &
               ivar%Rv_Mod    , &
               ivar%Rh_Mod    , &
               ivar%rcVar       )
        ivar%Transmittance_Valid = .true.
        ivar%Transmittance       = transmittance
      END IF
    END IF

    ! Assemble the return...
    ! ...emissivities
    emissivity(iv_idx) = emissivity(iv_idx) + ivar%e_Azimuth(iv_idx)
    emissivity(ih_idx) = emissivity(ih_idx) + ivar%e_Azimuth(ih_idx)
    emissivity(u_idx)  = ivar%e_Azimuth(u_idx)
    emissivity(v_idx)  = ivar%e_Azimuth(v_idx)
    ! ...reflectivties

    reflectivity(iv_idx)      = ivar%Rv_Mod * (one-emissivity(iv_idx))
    reflectivity(ih_idx)      = ivar%Rh_Mod * (one-emissivity(ih_idx))
    reflectivity(u_idx:v_idx) = zero   ! 3rd, 4th Stokes from atmosphere are not included.
    ! ...save the emissivity for TL and AD reflectivity calculations
    ivar%e = emissivity


    ! Flag the internal variable structure as valid
    ivar%Is_Valid = .true.

  END SUBROUTINE compute_fastemx


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_FastemX_TL
!
! PURPOSE:
!       Subroutine to compute the tangent-linear Fastem4 or Fastem5 microwave
!       sea surface emissivity and reflectivity.
!
!       NOTE: The forward model must be called first to fill the internal
!             variable argument with the intermediate forward calculations.
!
! CALLING SEQUENCE:
!       CALL Compute_FastemX_TL( &
!              MWwaterCoeff    , &
!              Temperature_TL  , &
!              Salinity_TL     , &
!              Wind_Speed_TL   , &
!              iVar            , &
!              Emissivity_TL   , &
!              Reflectivity_TL , &
!              Azimuth_Angle_TL, &
!              Transmittance_TL  )
!
!
! INPUTS:
!       MWwaterCoeff:      Microwave water emissivity model coefficient object.
!                          Load the object with the coefficients for the emissivity
!                          model to use (Fastem4 or Fastem5)
!                          UNITS:      N/A
!                          TYPE:       MWwaterCoeff_type
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
!       Temperature_TL:    Tangent-linear sea surface temperature
!                          UNITS:      Kelvin, K
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
!       Salinity_TL:       Tangent-linear water salinity
!                          UNITS:      ppt (parts per thousand)
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
!       Wind_Speed_TL:     Tangent-linear sea surface wind speed
!                          UNITS:      m/s
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
!       iVar:              Structure containing internal variables computed
!                          in a previous forward model call.
!                          The contents of this structure are NOT accessible
!                          outside of this module.
!                          UNITS:      N/A
!                          TYPE:       iVar_type
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Emissivity_TL:     Tangent-linear surface emissivity
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                          ATTRIBUTES: INTENT(OUT)
!
!       Reflectivity_TL:   Tangent-linear surface reflectivity.
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                          ATTRIBUTES: INTENT(OUT)
!
! OPTIONAL INPUTS:
!       Azimuth_Angle_TL:  Tangent-linear relative azimuth angle.
!                          This argument is ignored if a valid relative azimuth
!                          angle was not passed into the forward model call.
!                          UNITS:      Degrees
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Transmittance_TL:  Tangent-linear total atmospheric transmittance
!                          This argument is ignored if a valid transmittance
!                          was not passed into the forward model call.
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE compute_fastemx_tl( &
    MWwaterCoeff    , &  ! Input
    Temperature_TL  , &  ! TL  Input
    Salinity_TL     , &  ! TL  Input
    Wind_Speed_TL   , &  ! TL  Input
    iVar            , &  ! Internal variable input
    Emissivity_TL   , &  ! TL Output
    Reflectivity_TL , &  ! TL Output
    Azimuth_Angle_TL, &  ! Optional TL  input
    Transmittance_TL  )  ! Optional TL  input
    ! Arguments
    TYPE(mwwatercoeff_type), INTENT(IN)  :: mwwatercoeff
    REAL(fp),                INTENT(IN)  :: temperature_tl
    REAL(fp),                INTENT(IN)  :: salinity_tl
    REAL(fp),                INTENT(IN)  :: wind_speed_tl
    TYPE(ivar_type),         INTENT(IN)  :: ivar
    REAL(fp),                INTENT(OUT) :: emissivity_tl(:)
    REAL(fp),                INTENT(OUT) :: reflectivity_tl(:)
    REAL(fp),      OPTIONAL, INTENT(IN)  :: azimuth_angle_tl
    REAL(fp),      OPTIONAL, INTENT(IN)  :: transmittance_tl
    ! Local variables
    REAL(fp) :: rv_fresnel_tl, rh_fresnel_tl
    REAL(fp) :: rv_foam_tl   , rh_foam_tl
    REAL(fp) :: rv_large_tl  , rh_large_tl
    REAL(fp) :: rv_tl        , rh_tl
    REAL(fp) :: rv_mod_tl    , rh_mod_tl
    REAL(fp) :: foam_cover_tl
    REAL(fp) :: e_azimuth_tl(n_stokes)
    COMPLEX(fp) :: permittivity_tl
    REAL(fp) :: f_small_tl

    ! Check internal structure
    IF ( .NOT. ivar%Is_Valid ) THEN
      emissivity_tl   = zero
      reflectivity_tl = zero
      RETURN
    END IF


    ! Permittivity calculation
    CALL ocean_permittivity_tl( temperature_tl, salinity_tl, ivar%Frequency, &
                                permittivity_tl, &
                                ivar%pVar)


    ! Fresnel reflectivity calculation
    CALL fresnel_reflectivity_tl( permittivity_tl, ivar%cos_z, &
                                  rv_fresnel_tl, rh_fresnel_tl, &
                                  ivar%fVar )


    ! Foam reflectivity "calculation"
    rv_foam_tl = zero
    rh_foam_tl = zero


    ! Foam coverage calculation
    CALL foam_coverage_tl( &
           mwwatercoeff%FCCoeff, &
           ivar%Wind_Speed, &
           wind_speed_tl, &
           foam_cover_tl )


    ! Large Scale Correction Calculation
    CALL large_scale_correction_tl( &
           wind_speed_tl, &
           rv_large_tl  , &
           rh_large_tl  , &
           ivar%lscVar    )


    ! Small Scale Correction Calculation
    CALL small_scale_correction_tl( &
           mwwatercoeff%SSCCoeff, &
           wind_speed_tl, &
           f_small_tl   , &
           ivar%sscVar    )

    ! Compute the first two Stokes components of the tangent-linear emissivity
    rv_tl = rv_fresnel_tl*ivar%F_Small + ivar%Rv_Fresnel*f_small_tl - rv_large_tl
    emissivity_tl(iv_idx) = (ivar%Foam_Cover-one)*rv_tl + &
                            (ivar%Rv-ivar%Rv_Foam)*foam_cover_tl - &
                            ivar%Foam_Cover*rv_foam_tl
    rh_tl = rh_fresnel_tl*ivar%F_Small + ivar%Rh_Fresnel*f_small_tl - rh_large_tl
    emissivity_tl(ih_idx) = (ivar%Foam_Cover-one)*rh_tl + &
                            (ivar%Rh-ivar%Rh_Foam)*foam_cover_tl - &
                            ivar%Foam_Cover*rh_foam_tl

    ! Azimuthal component calculation
    IF ( PRESENT(azimuth_angle_tl) .AND. ivar%Azimuth_Angle_Valid ) THEN
      IF ( mwwatercoeff%Version == fastem6 ) THEN
        CALL azimuth_emissivity_f6_tl( &
               mwwatercoeff%AZCoeff, &
               wind_speed_tl       , &
               azimuth_angle_tl    , &
               e_azimuth_tl        , &
               ivar%aeF6Var          )
      
      ELSE
        CALL azimuth_emissivity_tl( &
               mwwatercoeff%AZCoeff, &
               wind_speed_tl   , &
               azimuth_angle_tl, &
               e_azimuth_tl    , &
               ivar%aeVar        )
      END IF
    ELSE
      e_azimuth_tl = zero
    END IF


    ! Anisotropic downward radiation correction calculation
    IF ( PRESENT(transmittance_tl) .AND. ivar%Transmittance_Valid ) THEN
      CALL reflection_correction_tl( &
             mwwatercoeff%RCCoeff, &
             wind_speed_tl   , &
             transmittance_tl, &
             rv_mod_tl       , &
             rh_mod_tl       , &
             ivar%rcVar        )
    ELSE
      rv_mod_tl = zero
      rh_mod_tl = zero
    END IF


    ! Compute the tangent-linear...
    ! ...emissivities
    emissivity_tl(iv_idx) = emissivity_tl(iv_idx) + e_azimuth_tl(iv_idx)
    emissivity_tl(ih_idx) = emissivity_tl(ih_idx) + e_azimuth_tl(ih_idx)
    emissivity_tl(u_idx)  = e_azimuth_tl(u_idx)
    emissivity_tl(v_idx)  = e_azimuth_tl(v_idx)
    ! ...reflectivities
    reflectivity_tl(iv_idx)      = (one-ivar%e(iv_idx))*rv_mod_tl - ivar%Rv_Mod*emissivity_tl(iv_idx)
    reflectivity_tl(ih_idx)      = (one-ivar%e(ih_idx))*rh_mod_tl - ivar%Rh_Mod*emissivity_tl(ih_idx)
    reflectivity_tl(u_idx:v_idx) = zero  ! 3rd, 4th Stokes from atmosphere are not included.

  END SUBROUTINE compute_fastemx_tl


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Compute_FastemX_AD
!
! PURPOSE:
!       Subroutine to compute the adjoint Fastem4 or Fastem5 microwave
!       sea surface emissivity and reflectivity.
!
!       NOTE: The forward model must be called first to fill the internal
!             variable argument with the intermediate forward calculations.
!
! CALLING SEQUENCE:
!       CALL Compute_FastemX_AD( &
!              MWwaterCoeff    , &
!              Emissivity_AD   , &
!              Reflectivity_AD , &
!              iVar            , &
!              Temperature_AD  , &
!              Salinity_AD     , &
!              Wind_Speed_AD   , &
!              Azimuth_Angle_AD, &
!              Transmittance_AD  )
!
!
! INPUTS:
!       MWwaterCoeff:      Microwave water emissivity model coefficient object.
!                          Load the object with the coefficients for the emissivity
!                          model to use (Fastem4 or Fastem5)
!                          UNITS:      N/A
!                          TYPE:       MWwaterCoeff_type
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
!       Emissivity_AD:     Adjoint surface emissivity
!                          ***SET TO ZERO UPON EXIT***
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                          ATTRIBUTES: INTENT(IN OUT)
!
!       Reflectivity_AD:   Adjoint surface reflectivity.
!                          ***SET TO ZERO UPON EXIT***
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Rank-1, 4-elements (n_Stokes)
!                          ATTRIBUTES: INTENT(IN OUT)
!
!       iVar:              Structure containing internal variables computed
!                          in a previous forward model call.
!                          The contents of this structure are NOT accessible
!                          outside of this module.
!                          UNITS:      N/A
!                          TYPE:       iVar_type
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Temperature_AD:    Adjoint sea surface temperature
!                          ***MUST CONTAIN VALUE UPON ENTRY***
!                          UNITS:      K^-1
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN OUT)
!
!       Salinity_AD:       Adjoint water salinity
!                          ***MUST CONTAIN VALUE UPON ENTRY***
!                          UNITS:      ppt^-1 (parts per thousand)
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN OUT)
!
!       Wind_Speed_AD:     Adjoint sea surface wind speed
!                          ***MUST CONTAIN VALUE UPON ENTRY***
!                          UNITS:      (m/s)^-1
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN)
!
! OPTIONAL OUTPUTS:
!       Azimuth_Angle_AD:  Adjoint relative azimuth angle.
!                          This argument is ignored if a valid relative azimuth
!                          angle was not passed into the forward model call.
!                          UNITS:      Degrees^-1
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Transmittance_AD:  Adjoint total atmospheric transmittance
!                          This argument is ignored if a valid transmittance
!                          was not passed into the forward model call.
!                          UNITS:      N/A
!                          TYPE:       REAL(fp)
!                          DIMENSION:  Scalar
!                          ATTRIBUTES: INTENT(IN), OPTIONAL
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE compute_fastemx_ad( &
    MWwaterCoeff    , &  ! Input
    Emissivity_AD   , &  ! AD Input
    Reflectivity_AD , &  ! AD Input
    iVar            , &  ! Internal variable input
    Temperature_AD  , &  ! AD Output
    Salinity_AD     , &  ! AD Output
    Wind_Speed_AD   , &  ! AD Output
    Azimuth_Angle_AD, &  ! Optional AD Output
    Transmittance_AD )   ! Optional AD Output
    ! Arguments
    TYPE(mwwatercoeff_type), INTENT(IN)  :: mwwatercoeff
    REAL(fp),                INTENT(IN OUT) :: emissivity_ad(:)
    REAL(fp),                INTENT(IN OUT) :: reflectivity_ad(:)
    TYPE(ivar_type),         INTENT(IN)     :: ivar
    REAL(fp),                INTENT(IN OUT) :: temperature_ad
    REAL(fp),                INTENT(IN OUT) :: salinity_ad
    REAL(fp),                INTENT(IN OUT) :: wind_speed_ad
    REAL(fp),      OPTIONAL, INTENT(IN OUT) :: azimuth_angle_ad
    REAL(fp),      OPTIONAL, INTENT(IN OUT) :: transmittance_ad
    ! Local variables
    REAL(fp) :: rv_fresnel_ad, rh_fresnel_ad
    REAL(fp) :: rv_foam_ad   , rh_foam_ad
    REAL(fp) :: rv_large_ad  , rh_large_ad
    REAL(fp) :: rv_ad        , rh_ad
    REAL(fp) :: rv_mod_ad    , rh_mod_ad
    REAL(fp) :: foam_cover_ad
    REAL(fp) :: e_azimuth_ad(n_stokes)
    COMPLEX(fp) :: permittivity_ad
    REAL(fp) :: f_small_ad

    ! Check internal structure
    IF ( .NOT. ivar%Is_Valid ) THEN
      temperature_ad = zero
      salinity_ad    = zero
      wind_speed_ad  = zero
      IF ( PRESENT(azimuth_angle_ad) ) azimuth_angle_ad = zero
      IF ( PRESENT(transmittance_ad) ) transmittance_ad = zero
      RETURN
    END IF


    ! Compute the adjoint of the...
    ! ...reflectivities
    reflectivity_ad(u_idx:v_idx) = zero  ! 3rd, 4th Stokes from atmosphere are not included.

    emissivity_ad(ih_idx)   = emissivity_ad(ih_idx) - ivar%Rh_Mod*reflectivity_ad(ih_idx)
    rh_mod_ad               = (one-ivar%e(ih_idx))*reflectivity_ad(ih_idx)
    reflectivity_ad(ih_idx) = zero

    emissivity_ad(iv_idx)   = emissivity_ad(iv_idx) - ivar%Rv_Mod*reflectivity_ad(iv_idx)
    rv_mod_ad               = (one-ivar%e(iv_idx))*reflectivity_ad(iv_idx)
    reflectivity_ad(iv_idx) = zero

    ! ...emissivities
    e_azimuth_ad(v_idx)  = emissivity_ad(v_idx); emissivity_ad(v_idx) = zero
    e_azimuth_ad(u_idx)  = emissivity_ad(u_idx); emissivity_ad(u_idx) = zero
    e_azimuth_ad(ih_idx) = emissivity_ad(ih_idx) ! No zero of Emissivity_AD(Ih_IDX)
    e_azimuth_ad(iv_idx) = emissivity_ad(iv_idx) ! No zero of Emissivity_AD(Ih_IDX)


    ! Anisotropic downward radiation correction calculation
    IF ( PRESENT(transmittance_ad) .AND. ivar%Transmittance_Valid ) THEN
      CALL reflection_correction_ad( &
             mwwatercoeff%RCCoeff, &
             rv_mod_ad       , &
             rh_mod_ad       , &
             wind_speed_ad   , &
             transmittance_ad, &
             ivar%rcVar        )
    ELSE
      rv_mod_ad = zero
      rh_mod_ad = zero
    END IF


    ! Azimuthal component calculation
    IF ( PRESENT(azimuth_angle_ad) .AND. ivar%Azimuth_Angle_Valid ) THEN
      IF ( mwwatercoeff%Version == fastem6 ) THEN
        CALL azimuth_emissivity_f6_ad( &
               mwwatercoeff%AZCoeff, &
               e_azimuth_ad    , &
               wind_speed_ad   , &
               azimuth_angle_ad, &
               ivar%aeF6Var      )
      ELSE
        CALL azimuth_emissivity_ad( &
               mwwatercoeff%AZCoeff, &
               e_azimuth_ad    , &
               wind_speed_ad   , &
               azimuth_angle_ad, &
               ivar%aeVar        )
      END IF
    ELSE
      e_azimuth_ad = zero
    END IF

    ! Compute the adjoint of the first two Stokes components of the emissivity
    rh_foam_ad    = -ivar%Foam_Cover      *emissivity_ad(ih_idx)
    foam_cover_ad = (ivar%Rh-ivar%Rh_Foam)*emissivity_ad(ih_idx)
    rh_ad         = (ivar%Foam_Cover-one) *emissivity_ad(ih_idx)
    emissivity_ad(ih_idx) = zero
    rh_large_ad   = -rh_ad
    f_small_ad    = ivar%Rh_Fresnel*rh_ad
    rh_fresnel_ad =  rh_ad*ivar%F_Small
    rh_ad = zero

    rv_foam_ad    = -ivar%Foam_Cover      *emissivity_ad(iv_idx)
    foam_cover_ad = (ivar%Rv-ivar%Rv_Foam)*emissivity_ad(iv_idx) + foam_cover_ad
    rv_ad         = (ivar%Foam_Cover-one) *emissivity_ad(iv_idx)
    emissivity_ad(iv_idx) = zero
    rv_large_ad   = -rv_ad
    f_small_ad    = f_small_ad + ivar%Rv_Fresnel*rv_ad
    rv_fresnel_ad =  rv_ad*ivar%F_Small
    rv_ad = zero


    ! Small scale Correction Calculation AD
    CALL small_scale_correction_ad( &
           mwwatercoeff%SSCCoeff, &
           f_small_ad   , &
           wind_speed_ad, &
           ivar%sscVar    )


    ! Large Scale Correction Calculation
    CALL large_scale_correction_ad( &
           rv_large_ad  , &
           rh_large_ad  , &
           wind_speed_ad, &
           ivar%lscVar    )


    ! Foam coverage calculation
    CALL foam_coverage_ad( &
           mwwatercoeff%FCCoeff, &
           ivar%Wind_Speed, &
           foam_cover_ad, &
           wind_speed_ad )


    ! Foam reflectivity "calculation"
    rv_foam_ad = zero
    rh_foam_ad = zero


    ! Fresnel reflectivity calculation
    permittivity_ad = zero
    CALL fresnel_reflectivity_ad( rv_fresnel_ad, rh_fresnel_ad, ivar%cos_z, &
                                  permittivity_ad, &
                                  ivar%fVar )

    ! Permittivity calculation
    CALL ocean_permittivity_ad( permittivity_ad, ivar%Frequency, &
                                temperature_ad, salinity_ad, &
                                ivar%pVar )

  END SUBROUTINE compute_fastemx_ad


!################################################################################
!################################################################################
!##                                                                            ##
!##                        ## PRIVATE MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################



END MODULE crtm_fastemx