temperature_variables_mod.f90

Go to the documentation of this file.

! (C) Copyright 2018 UCAR
! 
! This software is licensed under the terms of the Apache Licence Version 2.0
! which can be obtained at http://www.apache.org/licenses/LICENSE-2.0. 

!> Variable transforms on temperature variables for fv3-jedi 
!> Daniel Holdaway, NASA/JCSDA

module temperature_vt_mod

use fv3jedi_constants_mod, only: kappa, epsilon
use fv3jedi_geom_mod, only: fv3jedi_geom
use fv3jedi_kinds_mod, only: kind_real

implicit none
private

public t_to_tv, t_to_tv_tl, t_to_tv_ad
public tv_to_t, tv_to_t_tl, tv_to_t_ad

contains

!----------------------------------------------------------------------------
! Temperature to Virtual Temperature ----------------------------------------
!----------------------------------------------------------------------------

subroutine t_to_tv(geom,T,q,Tv)

 implicit none
 type(fv3jedi_geom)  , intent(in ) :: geom !Geometry for the model
 real(kind=kind_real), intent(in ) :: t (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Temperature (K)
 real(kind=kind_real), intent(in ) :: q (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Specific humidity (kg/kg)
 real(kind=kind_real), intent(out) :: tv(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Virtual temperature (K)

 tv = t*(1.0_kind_real + epsilon*q)

end subroutine t_to_tv

!----------------------------------------------------------------------------

subroutine t_to_tv_tl(geom,T,T_tl,q,q_tl,Tv_tl)

 implicit none
 type(fv3jedi_geom)  , intent(in ) :: geom
 real(kind=kind_real), intent(in ) :: t   (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in ) :: t_tl(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in ) :: q   (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in ) :: q_tl(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(out) :: tv_tl(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)

 tv_tl = t_tl*(1.0_kind_real + epsilon*q) + t*epsilon*q_tl

end subroutine t_to_tv_tl

!----------------------------------------------------------------------------

subroutine t_to_tv_ad(geom,T,T_ad,q,q_ad,Tv_ad)

 implicit none
 type(fv3jedi_geom)  , intent(in   ) :: geom 
 real(kind=kind_real), intent(in   ) :: t    (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: t_ad (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in   ) :: q    (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: q_ad (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: tv_ad(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)

 t_ad = t_ad + tv_ad * (1.0_kind_real + epsilon*q)
 q_ad = q_ad + tv_ad *                  epsilon*t
 tv_ad = 0.0_kind_real

end subroutine t_to_tv_ad

!----------------------------------------------------------------------------
! Virtual Temperature to Temperature ----------------------------------------
!----------------------------------------------------------------------------

subroutine tv_to_t(geom,Tv,q,T)

 implicit none
 type(fv3jedi_geom)  , intent(in ) :: geom !Geometry for the model
 real(kind=kind_real), intent(in ) :: tv(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Temperature (K)
 real(kind=kind_real), intent(in ) :: q (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Specific humidity (kg/kg)
 real(kind=kind_real), intent(out) :: t (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)  !Virtual temperature (K)

 t = tv/(1.0_kind_real + epsilon*q)

end subroutine tv_to_t

!----------------------------------------------------------------------------

subroutine tv_to_t_tl(geom,Tv,Tv_tl,q,q_tl,T_tl)

 implicit none
 type(fv3jedi_geom)  , intent(in   ) :: geom
 real(kind=kind_real), intent(in   ) :: tv   (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in   ) :: tv_tl(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in   ) :: q    (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in   ) :: q_tl (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: t_tl (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)

 t_tl = (tv_tl*(1.0_kind_real+epsilon*q)-tv*epsilon*q_tl)/(1.0_kind_real+epsilon*q)**2

end subroutine tv_to_t_tl

!----------------------------------------------------------------------------

subroutine tv_to_t_ad(geom,Tv,Tv_ad,q,q_ad,T_ad)

 implicit none
 type(fv3jedi_geom)  , intent(in   ) :: geom
 real(kind=kind_real), intent(in   ) :: tv   (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: tv_ad(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(in   ) :: q    (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: q_ad (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 real(kind=kind_real), intent(inout) :: t_ad (geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)
 
 real(kind=kind_real) :: temp(geom%isc:geom%iec,geom%jsc:geom%jec,1:geom%npz)

 temp = t_ad/(epsilon*q+1.0_kind_real)

 tv_ad = tv_ad + temp
 q_ad  = q_ad  - tv*epsilon*temp/(epsilon*q+1.0_kind_real)
 t_ad = 0.0_kind_real

end subroutine tv_to_t_ad

!----------------------------------------------------------------------------

end module temperature_vt_mod