Fresnel.f90

Go to the documentation of this file.

!
! Fresnel
!
! Module containing routines to compute Fresnel reflectivities.
!
!
! CREATION HISTORY:
!       Written by:     Masahiro Kazumori, JCSDA
!                       Masahiro.Kazumori@noaa.gov
!       Modified by:    Paul van Delst, CIMSS/SSEC 11-Apr-2007
!                       paul.vandelst@noaa.gov

MODULE fresnel

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds, ONLY: fp
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  PRIVATE
  PUBLIC :: ivar_type
  PUBLIC :: fresnel_reflectivity
  PUBLIC :: fresnel_reflectivity_tl
  PUBLIC :: fresnel_reflectivity_ad
  
  ! -----------------
  ! Module parameters
  ! -----------------
  ! RCS Id for the module
  CHARACTER(*), PARAMETER :: module_rcs_id = &
  '$Id: Fresnel.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  REAL(fp), PARAMETER :: zero   = 0.0_fp
  REAL(fp), PARAMETER :: point5 = 0.5_fp
  REAL(fp), PARAMETER :: one    = 1.0_fp
  REAL(fp), PARAMETER :: two    = 2.0_fp


  ! --------------------------------------
  ! Structure definition to hold forward
  ! variables across FWD, TL, and AD calls
  ! --------------------------------------
  TYPE :: ivar_type
    PRIVATE
    ! The intermediate terms
    COMPLEX(fp) :: z1, z2
    ! The real and imaginary components
    REAL(fp)    :: rzrv,izrv  ! Vertical
    REAL(fp)    :: rzrh,izrh  ! Horizontal
  END TYPE ivar_type


CONTAINS


!--------------------------------------------------------------------------------
!
! NAME:
!       Fresnel_Reflectivity
!
! PURPOSE:
!       Subroutine to compute Fresnel reflectivities
!
! CALLING SEQUENCE:
!       CALL Fresnel_Reflectivity( permittivity, &  ! Input
!                                  cos_i       , &  ! Input
!                                  Rv          , &  ! Output
!                                  Rh          , &  ! Output
!                                  iVar          )  ! Internal variable output
!
! INPUT ARGUMENTS:
!       permittivity:  Permittivity of medium
!                      UNITS:      Farads per metre (F.m^-1)
!                      TYPE:       COMPLEX(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
!       cos_i:         Cosine of incidence angle
!                      UNITS:      N/A
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
! OUTPUT ARGUMENTS:
!       Rv:            Reflectivity for polarisation parallel to the 
!                      plane of incidence (i.e. vertical polarization)
!                      UNITS:      N/A
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
!       Rh:            Reflectivity for polarisation perpendicular to the
!                      plane of incidence (i.e. horizontal polarization)
!                      UNITS:      N/A
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
!       iVar:          Structure containing internal variables required for
!                      subsequent tangent-linear or adjoint model calls.
!                      The contents of this structure are NOT accessible
!                      outside of the Fresnel module.
!                      UNITS:      N/A
!                      TYPE:       TYPE(iVar_type)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
! CREATION HISTORY:
!       Written by:     Masahiro Kazumori, JCSDA
!                       Masahiro.Kazumori@noaa.gov
!       Modified by:    Paul van Delst, CIMSS/SSEC 11-Apr-2007
!                       paul.vandelst@noaa.gov
!
!--------------------------------------------------------------------------------

  SUBROUTINE fresnel_reflectivity( permittivity, &  ! Input
                                   cos_i       , &  ! Input
                                   Rv          , &  ! Output
                                   Rh          , &  ! Output
                                   iVar          )  ! Internal variable output
    ! Arguments
    COMPLEX(fp),     INTENT(IN)     :: permittivity
    REAL(fp),        INTENT(IN)     :: cos_i
    REAL(fp),        INTENT(OUT)    :: rv
    REAL(fp),        INTENT(OUT)    :: rh
    TYPE(ivar_type), INTENT(IN OUT) :: ivar
    ! Local variables
    COMPLEX(fp) :: zrv ! Vertical
    COMPLEX(fp) :: zrh ! Horizontal

    ! Compute the complex reflectivity components
    ivar%z1 = sqrt(permittivity - one + (cos_i*cos_i))
    ivar%z2 = permittivity * cos_i
    zrh = (cos_i  -ivar%z1) / (cos_i  +ivar%z1)
    zrv = (ivar%z2-ivar%z1) / (ivar%z2+ivar%z1)

    ! The square of the vertical abs value
    ivar%rzRv = REAL(zrv,fp)
    ivar%izRv = aimag(zrv)
    rv = ivar%rzRv**2 + ivar%izRv**2

    ! The square of the horizontal abs value
    ivar%rzRh = REAL(zrh,fp)
    ivar%izRh = aimag(zrh)
    rh = ivar%rzRh**2 + ivar%izRh**2

  END SUBROUTINE fresnel_reflectivity


!--------------------------------------------------------------------------------
!
! NAME:
!       Fresnel_Reflectivity_TL
!
! PURPOSE:
!       Subroutine to compute tangent-linear Fresnel reflectivities
!
! CALLING SEQUENCE:
!       CALL Fresnel_Reflectivity_TL( permittivity_TL, &  ! Input
!                                     cos_i          , &  ! Input
!                                     Rv_TL          , &  ! Output
!                                     Rh_TL          , &  ! Output
!                                     iVar             )  ! Internal variable input
!
! INPUT ARGUMENTS:
!       permittivity_TL:  Tangent-linear permittivity of medium
!                         UNITS:      Farads per metre (F.m^-1)
!                         TYPE:       COMPLEX(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       cos_i             Cosine of incidence angle
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       iVar:             Structure containing internal variables required for
!                         subsequent tangent-linear or adjoint model calls.
!                         The contents of this structure are NOT accessible
!                         outside of the Fresnel module.
!                         UNITS:      N/A
!                         TYPE:       TYPE(iVar_type)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
! OUTPUT ARGUMENTS:
!       Rv_TL             Tangent-linear reflectivity for polarisation parallel
!                         to the plane of incidence (i.e. vertical polarization)
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(OUT)
!
!       Rh_TL             Tangent-linear reflectivity for polarisation
!                         perpendicular to the plane of incidence
!                         (i.e. horizontal polarization)
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(OUT)
!
! CREATION HISTORY:
!       Written by:     Masahiro Kazumori, JCSDA
!                       Masahiro.Kazumori@noaa.gov
!       Modified by:    Paul van Delst, CIMSS/SSEC 11-Apr-2007
!                       paul.vandelst@noaa.gov
!
!--------------------------------------------------------------------------------

  SUBROUTINE fresnel_reflectivity_tl( permittivity_TL, &  ! Input
                                      cos_i          , &  ! Input
                                      Rv_TL          , &  ! Output
                                      Rh_TL          , &  ! Output
                                      iVar             )  ! Internal variable input
    ! Arguments
    COMPLEX(fp),     INTENT(IN)  :: permittivity_tl
    REAL(fp),        INTENT(IN)  :: cos_i
    REAL(fp),        INTENT(OUT) :: rv_tl
    REAL(fp),        INTENT(OUT) :: rh_tl
    TYPE(ivar_type), INTENT(IN)  :: ivar
    ! Local variables
    COMPLEX(fp) :: z1_tl, z2_tl
    COMPLEX(fp) :: zrv_tl           ! Vertical
    COMPLEX(fp) :: zrh_tl           ! Horizontal
    REAL(fp)    :: rzrv_tl,izrv_tl  ! Vertical
    REAL(fp)    :: rzrh_tl,izrh_tl  ! Horizontal

    ! Compute the tangent-linear complex reflectivity components
    z1_tl = point5 * permittivity_tl / ivar%z1
    z2_tl = cos_i * permittivity_tl
    zrh_tl = -two * cos_i * z1_tl / (cos_i+ivar%z1)**2
    zrv_tl =  two * (ivar%z1*z2_tl - ivar%z2*z1_tl) / (ivar%z2+ivar%z1)**2

    ! The square of the tangent-linear vertical abs value
    rzrv_tl = REAL(zrv_tl,fp)
    izrv_tl = aimag(zrv_tl)
    rv_tl = two * (ivar%rzRv*rzrv_tl + ivar%izRv*izrv_tl)

    ! The square of the tangent-linear horizontal abs value
    rzrh_tl = REAL(zrh_tl,fp)
    izrh_tl = aimag(zrh_tl)
    rh_tl = two * (ivar%rzRh*rzrh_tl + ivar%izRh*izrh_tl)

  END SUBROUTINE fresnel_reflectivity_tl


!--------------------------------------------------------------------------------
!
! NAME:
!       Fresnel_Reflectivity_AD
!
! PURPOSE:
!       Subroutine to compute Fresnel reflectivity adjoints
!
! CALLING SEQUENCE:
!       CALL Fresnel_Reflectivity_AD( Rv_AD          , &  ! Input
!                                     Rh_AD          , &  ! Input
!                                     cos_i          , &  ! Input
!                                     permittivity_AD, &  ! Output
!                                     iVar             )  ! Internal variable input
!
! INPUT ARGUMENTS:
!       Rv_AD             Adjoint reflectivity for polarisation parallel
!                         to the plane of incidence (i.e. vertical polarization)
!                         ** Set to ZERO on exit **
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
!       Rh_AD             Adjoint reflectivity for polarisation
!                         perpendicular to the plane of incidence
!                         (i.e. horizontal polarization)
!                         ** Set to ZERO on exit **
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
!       cos_i             Cosine of incidence angle
!                         UNITS:      N/A
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       iVar:             Structure containing internal variables required for
!                         subsequent tangent-linear or adjoint model calls.
!                         The contents of this structure are NOT accessible
!                         outside of the Fresnel module.
!                         UNITS:      N/A
!                         TYPE:       TYPE(iVar_type)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
! OUTPUT ARGUMENTS:
!       permittivity_AD:  Adjoint permittivity of medium, dR/de,
!                         where R == reflectivity
!                               e == permittivity
!                         UNITS:      inverse Farads per metre (F.m^-1)^-1
!                         TYPE:       COMPLEX(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
! CREATION HISTORY:
!       Written by:     Masahiro Kazumori, JCSDA
!                       Masahiro.Kazumori@noaa.gov
!       Modified by:    Paul van Delst, CIMSS/SSEC 11-Apr-2007
!                       paul.vandelst@noaa.gov
!
!--------------------------------------------------------------------------------

  SUBROUTINE fresnel_reflectivity_ad( Rv_AD          , &  ! Input
                                      Rh_AD          , &  ! Input
                                      cos_i          , &  ! Input
                                      permittivity_AD, &  ! Output
                                      iVar             )  ! Internal variable input
    ! Arguments
    REAL(fp),        INTENT(IN OUT) :: rv_ad
    REAL(fp),        INTENT(IN OUT) :: rh_ad
    REAL(fp),        INTENT(IN)     :: cos_i
    COMPLEX(fp),     INTENT(IN OUT) :: permittivity_ad
    TYPE(ivar_type), INTENT(IN)     :: ivar
    ! Local variables
    COMPLEX(fp) :: z1_ad, z2_ad
    COMPLEX(fp) :: zrv_ad           ! Vertical
    COMPLEX(fp) :: zrh_ad           ! Horizontal
    REAL(fp)    :: rzrv_ad,izrv_ad  ! Vertical
    REAL(fp)    :: rzrh_ad,izrh_ad  ! Horizontal
    COMPLEX(fp) :: denom

    ! The adjoint of the horizontal reflectivity
    izrh_ad = two*ivar%izRh*rh_ad
    rzrh_ad = two*ivar%rzRh*rh_ad
    rh_ad  = zero
    zrh_ad = cmplx(rzrh_ad, -izrh_ad, fp)  ! complex conjugate

    ! The adjoint of the vertical reflectivity
    izrv_ad = two*ivar%izRv*rv_ad 
    rzrv_ad = two*ivar%rzRv*rv_ad
    rv_ad  = zero
    zrv_ad = cmplx(rzrv_ad, -izrv_ad, fp)  ! complex conjugate

    ! The adjoint of the complex vertical polarised component
    denom = (ivar%z2+ivar%z1)**2
    z1_ad = -two*ivar%z2*zrv_ad / denom
    z2_ad =  two*ivar%z1*zrv_ad / denom
    
    ! The adjoint of the complex horizontal polarised component
    z1_ad = z1_ad - ( two*cos_i*zrh_ad / (cos_i+ivar%z1)**2 )
    
    ! The adjoint of the preserved variables
    permittivity_ad = permittivity_ad + conjg(cos_i*z2_ad)
    permittivity_ad = permittivity_ad + conjg(point5*z1_ad/ivar%z1)

  END SUBROUTINE fresnel_reflectivity_ad
  
END MODULE fresnel