doxygen-example/_c_r_t_m___antenna_correction_8f90_source.html

 !
 ! CRTM_AntennaCorrection
 !
 ! Module containgin routines to apply the antenna correction to the
 ! RTSolution brightness temperatures.
 !
 !
 ! CREATION HISTORY:
 !       Written by:     Paul van Delst, 20-Jul-2007
 !                       paul.vandelst@noaa.gov
 !

 MODULE crtm_antennacorrection

   ! ------------------
   ! Environment set up
   ! ------------------
   ! Module use statements
   USE type_kinds              , ONLY: fp
   USE crtm_parameters         , ONLY: tspace
   USE crtm_geometryinfo_define, ONLY: crtm_geometryinfo_type, &
                                       crtm_geometryinfo_getvalue
   USE crtm_rtsolution_define  , ONLY: crtm_rtsolution_type
   USE crtm_spccoeff           , ONLY: sc
   ! Disable all implicit typing
   IMPLICIT NONE


   ! --------------------
   ! Default visibilities
   ! --------------------
   ! Everything private by default
   PRIVATE
   ! Module procedures
   PUBLIC :: crtm_compute_antcorr
   PUBLIC :: crtm_compute_antcorr_tl
   PUBLIC :: crtm_compute_antcorr_ad


   ! -----------------
   ! Module parameters
   ! -----------------
   CHARACTER(*),  PARAMETER :: module_version_id = &
   '$Id: CRTM_AntennaCorrection.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'


 CONTAINS


 !##################################################################################
 !##################################################################################
 !##                                                                              ##
 !##                           ## PUBLIC MODULE ROUTINES ##                       ##
 !##                                                                              ##
 !##################################################################################
 !##################################################################################

 !------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       CRTM_Compute_AntCorr
 !
 ! PURPOSE:
 !       Subroutine to compute the antenna correction and apply it the RTSolution
 !       brightness temperatures
 !
 ! CALLING SEQUENCE:
 !       CALL CRTM_Compute_AntCorr( GeometryInfo, &
 !                                  SensorIndex , &
 !                                  ChannelIndex, &
 !                                  RTSolution    )
 !
 ! INPUTS:
 !       GeometryInfo:    Structure containing the view geometry information.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_GeometryInfo_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       SensorIndex:     Sensor index id. This is a unique index associated
 !                        with a (supported) sensor used to access the
 !                        shared coefficient data for a particular sensor.
 !                        See the ChannelIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       ChannelIndex:    Channel index id. This is a unique index associated
 !                        with a (supported) sensor channel used to access the
 !                        shared coefficient data for a particular sensor's
 !                        channel.
 !                        See the SensorIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUTS:
 !       RTSolution:      Structure containing the radiative transfer solution.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_RTSolution_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !:sdoc-:
 !------------------------------------------------------------------------------

   SUBROUTINE crtm_compute_antcorr( gI, &  ! Input
                                    n , &  ! Input
                                    l , &  ! Input
                                    RT  )  ! In/Output
     ! Arguments
     TYPE(crtm_geometryinfo_type), INTENT(IN)     :: gi
     INTEGER                     , INTENT(IN)     :: n  ! SensorIndex
     INTEGER                     , INTENT(IN)     :: l  ! ChannelIndex
     TYPE(crtm_rtsolution_type)  , INTENT(IN OUT) :: rt
     ! Local variables
     INTEGER :: ifov

     ! Get the FOV index value
     CALL crtm_geometryinfo_getvalue( gi, ifov = ifov )

     ! Compute the antenna temperature
     ! Note the earth temperature is used as a proxy
     ! for the platform temperature.
     rt%Brightness_Temperature = sc(n)%AC%A_earth(   ifov,l)*rt%Brightness_Temperature + &
                                 sc(n)%AC%A_platform(ifov,l)*rt%Brightness_Temperature + &
                                 sc(n)%AC%A_space(   ifov,l)*tspace

   END SUBROUTINE crtm_compute_antcorr


 !------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       CRTM_Compute_AntCorr_TL
 !
 ! PURPOSE:
 !       Subroutine to compute the tangent-linear antenna correction and
 !       apply it to the tangent-linear RTSolution brightness temperatures.
 !
 ! CALLING SEQUENCE:
 !       CALL CRTM_Compute_AntCorr_TL( GeometryInfo, &
 !                                     SensorIndex , &
 !                                     ChannelIndex, &
 !                                     RTSolution_TL )
 !
 ! INPUTS:
 !       GeometryInfo:    Structure containing the view geometry information.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_GeometryInfo_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       SensorIndex:     Sensor index id. This is a unique index associated
 !                        with a (supported) sensor used to access the
 !                        shared coefficient data for a particular sensor.
 !                        See the ChannelIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       ChannelIndex:    Channel index id. This is a unique index associated
 !                        with a (supported) sensor channel used to access the
 !                        shared coefficient data for a particular sensor's
 !                        channel.
 !                        See the SensorIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUTS:
 !       RTSolution_TL:   Structure containing the tangent-linear radiative
 !                        transfer solution.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_RTSolution_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !:sdoc-:
 !------------------------------------------------------------------------------

   SUBROUTINE crtm_compute_antcorr_tl( gI   , &  ! Input
                                       n    , &  ! Input
                                       l    , &  ! Input
                                       RT_TL  )  ! In/Output
     ! Arguments
     TYPE(crtm_geometryinfo_type), INTENT(IN)     :: gi
     INTEGER                     , INTENT(IN)     :: n  ! SensorIndex
     INTEGER                     , INTENT(IN)     :: l  ! ChannelIndex
     TYPE(crtm_rtsolution_type)  , INTENT(IN OUT) :: rt_tl
     ! Local variables
     INTEGER :: ifov
     REAL(fp) :: c

     ! Get the FOV index value
     CALL crtm_geometryinfo_getvalue( gi, ifov = ifov )

     ! Compute the tangent linear antenna temperature
     ! Note the A_platform term has to be included even
     ! though the earth temperature is used as a proxy
     ! for the platform temperature.
     c = sc(n)%AC%A_earth(ifov,l) + sc(n)%AC%A_platform(ifov,l)
     rt_tl%Brightness_Temperature = c * rt_tl%Brightness_Temperature

   END SUBROUTINE crtm_compute_antcorr_tl


 !------------------------------------------------------------------------------
 !:sdoc+:
 !
 ! NAME:
 !       CRTM_Compute_AntCorr_AD
 !
 ! PURPOSE:
 !       Subroutine to compute the adjoint antenna correction and
 !       apply it to the adjoint RTSolution brightness temperatures.
 !
 ! CALLING SEQUENCE:
 !       CALL CRTM_Compute_AntCorr_AD( GeometryInfo, &
 !                                     SensorIndex , &
 !                                     ChannelIndex, &
 !                                     RTSolution_AD )
 !
 ! INPUTS:
 !       GeometryInfo:    Structure containing the view geometry information.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_GeometryInfo_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       SensorIndex:     Sensor index id. This is a unique index associated
 !                        with a (supported) sensor used to access the
 !                        shared coefficient data for a particular sensor.
 !                        See the ChannelIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 !       ChannelIndex:    Channel index id. This is a unique index associated
 !                        with a (supported) sensor channel used to access the
 !                        shared coefficient data for a particular sensor's
 !                        channel.
 !                        See the SensorIndex argument.
 !                        UNITS:      N/A
 !                        TYPE:       INTEGER
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN)
 !
 ! OUTPUTS:
 !       RTSolution_AD:   Structure containing the adjoint radiative
 !                        transfer solution.
 !                        UNITS:      N/A
 !                        TYPE:       CRTM_RTSolution_type
 !                        DIMENSION:  Scalar
 !                        ATTRIBUTES: INTENT(IN OUT)
 !:sdoc-:
 !------------------------------------------------------------------------------

   SUBROUTINE crtm_compute_antcorr_ad( gI   , &  ! Input
                                       n    , &  ! Input
                                       l    , &  ! Input
                                       RT_AD  )  ! In/Output
     ! Arguments
     TYPE(crtm_geometryinfo_type), INTENT(IN)     :: gi
     INTEGER                     , INTENT(IN)     :: n  ! SensorIndex
     INTEGER                     , INTENT(IN)     :: l  ! ChannelIndex
     TYPE(crtm_rtsolution_type)  , INTENT(IN OUT) :: rt_ad
     ! Local variables
     INTEGER :: ifov
     REAL(fp) :: c

     ! Get the FOV index value
     CALL crtm_geometryinfo_getvalue( gi, ifov = ifov )

     ! Compute the adjoint of the antenna temperature
     c = sc(n)%AC%A_earth(ifov,l) + sc(n)%AC%A_platform(ifov,l)
     rt_ad%Brightness_Temperature = c * rt_ad%Brightness_Temperature

   END SUBROUTINE crtm_compute_antcorr_ad

 END MODULE crtm_antennacorrection
crtm_antennacorrection
Definition: CRTM_AntennaCorrection.f90:13

crtm_antennacorrection::crtm_compute_antcorr_tl
subroutine, public crtm_compute_antcorr_tl(gI, n, l, RT_TL)
Definition: CRTM_AntennaCorrection.f90:190

crtm_parameters::tspace
real(fp), parameter, public tspace
Definition: CRTM_Parameters.f90:170

type_kinds::fp
integer, parameter, public fp
Definition: Type_Kinds.f90:124

crtm_parameters
Definition: CRTM_Parameters.f90:12

crtm_spccoeff
Definition: CRTM_SpcCoeff.f90:24

crtm_geometryinfo_define::crtm_geometryinfo_type
Definition: CRTM_GeometryInfo_Define.f90:104

crtm_antennacorrection::crtm_compute_antcorr
subroutine, public crtm_compute_antcorr(gI, n, l, RT)
Definition: CRTM_AntennaCorrection.f90:113

crtm_spccoeff::sc
type(spccoeff_type), dimension(:), allocatable, save, public sc
Definition: CRTM_SpcCoeff.f90:114

crtm_rtsolution_define
Definition: CRTM_RTSolution_Define.f90:13

type_kinds
Definition: Type_Kinds.f90:12

crtm_rtsolution_define::crtm_rtsolution_type
Definition: CRTM_RTSolution_Define.f90:114

crtm_geometryinfo_define
Definition: CRTM_GeometryInfo_Define.f90:13

crtm_antennacorrection::module_version_id
character(*), parameter module_version_id
Definition: CRTM_AntennaCorrection.f90:43

crtm_antennacorrection::crtm_compute_antcorr_ad
subroutine, public crtm_compute_antcorr_ad(gI, n, l, RT_AD)
Definition: CRTM_AntennaCorrection.f90:268

crtm_geometryinfo_define::crtm_geometryinfo_getvalue
elemental subroutine, public crtm_geometryinfo_getvalue(gInfo, Geometry, iFOV, Longitude, Latitude, Surface_Altitude, Sensor_Scan_Angle, Sensor_Zenith_Angle, Sensor_Azimuth_Angle, Source_Zenith_Angle, Source_Azimuth_Angle, Flux_Zenith_Angle, Year, Month, Day, Distance_Ratio, Sensor_Scan_Radian, Sensor_Zenith_Radian, Sensor_Azimuth_Radian, Secant_Sensor_Zenith, Cosine_Sensor_Zenith, Source_Zenith_Radian, Source_Azimuth_Radian, Secant_Source_Zenith, Flux_Zenith_Radian, Secant_Flux_Zenith, Trans_Zenith_Radian, Secant_Trans_Zenith, AU_ratio2)
Definition: CRTM_GeometryInfo_Define.f90:421