Guillou.f90

Go to the documentation of this file.

!
! Guillou Ocean Permittivity module.
!
! Module containing routines to compute the complex permittivities for
! sea water based on
!
!   Guillou, C. et al. (1998) Impact of new permittivity measurements
!      on sea surface emissivity modeling in microwaves.
!      Radio Science, Volume 33, Number 3, Pages 649-667
!
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 11-Apr-2007
!                       paul.vandelst@noaa.gov
!

MODULE guillou

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE type_kinds, ONLY: fp
  USE fundamental_constants, ONLY: pi, &
                                   e0 => permittivity, &  ! Permittivity of vacuum (F/m)
                                   k_to_c => standard_temperature ! Temperature units conversion
  ! Disable implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  PRIVATE
  ! ...Datatypes
  PUBLIC :: ivar_type
  ! ...Procedures
  PUBLIC :: guillou_ocean_permittivity
  PUBLIC :: guillou_ocean_permittivity_tl
  PUBLIC :: guillou_ocean_permittivity_ad

  
  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: Guillou.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  REAL(fp), PARAMETER :: zero   = 0.0_fp
  REAL(fp), PARAMETER :: point5 = 0.5_fp
  REAL(fp), PARAMETER :: one    = 1.0_fp
  REAL(fp), PARAMETER :: two    = 2.0_fp
  REAL(fp), PARAMETER :: three  = 3.0_fp
  REAL(fp), PARAMETER :: four   = 4.0_fp
  REAL(fp), PARAMETER :: five   = 5.0_fp
  REAL(fp), PARAMETER :: twopi  = two*pi


  ! Scaling factors (used here for documenting the conversion
  ! to SI units of the double Debye model denominator)
  ! ---------------------------------------------------------
  REAL(fp), PARAMETER :: ps_to_s   = 1.0e-12_fp ! Picoseconds -> Seconds
  REAL(fp), PARAMETER :: ghz_to_hz = 1.0e+09_fp ! Gigahertz   -> Hertz
  REAL(fp), PARAMETER :: scale_factor = ps_to_s * ghz_to_hz


  ! Parameters for the Guillou et al (1998) permittivity model
  ! ----------------------------------------------------------
  ! The coefficients for the sea water conductivity temperature
  ! polynomials. Eqn.(1) in reference. Note that these values
  ! have more precision than is reported in the ref.
  REAL(fp), PARAMETER :: d1_coeff(0:2) = (/  0.086374_fp, &
                                             0.030606_fp, &
                                           -0.0004121_fp /)
  REAL(fp), PARAMETER :: d2_coeff(0:2) = (/ 0.077454_fp, &
                                            0.001687_fp, &
                                          0.00001937_fp /)
  
  ! The coefficients for the static permittivity temperature
  ! polynomials. Eqn.(3) in reference. Note that these values
  ! have more precision than is reported in the ref.
  REAL(fp), PARAMETER :: a1_coeff(0:5) = (/      81.820_fp, &
                                            -6.0503e-02_fp, &
                                            -3.1661e-02_fp, &
                                             3.1097e-03_fp, &
                                            -1.1791e-04_fp, &
                                             1.4838e-06_fp /)
  REAL(fp), PARAMETER :: a2_coeff(0:5) = (/     0.12544_fp, &
                                             9.4037e-03_fp, &
                                            -9.5551e-04_fp, &
                                             9.0888e-05_fp, &
                                            -3.6011e-06_fp, &
                                             4.7130e-08_fp /)
  
  ! The coefficients for the high-frequency permittivity temperature
  ! polynomial. Eqn.(4) in reference. Note that these values
  ! have more precision than is reported in the ref.
  REAL(fp), PARAMETER :: b1_coeff(0:5) = (/  6.4587_fp    , &
                                            -0.04203_fp   , &
                                            -0.0065881_fp , &
                                             0.00064924_fp, &
                                            -1.2328e-05_fp, &
                                             5.0433e-08_fp /)
                                            
  ! The coefficients for the relaxation time temperature
  ! polynomial. Eqn.(5) in reference. Note that these values
  ! have more precision than is reported in the ref.
  REAL(fp), PARAMETER :: c1_coeff(0:5) = (/ 17.303_fp    , &
                                           -0.66651_fp   , &
                                            5.1482e-03_fp, &
                                            1.2145e-03_fp, &
                                           -5.0325e-05_fp, &
                                            5.8272e-07_fp /)
  REAL(fp), PARAMETER :: c2_coeff(0:5) = (/-6.272e-03_fp , &
                                            2.357e-04_fp , &
                                            5.075e-04_fp , &
                                           -6.3983e-05_fp, &
                                            2.463e-06_fp , &
                                           -3.0676e-08_fp /)


  ! --------------------------------------
  ! Structure definition to hold forward
  ! variables across FWD, TL, and AD calls
  ! --------------------------------------
  TYPE :: ivar_type
    PRIVATE
    REAL(fp) :: t=zero, s=zero                       ! Temperature in degC; salinity
    REAL(fp) :: f=zero, f2=zero, f0=zero, f2po=zero  ! Frequency terms
    REAL(fp) :: a1=zero, a2=zero, es=zero            ! Static permittivity temperature polynomials
    REAL(fp) :: einf=zero                            ! High-frequency permittivity temperature polynomial
    REAL(fp) :: c1=zero, c2=zero                     ! Relaxation time temperature polynomial
    REAL(fp) :: d1=zero, d2=zero                     ! Conductivity temperature polynomials 
  END TYPE ivar_type
  

CONTAINS


!################################################################################
!################################################################################
!##                                                                            ##
!##                         ## PUBLIC MODULE ROUTINES ##                       ##
!##                                                                            ##
!################################################################################
!################################################################################

!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Guillou_Ocean_Permittivity
!
! PURPOSE:
!       Subroutine to compute ocean permittivity according to the reference,
!         Guillou, C. et al. (1998) Impact of new permittivity measurements
!            on sea surface emissivity modeling in microwaves.
!            Radio Science, Volume 33, Number 3, Pages 649-667
!
! CALLING SEQUENCE:
!       CALL Guillou_Ocean_Permittivity( Temperature , & ! Input
!                                        Salinity    , & ! Input
!                                        Frequency   , & ! Input
!                                        Permittivity, & ! Output
!                                        iVar          ) ! Internal variable output
!
! INPUTS:
!       Temperature:   Sea surface temperature
!                      UNITS:      Kelvin (K)
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
!       Salinity:      Water salinity
!                      UNITS:      ppt (parts per thousand)
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
!       Frequency:     Frequency
!                      UNITS:      GHz
!                      TYPE:       REAL(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(IN)
!
! OUTPUTS:
!       Permittivity:  Ocean permittivity
!                      UNITS:      N/A
!                      TYPE:       COMPLEX(fp)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!
!       iVar:          Structure containing internal variables required for
!                      subsequent tangent-linear or adjoint model calls.
!                      The contents of this structure are NOT accessible
!                      outside of this module.
!                      UNITS:      N/A
!                      TYPE:       TYPE(iVar_type)
!                      DIMENSION:  Scalar
!                      ATTRIBUTES: INTENT(OUT)
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE guillou_ocean_permittivity( &
    Temperature , & ! Input
    Salinity    , & ! Input
    Frequency   , & ! Input
    Permittivity, & ! Output
    iVar          ) ! Internal variable output
    ! Arguments
    REAL(fp),        INTENT(IN)     :: temperature
    REAL(fp),        INTENT(IN)     :: salinity
    REAL(fp),        INTENT(IN)     :: frequency
    COMPLEX(fp),     INTENT(OUT)    :: permittivity
    TYPE(ivar_type), INTENT(IN OUT) :: ivar
    ! Local variables
    REAL(fp) :: sigma
    REAL(fp) :: tau
    REAL(fp) :: re, ie


    ! Save the inputs
    ! ---------------
    ivar%t = temperature - k_to_c
    ivar%s = salinity
  
  
    ! Conductivity
    ! ------------
    ! Compute the conductivity temperature polynomials
    ! Eqn.(1) in reference
    ivar%d1 = d1_coeff(0) + ivar%t*(d1_coeff(1) + ivar%t*d1_coeff(2))
    ivar%d2 = d2_coeff(0) + ivar%t*(d2_coeff(1) + ivar%t*d2_coeff(2))

    ! Compute the salinity dependent conductivity
    sigma = ivar%d1 + ivar%s*ivar%d2


    ! Static permittivity
    ! -------------------
    ! Compute the static permittivity temperature polynomials.
    ! Eqn.(3) in reference.
    ivar%a1 = a1_coeff(0) + ivar%t*(a1_coeff(1) + &
                              ivar%t*(a1_coeff(2) + &
                                ivar%t*(a1_coeff(3) + &
                                  ivar%t*(a1_coeff(4) + &
                                    ivar%t*a1_coeff(5) ))))
    ivar%a2 = a2_coeff(0) + ivar%t*(a2_coeff(1) + &
                              ivar%t*(a2_coeff(2) + &
                                ivar%t*(a2_coeff(3) + &
                                  ivar%t*(a2_coeff(4) + &
                                    ivar%t*a2_coeff(5) ))))
  
    ! Compute the salinity dependent static permittivity
    ivar%es = ivar%a1 - ivar%s*ivar%a2


    ! High frequency permittivity
    ! ---------------------------
    ! Compute the high-frequency permittivity temperature polynomial
    ! Eqn.(4) in reference
    ivar%einf = b1_coeff(0) + ivar%t*(b1_coeff(1) + &
                                ivar%t*(b1_coeff(2) + &
                                  ivar%t*(b1_coeff(3) + &
                                    ivar%t*(b1_coeff(4) + &
                                      ivar%t*b1_coeff(5) ))))
  

    ! Relaxation time
    ! ---------------
    ! Compute the Debye relaxation time temperature polynomials
    ! Eqn.(5) in reference
    ivar%c1 = c1_coeff(0) + ivar%t*(c1_coeff(1) + &
                              ivar%t*(c1_coeff(2) + &
                                ivar%t*(c1_coeff(3) + &
                                  ivar%t*(c1_coeff(4) + &
                                    ivar%t*c1_coeff(5) ))))
    ivar%c2 = c2_coeff(0) + ivar%t*(c2_coeff(1) + &
                              ivar%t*(c2_coeff(2) + &
                                ivar%t*(c2_coeff(3) + &
                                  ivar%t*(c2_coeff(4) + &
                                    ivar%t*c2_coeff(5) ))))
    
    ! Compute the salinity dependent relaxation time in picoseconds
    tau = ivar%c1 + ivar%s*ivar%c2


    ! Compute the complex permittivity
    ! --------------------------------
    ! The various frequency terms
    ivar%f  = twopi * frequency * tau * scale_factor
    ivar%f2 = ivar%f**2
    ivar%f0 = twopi * frequency * ghz_to_hz * e0
    
    ivar%f2po = one+ivar%f2
    
    ! The real part
    re = (ivar%es + ivar%einf*ivar%f2)/ivar%f2po

    ! The imaginary part
    ie = ivar%f*(ivar%es - ivar%einf)/ivar%f2po + sigma/ivar%f0
    
    ! Combine them
    permittivity = cmplx(re,-ie,fp)
    
  END SUBROUTINE guillou_ocean_permittivity


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Guillou_Ocean_Permittivity_TL
!
! PURPOSE:
!       Subroutine to compute the tangent-linear ocean permittivity according
!       to the reference,
!         Guillou, C. et al. (1998) Impact of new permittivity measurements
!            on sea surface emissivity modeling in microwaves.
!            Radio Science, Volume 33, Number 3, Pages 649-667
!
! CALLING SEQUENCE:
!       CALL Guillou_Ocean_Permittivity_TL( Temperature_TL , & ! Input
!                                           Salinity_TL    , & ! Input
!                                           Frequency      , & ! Input
!                                           Permittivity_TL, & ! Output
!                                           iVar             ) ! Internal variable input
!
! INPUTS:
!       Temperature_TL:   Tangent-linear sea surface temperature
!                         UNITS:      Kelvin (K)
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       Salinity_TL:      Tangent-linear water salinity
!                         UNITS:      ppt (parts per thousand)
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       Frequency:        Frequency
!                         UNITS:      GHz
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       iVar:             Structure containing internal variables required for
!                         subsequent tangent-linear or adjoint model calls.
!                         The contents of this structure are NOT accessible
!                         outside of this module.
!                         UNITS:      N/A
!                         TYPE:       TYPE(iVar_type)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(OUT)
!
! OUTPUTS:
!       Permittivity_TL:  Tangent-linear ocean permittivity
!                         UNITS:      N/A
!                         TYPE:       COMPLEX(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(OUT)
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE guillou_ocean_permittivity_tl( &
    Temperature_TL , & ! Input
    Salinity_TL    , & ! Input
    Frequency      , & ! Input
    Permittivity_TL, & ! Output
    iVar             ) ! Internal variable input
    ! Arguments
    REAL(fp),        INTENT(IN)  :: temperature_tl
    REAL(fp),        INTENT(IN)  :: salinity_tl
    REAL(fp),        INTENT(IN)  :: frequency
    COMPLEX(fp),     INTENT(OUT) :: permittivity_tl
    TYPE(ivar_type), INTENT(IN)  :: ivar
    ! Local variables
    REAL(fp) :: d1_tl, d2_tl, sigma_tl
    REAL(fp) :: a1_tl, a2_tl, es_tl
    REAL(fp) :: einf_tl
    REAL(fp) :: c1_tl, c2_tl, tau_tl
    REAL(fp) :: f_tl, f2_tl, f2po_tl
    REAL(fp) :: inv_f2po
    REAL(fp) :: re_tl, ie_tl


    ! Conductivity
    ! ------------
    ! Compute the tangent-linear conductivity
    ! temperature polynomials. Eqn.(1) in reference
    d1_tl = (d1_coeff(1) + ivar%t*two*d1_coeff(2)) * temperature_tl
    d2_tl = (d2_coeff(1) + ivar%t*two*d2_coeff(2)) * temperature_tl

    ! Compute the tangent-linear salinity
    ! dependent conductivity
    sigma_tl = d1_tl + ivar%s*d2_tl + salinity_tl*ivar%d2


    ! Static permittivity
    ! -------------------
    ! Compute the tangent-linear static permittivity
    ! temperature polynomials. Eqn.(3) in reference.
    a1_tl = (a1_coeff(1) + ivar%t*(two*a1_coeff(2)      + &
                             ivar%t*(three*a1_coeff(3)  + &
                               ivar%t*(four*a1_coeff(4) + &
                                 ivar%t*five*a1_coeff(5)))) ) * temperature_tl
    a2_tl = (a2_coeff(1) + ivar%t*(two*a2_coeff(2)      + &
                             ivar%t*(three*a2_coeff(3)  + &
                               ivar%t*(four*a2_coeff(4) + &
                                 ivar%t*five*a2_coeff(5)))) ) * temperature_tl
  
    ! Compute the tangent-linear salinity
    ! dependent static permittivity
    es_tl = a1_tl - ivar%s*a2_tl - salinity_tl*ivar%a2


    ! High frequency permittivity
    ! ---------------------------
    ! Compute the tangent-linear high-frequency permittivity
    ! temperature polynomial. Eqn.(4) in reference
    einf_tl = (b1_coeff(1) + ivar%t*(two*b1_coeff(2)      + &
                               ivar%t*(three*b1_coeff(3)  + &
                                 ivar%t*(four*b1_coeff(4) + &
                                   ivar%t*five*b1_coeff(5)))) ) * temperature_tl


    ! Relaxation time
    ! ---------------
    ! Compute the tangent-linear Debye relaxation time
    ! temperature polynomials. Eqn.(5) in reference
    c1_tl = (c1_coeff(1) + ivar%t*(two*c1_coeff(2)      + &
                             ivar%t*(three*c1_coeff(3)  + &
                               ivar%t*(four*c1_coeff(4) + &
                                 ivar%t*five*c1_coeff(5)))) ) * temperature_tl
    c2_tl = (c2_coeff(1) + ivar%t*(two*c2_coeff(2)      + &
                             ivar%t*(three*c2_coeff(3)  + &
                               ivar%t*(four*c2_coeff(4) + &
                                 ivar%t*five*c2_coeff(5)))) ) * temperature_tl
    
    ! Compute the tangent-linear salinity
    ! dependent relaxation time in picoseconds
    tau_tl = c1_tl + ivar%s*c2_tl + salinity_tl*ivar%c2


    ! Compute the complex permittivity
    ! --------------------------------
    ! The tangent-linear of various frequency terms
    f_tl  = twopi * frequency * tau_tl * scale_factor
    f2_tl = two * ivar%f * f_tl
    
    f2po_tl  = f2_tl
    inv_f2po = one/ivar%f2po
    
    ! The real part
    re_tl = inv_f2po*(ivar%f2*einf_tl + &
                      es_tl - &
                      inv_f2po*(ivar%es-ivar%einf)*f2po_tl)

    ! The imaginary part
    ie_tl = inv_f2po*(ivar%f*es_tl - &
                      ivar%f*einf_tl +&
                      inv_f2po*(ivar%es-ivar%einf)*(one-ivar%f2)*f_tl) + &
            sigma_tl/ivar%f0
    
    ! Combine them
    permittivity_tl = cmplx(re_tl, -ie_tl, fp)

  END SUBROUTINE guillou_ocean_permittivity_tl


!--------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       Guillou_Ocean_Permittivity_AD
!
! PURPOSE:
!       Subroutine to compute the adjoint of the ocean permittivity according
!       to the reference,
!         Guillou, C. et al. (1998) Impact of new permittivity measurements
!            on sea surface emissivity modeling in microwaves.
!            Radio Science, Volume 33, Number 3, Pages 649-667
!
! CALLING SEQUENCE:
!       CALL Guillou_Ocean_Permittivity_AD( Permittivity_AD, & ! Input
!                                           Frequency      , & ! Input
!                                           Temperature_AD , & ! Output
!                                           Salinity_AD    , & ! Output
!                                           iVar             ) ! Internal variable input
!
! INPUTS:
!       Permittivity_AD:  Adjoint ocean permittivity
!                         UNITS:      N/A
!                         TYPE:       COMPLEX(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
!       Frequency:        Frequency
!                         UNITS:      GHz
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN)
!
!       iVar:             Structure containing internal variables required for
!                         subsequent tangent-linear or adjoint model calls.
!                         The contents of this structure are NOT accessible
!                         outside of this module.
!                         UNITS:      N/A
!                         TYPE:       TYPE(iVar_type)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(OUT)
!
! OUTPUTS:
!       Temperature_AD:   Adjoint sea surface temperature, de/dT.
!                         UNITS:      per Kelvin (K^-1)
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
!       Salinity_AD:      Adjoint water salinity, de/dS
!                         UNITS:      per ppt (parts-per-thousand^-1)
!                         TYPE:       REAL(fp)
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN OUT)
!
! SIDE EFFECTS:
!       The input adjoint variable, Permittivity_AD, is set to zero upon
!       exiting this routine.
!
!:sdoc-:
!--------------------------------------------------------------------------------

  SUBROUTINE guillou_ocean_permittivity_ad( &
    Permittivity_AD, & ! Input
    Frequency      , & ! Input
    Temperature_AD , & ! Output
    Salinity_AD    , & ! Output
    iVar             ) ! Internal variable input
    ! Arguments
    COMPLEX(fp),     INTENT(IN OUT) :: permittivity_ad
    REAL(fp),        INTENT(IN)     :: frequency
    REAL(fp),        INTENT(IN OUT) :: temperature_ad
    REAL(fp),        INTENT(IN OUT) :: salinity_ad
    TYPE(ivar_type), INTENT(IN)     :: ivar
    ! Local variables
    REAL(fp) :: ie_ad, re_ad
    REAL(fp) :: f2po2
    REAL(fp) :: a1_ad, a2_ad, es_ad
    REAL(fp) :: einf_ad
    REAL(fp) :: c1_ad, c2_ad, tau_ad
    REAL(fp) :: d1_ad, d2_ad, sigma_ad
    REAL(fp) :: f2_ad, f_ad
        

    ! Complex permittivity
    ! --------------------
    ! Separate the real and imaginary parts
    ie_ad = -aimag(permittivity_ad)
    re_ad = REAL(permittivity_ad, fp)
    permittivity_ad = zero
    
    ! Adjoint of the imaginary part
    f2po2 = ivar%f2po**2
    sigma_ad =  ie_ad/ivar%f0
    f2_ad    = -ie_ad*ivar%f*(ivar%es-ivar%einf)/f2po2
    einf_ad  = -ie_ad*ivar%f/ivar%f2po
    es_ad    =  ie_ad*ivar%f/ivar%f2po
    f_ad     =  ie_ad*(ivar%es-ivar%einf)/ivar%f2po 
    ie_ad = zero

    ! Adjoint of the real part
    f2_ad   = f2_ad   - re_ad*(ivar%es-ivar%einf)/f2po2
    einf_ad = einf_ad + re_ad*ivar%f2/ivar%f2po
    es_ad   = es_ad   + re_ad/ivar%f2po
    re_ad = zero

    ! Adjoint of the frequency terms
    f_ad  = f_ad + two*ivar%f*f2_ad
    f2_ad = zero
    tau_ad = twopi * frequency * scale_factor * f_ad
    f_ad   = zero


    ! Relaxation time
    ! ---------------
    ! Compute the adjoint of the salinity
    ! dependent relaxation time in picoseconds
    salinity_ad = salinity_ad + ivar%c2*tau_ad
    c2_ad       = ivar%s * tau_ad
    c1_ad       = tau_ad
    tau_ad      = zero

    ! Compute the adjoint of the Debye relaxation time
    ! temperature polynomials. Eqn.(5) in reference
    temperature_ad = temperature_ad + (c2_coeff(1) + ivar%t*(two*c2_coeff(2)      + &
                                                       ivar%t*(three*c2_coeff(3)  + &
                                                         ivar%t*(four*c2_coeff(4) + &
                                                           ivar%t*five*c2_coeff(5)))) ) * c2_ad
    temperature_ad = temperature_ad + (c1_coeff(1) + ivar%t*(two*c1_coeff(2)      + &
                                                       ivar%t*(three*c1_coeff(3)  + &
                                                         ivar%t*(four*c1_coeff(4) + &
                                                           ivar%t*five*c1_coeff(5)))) ) * c1_ad
    
    
    ! High frequency permittivity
    ! ---------------------------
    ! Compute the adjoint of the high-frequency permittivity
    ! temperature polynomial. Eqn.(4) in reference
    temperature_ad = temperature_ad + (b1_coeff(1) + ivar%t*(two*b1_coeff(2)      + &
                                                       ivar%t*(three*b1_coeff(3)  + &
                                                         ivar%t*(four*b1_coeff(4) + &
                                                           ivar%t*five*b1_coeff(5)))) ) * einf_ad


    ! Static permittivity
    ! -------------------
    ! Compute the adjoint of the salinity
    ! dependent static permittivity
    salinity_ad = salinity_ad - ivar%a2*es_ad
    a2_ad = -ivar%s * es_ad
    a1_ad = es_ad
    es_ad = zero

    ! Compute the adjoint of the static permittivity
    ! temperature polynomials. Eqn.(3) in reference.
    temperature_ad = temperature_ad + (a2_coeff(1) + ivar%t*(two*a2_coeff(2)      + &
                                                       ivar%t*(three*a2_coeff(3)  + &
                                                         ivar%t*(four*a2_coeff(4) + &
                                                           ivar%t*five*a2_coeff(5)))) ) * a2_ad
    temperature_ad = temperature_ad + (a1_coeff(1) + ivar%t*(two*a1_coeff(2)      + &
                                                       ivar%t*(three*a1_coeff(3)  + &
                                                         ivar%t*(four*a1_coeff(4) + &
                                                           ivar%t*five*a1_coeff(5)))) ) * a1_ad

    ! Conductivity
    ! ------------
    ! Compute the adjoint of the salinity
    ! dependent conductivity
    salinity_ad = salinity_ad + ivar%d2*sigma_ad
    d2_ad = ivar%s * sigma_ad
    d1_ad = sigma_ad
    sigma_ad = zero    

    ! Compute the adjoint of the conductivity
    ! temperature polynomials. Eqn.(1) in reference
    temperature_ad = temperature_ad + (d2_coeff(1) + ivar%t*two*d2_coeff(2)) * d2_ad
    temperature_ad = temperature_ad + (d1_coeff(1) + ivar%t*two*d1_coeff(2)) * d1_ad

  END SUBROUTINE guillou_ocean_permittivity_ad

END MODULE guillou