ASvar_Define.f90

Go to the documentation of this file.

! 
! ASvar_Define
!
! Module defining the CRTM AerosolScatter module internal
! variable object.
! 
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 14-Feb-2012
!                       paul.vandelst@noaa.gov
!                       

MODULE asvar_define

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds           , ONLY: fp
  USE message_handler      , ONLY: success, failure, information, display_message
  USE compare_float_numbers, ONLY: OPERATOR(.equalto.)
  USE file_utility         , ONLY: file_open, file_exists
  USE binary_file_utility  , ONLY: open_binary_file      , &
                                   writegatts_binary_file, &
                                   readgatts_binary_file
  USE crtm_interpolation   , ONLY: npts      , &
                                   lpoly_type
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! Datatypes
  PUBLIC :: asvar_type
  PUBLIC :: asinterp_type
  ! Operators
  PUBLIC :: OPERATOR(==)
  ! Procedures
  PUBLIC :: asvar_associated
  PUBLIC :: asvar_destroy
  PUBLIC :: asvar_create
  PUBLIC :: asvar_inspect
  PUBLIC :: asvar_validrelease
  PUBLIC :: asvar_info
  PUBLIC :: asvar_defineversion
  PUBLIC :: asvar_inquirefile
  PUBLIC :: asvar_readfile
  PUBLIC :: asvar_writefile


  ! ---------------------
  ! Procedure overloading
  ! ---------------------
  INTERFACE OPERATOR(==)
    MODULE PROCEDURE asvar_equal
  END INTERFACE OPERATOR(==)


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
    '$Id: ASvar_Define.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Release and version
  INTEGER, PARAMETER :: asvar_release = 1  ! This determines structure and file formats.
  INTEGER, PARAMETER :: asvar_version = 1  ! This is just the default data version.
  ! Close status for write errors
  CHARACTER(*), PARAMETER :: write_error_status = 'DELETE'
  ! Literal constants
  REAL(fp), PARAMETER :: zero = 0.0_fp
  REAL(fp), PARAMETER :: one  = 1.0_fp
  ! String lengths
  INTEGER,  PARAMETER :: ml = 256 ! Message length
  INTEGER,  PARAMETER :: sl =  80 ! String length

  
  ! ---------------------
  ! Structure definitions
  ! ---------------------
  ! The interpolation routine structure
  TYPE :: asinterp_type
    ! The interpolating polynomials
    TYPE(lpoly_type) :: wlp  ! Frequency
    TYPE(lpoly_type) :: xlp  ! Effective radius
    ! The LUT interpolation indices
    INTEGER :: i1, i2        ! Frequency
    INTEGER :: j1, j2        ! Effective radius
    ! The LUT interpolation boundary check
    LOGICAL :: f_outbound    ! Frequency
    LOGICAL :: r_outbound    ! Effective radius
    ! The interpolation input
    REAL(fp) :: f_int        ! Frequency
    REAL(fp) :: r_int        ! Effective radius
    ! The data to be interpolated
    REAL(fp) :: f(npts)      ! Frequency
    REAL(fp) :: r(npts)      ! Effective radius
  END TYPE asinterp_type
  
  
  ! The internal variable definition to hold information
  ! between FWD, TL, AD, and K-matrix calls
  TYPE :: asvar_type
    ! Allocation indicator
    LOGICAL :: is_allocated = .false.
    ! Release and version information
    INTEGER :: release = asvar_release
    INTEGER :: version = asvar_version
    ! Dimensions
    INTEGER :: n_legendre_terms = 0  ! I1
    INTEGER :: n_phase_elements = 0  ! I2
    INTEGER :: n_layers         = 0  ! I3
    INTEGER :: n_aerosols       = 0  ! I4
    ! The interpolating data
    TYPE(asinterp_type), ALLOCATABLE :: asi(:,:)  ! I3 x I4
    ! The interpolation results
    REAL(fp), ALLOCATABLE :: ke(:,:)          ! I3 x I4  Mass extinction coefficient
    REAL(fp), ALLOCATABLE :: w(:,:)           ! I3 x I4  Single Scatter Albedo
    REAL(fp), ALLOCATABLE :: g(:,:)           ! I3 x I4  Asymmetry factor
    REAL(fp), ALLOCATABLE :: pcoeff(:,:,:,:)  ! 0:I1 x I2 x I3 x I4  Phase coefficients
    ! The accumulated scattering coefficient
    REAL(fp), ALLOCATABLE :: total_bs(:)      ! I3  Volume scattering coefficient
  END TYPE asvar_type


CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                           ## PUBLIC PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

  ELEMENTAL FUNCTION asvar_associated( self ) RESULT( Status )
    TYPE(asvar_type), INTENT(IN) :: self
    LOGICAL :: status
    status = self%Is_Allocated
  END FUNCTION asvar_associated

 
  ELEMENTAL SUBROUTINE asvar_destroy( self )
    TYPE(asvar_type), INTENT(OUT) :: self
    self%Is_Allocated = .false.
    self%n_Legendre_Terms = 0
    self%n_Phase_Elements = 0
    self%n_Layers         = 0
    self%n_Aerosols       = 0
  END SUBROUTINE asvar_destroy
  
  
  ELEMENTAL SUBROUTINE asvar_create( &
    self            , &  ! Output
    n_Legendre_Terms, &  ! Input
    n_Phase_Elements, &  ! Input
    n_Layers        , &  ! Input
    n_Aerosols        )  ! Input
    ! Arguments
    TYPE(asvar_type), INTENT(OUT) :: self
    INTEGER              , INTENT(IN)  :: n_legendre_terms        
    INTEGER              , INTENT(IN)  :: n_phase_elements             
    INTEGER              , INTENT(IN)  :: n_layers                
    INTEGER              , INTENT(IN)  :: n_aerosols                   
    ! Local variables
    INTEGER :: alloc_stat

    ! Check input
    IF ( n_legendre_terms < 1 .OR. &
         n_phase_elements < 1 .OR. &
         n_layers         < 1 .OR. &
         n_aerosols       < 1 ) RETURN

    ! Perform the allocation
    ALLOCATE( self%asi(n_layers, n_aerosols), &
              self%ke(n_layers, n_aerosols), &
              self%w(n_layers, n_aerosols), &
              self%g(n_layers, n_aerosols), &
              self%pcoeff(0:n_legendre_terms,n_phase_elements,n_layers, n_aerosols), &
              self%total_bs(n_layers), &
              stat = alloc_stat )
    IF ( alloc_stat /= 0 ) RETURN


    ! Initialise dimensions only!
    self%n_Legendre_Terms = n_legendre_terms
    self%n_Phase_Elements = n_phase_elements
    self%n_Layers         = n_layers        
    self%n_Aerosols       = n_aerosols      

    ! Set allocation indicator
    self%Is_Allocated = .true.
  END SUBROUTINE asvar_create
  
  
  SUBROUTINE asvar_inspect( self)
    TYPE(asvar_type), INTENT(IN) :: self
    INTEGER :: i2, i3, i4
    WRITE(*,'(1x,"ASvar OBJECT")')

    ! Release/version info
    WRITE(*,'(3x,"Release.Version     :",1x,i0,".",i0)') self%Release, self%Version

    ! Dimensions
    WRITE(*,'(3x,"n_Legendre_Terms    :",1x,i0)') self%n_Legendre_Terms
    WRITE(*,'(3x,"n_Phase_Elements    :",1x,i0)') self%n_Phase_Elements
    WRITE(*,'(3x,"n_Layers            :",1x,i0)') self%n_Layers        
    WRITE(*,'(3x,"n_Aerosols          :",1x,i0)') self%n_Aerosols      
    IF ( .NOT. asvar_associated(self) ) RETURN

    ! Data
    WRITE(*,'(3x,"Mass extinction coefficient (ke) :")')
    DO i4 = 1, self%n_Aerosols
      WRITE(*,'(5x,"ke Aerosol index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%ke(:,i4)
    END DO
    WRITE(*,'(3x,"Single scatter albedo (w) :")')
    DO i4 = 1, self%n_Aerosols
      WRITE(*,'(5x,"w Aerosol index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%w(:,i4)
    END DO
    WRITE(*,'(3x,"Asymmetry factor (g) :")')
    DO i4 = 1, self%n_Aerosols
      WRITE(*,'(5x,"g Aerosol index #",i0)') i4
      WRITE(*,'(5(1x,es13.6,:))') self%g(:,i4)
    END DO
    WRITE(*,'(3x,"Phase coefficients (pcoeff) :")')
    DO i4 = 1, self%n_Aerosols
      WRITE(*,'(5x,"pcoeff Aerosol index #",i0)') i4
      DO i3 = 1, self%n_Layers
        WRITE(*,'(7x,"pcoeff Layer index #",i0)') i3
        DO i2 = 1, self%n_Phase_Elements
          WRITE(*,'(9x,"pcoeff Phase element index #",i0)') i2
          WRITE(*,'(5(1x,es13.6,:))') self%pcoeff(0:,i2,i3,i4)
        END DO
      END DO
    END DO
    WRITE(*,'(3x,"Volume scattering coefficient (total_bs) :")')
    WRITE(*,'(5(1x,es13.6,:))') self%total_bs
  END SUBROUTINE asvar_inspect


  FUNCTION asvar_validrelease( self ) RESULT( IsValid )
    ! Arguments
    TYPE(asvar_type), INTENT(IN) :: self
    ! Function result
    LOGICAL :: isvalid
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ASvar_ValidRelease'
    ! Local variables
    CHARACTER(ML) :: msg

    ! Set up
    isvalid = .true.

    ! Check release is not too old
    IF ( self%Release < asvar_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An ASvar data update is needed. ", &
                  &"ASvar release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, asvar_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF


    ! Check release is not too new
    IF ( self%Release > asvar_release ) THEN
      isvalid = .false.
      WRITE( msg,'("An ASvar software update is needed. ", &
                  &"ASvar release is ",i0,". Valid release is ",i0,"." )' ) &
                  self%Release, asvar_release
      CALL display_message( routine_name, msg, information ); RETURN
    END IF
  END FUNCTION asvar_validrelease


  SUBROUTINE asvar_info( self, Info )
    ! Arguments
    TYPE(asvar_type), INTENT(IN)  :: self
    CHARACTER(*),     INTENT(OUT) :: info
    ! Parameters
    INTEGER, PARAMETER :: carriage_return = 13
    INTEGER, PARAMETER :: linefeed = 10
    ! Local variables
    CHARACTER(2000) :: long_string

    ! Write the required data to the local string
    WRITE( long_string, &
           '(a,1x,"ASvar RELEASE.VERSION: ",i2,".",i2.2,a,3x, &
           &"N_LEGENDRE_TERMS=",i0,2x,&
           &"N_PHASE_ELEMENTS=",i0,2x,&
           &"N_LAYERS=",i0,2x,&
           &"N_AEROSOLS=",i0 )' ) &
           achar(carriage_return)//achar(linefeed), &
           self%Release, self%Version, &
           achar(carriage_return)//achar(linefeed), &
           self%n_Legendre_Terms, &
           self%n_Phase_Elements, &
           self%n_Layers        , &
           self%n_Aerosols      
                       
    ! Trim the output based on the
    ! dummy argument string length
    info = long_string(1:min(len(info), len_trim(long_string)))
  END SUBROUTINE asvar_info


  SUBROUTINE asvar_defineversion( Id )
    CHARACTER(*), INTENT(OUT) :: id
    id = module_version_id
  END SUBROUTINE asvar_defineversion


  FUNCTION asvar_inquirefile( &
    Filename        , &  ! Input
    n_Legendre_Terms, &  ! Optional output  
    n_Phase_Elements, &  ! Optional output  
    n_Layers        , &  ! Optional output  
    n_Aerosols      , &  ! Optional output  
    Release         , &  ! Optional output
    Version         , &  ! Optional output
    Title           , &  ! Optional output
    History         , &  ! Optional output
    Comment         ) &  ! Optional output
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN)  :: filename
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_legendre_terms
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_phase_elements
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_layers        
    INTEGER     , OPTIONAL, INTENT(OUT) :: n_aerosols      
    INTEGER     , OPTIONAL, INTENT(OUT) :: release        
    INTEGER     , OPTIONAL, INTENT(OUT) :: version        
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title           
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history         
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment         
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ASvar_InquireFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(asvar_type) :: asvar

 
    ! Setup
    err_stat = success
    ! ...Check that the file exists
    IF ( .NOT. file_exists( filename ) ) THEN
      msg = 'File '//trim(filename)//' not found.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Open the file
    err_stat = open_binary_file( filename, fid )
    IF ( err_stat /= success ) THEN
      msg = 'Error opening '//trim(filename)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%Release, &
      asvar%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF
    IF ( .NOT. asvar_validrelease( asvar ) ) THEN
      msg = 'ASvar Release check failed.'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%n_Legendre_Terms, &
      asvar%n_Phase_Elements, &
      asvar%n_Layers        , &
      asvar%n_Aerosols      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading dimension values from '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL inquire_cleanup(); RETURN
    END IF


    ! Close the file
    CLOSE( fid, iostat=io_stat, iomsg=io_msg )
    IF ( io_stat /= 0 ) THEN
      msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
      CALL inquire_cleanup(); RETURN
    END IF


    ! Assign the return arguments
    IF ( PRESENT(n_legendre_terms) ) n_legendre_terms = asvar%n_Legendre_Terms
    IF ( PRESENT(n_phase_elements) ) n_phase_elements = asvar%n_Phase_Elements    
    IF ( PRESENT(n_layers        ) ) n_layers         = asvar%n_Layers        
    IF ( PRESENT(n_aerosols      ) ) n_aerosols       = asvar%n_Aerosols          
    IF ( PRESENT(release         ) ) release          = asvar%Release        
    IF ( PRESENT(version         ) ) version          = asvar%Version        
    
  CONTAINS
  
    SUBROUTINE inquire_cleanup()
      ! Close file if necessary
      IF ( file_open(fid) ) THEN
        CLOSE( fid, iostat=io_stat, iomsg=io_msg )
        IF ( io_stat /= 0 ) &
          msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
      END IF
      ! Set error status and print error message
      err_stat = failure
      CALL display_message( routine_name, msg, err_stat )
    END SUBROUTINE inquire_cleanup
    
  END FUNCTION asvar_inquirefile


  FUNCTION asvar_readfile( &
    ASvar     , &  ! Output
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional output
    History   , &  ! Optional output
    Comment   , &  ! Optional output
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(asvar_type),       INTENT(OUT) :: asvar
    CHARACTER(*),           INTENT(IN)  :: filename
    LOGICAL,      OPTIONAL, INTENT(IN)  :: no_close
    LOGICAL,      OPTIONAL, INTENT(IN)  :: quiet
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: title
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: history
    CHARACTER(*), OPTIONAL, INTENT(OUT) :: comment
    LOGICAL,      OPTIONAL, INTENT(IN)  :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ASvar_ReadFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    TYPE(asvar_type) :: dummy
    
    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL read_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file if it exists
      IF ( file_exists( filename ) ) THEN
        err_stat = open_binary_file( filename, fid )
        IF ( err_stat /= success ) THEN
          msg = 'Error opening '//trim(filename)
          CALL read_cleanup(); RETURN
        END IF
      ELSE
        msg = 'File '//trim(filename)//' not found.'
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Read and check the release and version
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%Release, &
      dummy%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading Release/Version - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    IF ( .NOT. asvar_validrelease( dummy ) ) THEN
      msg = 'ASvar Release check failed.'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the dimensions
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      dummy%n_Legendre_Terms, &
      dummy%n_Phase_Elements, &
      dummy%n_Layers        , &
      dummy%n_Aerosols      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading data dimensions - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Allocate the object
    CALL asvar_create( &
           asvar                 , &
           dummy%n_Legendre_Terms, &        
           dummy%n_Phase_Elements, &        
           dummy%n_Layers        , &        
           dummy%n_Aerosols        )                  
    IF ( .NOT. asvar_associated( asvar ) ) THEN
      msg = 'ASvar object allocation failed.'
      CALL read_cleanup(); RETURN
    END IF
    ! ...Explicitly assign the version number
    asvar%Version = dummy%Version
        

    ! Read the global attributes
    err_stat = readgatts_binary_file( &
                 fid, &
                 title   = title  , &
                 history = history, &
                 comment = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading global attributes'
      CALL read_cleanup(); RETURN
    END IF


    ! Read the data
    ! ...Mass extinction coefficient
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%ke
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading mass extinction coefficient - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Single scatter albedo
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%w
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading single scatter albedo - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Asymmetry factor
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%g
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading asymmetry factor - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Phase coefficients
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%pcoeff
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading phase coefficients - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF
    ! ...Total volume scattering coefficient
    READ( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%total_bs
    IF ( io_stat /= 0 ) THEN
      msg = 'Error reading total volume scattering coefficient - '//trim(io_msg)
      CALL read_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL read_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL asvar_info( asvar, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE read_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid, iostat=io_stat, iomsg=io_msg )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing input file during error cleanup - '//trim(io_msg)
       END IF
       CALL asvar_destroy( asvar )
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE read_cleanup

  END FUNCTION asvar_readfile


  FUNCTION asvar_writefile( &
    ASvar     , &  ! Input
    Filename  , &  ! Input
    No_Close  , &  ! Optional input
    Quiet     , &  ! Optional input
    Title     , &  ! Optional input
    History   , &  ! Optional input
    Comment   , &  ! Optional input
    Debug     ) &  ! Optional input (Debug output control)
  result( err_stat )
    ! Arguments
    TYPE(asvar_type),  INTENT(IN) :: asvar
    CHARACTER(*),           INTENT(IN) :: filename
    LOGICAL,      OPTIONAL, INTENT(IN) :: no_close
    LOGICAL,      OPTIONAL, INTENT(IN) :: quiet
    CHARACTER(*), OPTIONAL, INTENT(IN) :: title
    CHARACTER(*), OPTIONAL, INTENT(IN) :: history
    CHARACTER(*), OPTIONAL, INTENT(IN) :: comment
    LOGICAL,      OPTIONAL, INTENT(IN) :: debug
    ! Function result
    INTEGER :: err_stat
    ! Function parameters
    CHARACTER(*), PARAMETER :: routine_name = 'ASvar_WriteFile'
    ! Function variables
    CHARACTER(ML) :: msg
    CHARACTER(ML) :: io_msg
    LOGICAL :: close_file
    LOGICAL :: noisy
    INTEGER :: io_stat
    INTEGER :: fid
    

    ! Setup
    err_stat = success
    ! ...Check No_Close argument
    close_file = .true.
    IF ( PRESENT(no_close) ) close_file = .NOT. no_close
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Override Quiet settings if debug set.
    IF ( PRESENT(debug) ) THEN
      IF ( debug ) noisy = .true.
    END IF
    ! ...Check there is data to write
    IF ( .NOT. asvar_associated( asvar ) ) THEN
      msg = 'ASvar object is empty.'
      CALL write_cleanup(); RETURN
    END IF

   
    ! Check if the file is open.
    IF ( file_open( filename ) ) THEN
      ! ...Inquire for the logical unit number
      INQUIRE( file=filename, number=fid )
      ! ...Ensure it's valid
      IF ( fid < 0 ) THEN
        msg = 'Error inquiring '//trim(filename)//' for its FileID'
        CALL write_cleanup(); RETURN
      END IF
    ELSE
      ! ...Open the file for output
      err_stat = open_binary_file( filename, fid, for_output=.true. )
      IF ( err_stat /= success ) THEN
        msg = 'Error opening '//trim(filename)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Write the release and version
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%Release, &
      asvar%Version
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing Release/Version - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the dimensions
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%n_Legendre_Terms, &
      asvar%n_Phase_Elements, &
      asvar%n_Layers        , &
      asvar%n_Aerosols      
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing data dimensions - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Write the global attributes
    err_stat = writegatts_binary_file( &
                 fid, &
                 write_module = module_version_id, &
                 title        = title  , &
                 history      = history, &
                 comment      = comment  )
    IF ( err_stat /= success ) THEN
      msg = 'Error writing global attributes'
      CALL write_cleanup(); RETURN
    END IF


    ! Write the data
    ! ...Mass extinction coefficient
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%ke
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing mass extinction coefficient - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Single scatter albedo
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%w
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing single scatter albedo - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Asymmetry factor
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%g
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing asymmetry factor - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Phase coefficients
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%pcoeff
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing phase coefficients - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF
    ! ...Total volume scattering coefficient
    WRITE( fid, iostat=io_stat, iomsg=io_msg ) &
      asvar%total_bs
    IF ( io_stat /= 0 ) THEN
      msg = 'Error writing total volume scattering coefficient - '//trim(io_msg)
      CALL write_cleanup(); RETURN
    END IF


    ! Close the file
    IF ( close_file ) THEN
      CLOSE( fid, iostat=io_stat, iomsg=io_msg )
      IF ( io_stat /= 0 ) THEN
        msg = 'Error closing '//trim(filename)//' - '//trim(io_msg)
        CALL write_cleanup(); RETURN
      END IF
    END IF


    ! Output an info message
     IF ( noisy ) THEN
       CALL asvar_info( asvar, msg )
       CALL display_message( routine_name, 'FILE: '//trim(filename)//'; '//trim(msg), information )
     END IF

   CONTAINS
   
     SUBROUTINE write_cleanup()
       IF ( file_open(filename) ) THEN
         CLOSE( fid, iostat=io_stat, iomsg=io_msg )
         IF ( io_stat /= 0 ) &
           msg = trim(msg)//'; Error closing output file during error cleanup - '//trim(io_msg)
       END IF
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE write_cleanup

  END FUNCTION asvar_writefile

  
!################################################################################
!################################################################################
!##                                                                            ##
!##                          ## PRIVATE PROCEDURES ##                          ##
!##                                                                            ##
!################################################################################
!################################################################################

  ELEMENTAL FUNCTION asvar_equal( x, y ) RESULT( is_equal )
    TYPE(asvar_type), INTENT(IN) :: x, y
    LOGICAL :: is_equal

    ! Set up
    is_equal = .false.
   
    ! Check the object association status
    IF ( (.NOT. asvar_associated(x)) .OR. &
         (.NOT. asvar_associated(y))      ) RETURN

   ! Check contents
    ! ...Release/version info
    IF ( (x%Release /= y%Release) .OR. &
         (x%Version /= y%Version) ) RETURN
    ! ...Dimensions
    IF ( (x%n_Legendre_Terms /= y%n_Legendre_Terms ) .OR. &
         (x%n_Phase_Elements /= y%n_Phase_Elements ) .OR. &
         (x%n_Layers         /= y%n_Layers         ) .OR. &
         (x%n_Aerosols       /= y%n_Aerosols       ) ) RETURN
    ! ...Arrays
    IF ( all(x%ke       .equalto. y%ke       ) .AND. &
         all(x%w        .equalto. y%w        ) .AND. &
         all(x%g        .equalto. y%g        ) .AND. &
         all(x%pcoeff   .equalto. y%pcoeff   ) .AND. &
         all(x%total_bs .equalto. y%total_bs ) ) &
      is_equal = .true.
  END FUNCTION asvar_equal

END MODULE asvar_define