CRTM_IRwaterCoeff.f90

Go to the documentation of this file.

!
! CRTM_IRwaterCoeff
!
! Module containing the shared CRTM infrared water surface emissivity
! data and their load/destruction routines.
!
! PUBLIC DATA:
!   IRwaterC:  Data structure containing the infrared water surface
!              emissivity data.
!
! SIDE EFFECTS:
!       Routines in this module modify the contents of the public
!       data structure IRwaterC.
!
! RESTRICTIONS:
!       Routines in this module should only be called during the
!       CRTM initialisation.
!
! CREATION HISTORY:
!       Written by:     Paul van Delst, 04-May-2012
!                       paul.vandelst@noaa.gov
!

MODULE crtm_irwatercoeff

  ! -----------------
  ! Environment setup
  ! -----------------
  ! Module use
  USE message_handler    , ONLY: success, failure, display_message
  USE irwatercoeff_define, ONLY: irwatercoeff_type, &
                                 irwatercoeff_associated, &
                                 irwatercoeff_destroy, &
                                 irwatercoeff_readfile
  ! Disable all implicit typing
  IMPLICIT NONE


  ! ------------
  ! Visibilities
  ! ------------
  ! Everything private by default
  PRIVATE
  ! The shared data
  PUBLIC :: irwaterc
  ! Procedures
  PUBLIC :: crtm_irwatercoeff_load
  PUBLIC :: crtm_irwatercoeff_destroy
  PUBLIC :: crtm_irwatercoeff_isloaded


  ! -----------------
  ! Module parameters
  ! -----------------
  CHARACTER(*), PARAMETER :: module_version_id = &
  '$Id: CRTM_IRwaterCoeff.f90 60152 2015-08-13 19:19:13Z paul.vandelst@noaa.gov $'
  ! Message string length
  INTEGER, PARAMETER :: ml = 512


  ! ------------------------------------------------
  ! The shared infrared water surface emissivity data
  ! ------------------------------------------------
  TYPE(irwatercoeff_type), SAVE :: irwaterc


CONTAINS


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_IRwaterCoeff_Load
!
! PURPOSE:
!       Function to load the infrared water surface emissivity data into
!       the public data structure IRwaterC
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_IRwaterCoeff_Load( &
!                        Filename,                              &
!                        File_Path         = File_Path        , &
!                        Quiet             = Quiet            , &
!                        Process_ID        = Process_ID       , &
!                        Output_Process_ID = Output_Process_ID  )
!
! INPUT ARGUMENTS:
!       Filename:           Name of the IRwaterCoeff file.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN)
!
!
! OPTIONAL INPUT ARGUMENTS:
!       File_Path:          Character string specifying a file path for the
!                           input data file. If not specified, the current
!                           directory is the default.
!                           UNITS:      N/A
!                           TYPE:       CHARACTER(*)
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Quiet:              Set this logical argument to suppress INFORMATION
!                           messages being printed to stdout
!                           If == .FALSE., INFORMATION messages are OUTPUT [DEFAULT].
!                              == .TRUE.,  INFORMATION messages are SUPPRESSED.
!                           If not specified, default is .FALSE.
!                           UNITS:      N/A
!                           TYPE:       LOGICAL
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Process_ID:         Set this argument to the MPI process ID that this
!                           function call is running under. This value is used
!                           solely for controlling INFORMATIOn message output.
!                           If MPI is not being used, ignore this argument.
!                           This argument is ignored if the Quiet argument is set.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
!       Output_Process_ID:  Set this argument to the MPI process ID in which
!                           all INFORMATION messages are to be output. If
!                           the passed Process_ID value agrees with this value
!                           the INFORMATION messages are output.
!                           This argument is ignored if the Quiet argument
!                           is set.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!                           ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:       The return value is an integer defining the error
!                           status. The error codes are defined in the
!                           Message_Handler module.
!                           If == SUCCESS the data load was successful
!                              == FAILURE an unrecoverable error occurred.
!                           UNITS:      N/A
!                           TYPE:       INTEGER
!                           DIMENSION:  Scalar
!
! SIDE EFFECTS:
!       This function modifies the contents of the public data
!       structure IRwaterC.
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_irwatercoeff_load( &
    Filename         , &  ! Input
    File_Path        , &  ! Optional input
    Quiet            , &  ! Optional input
    Process_ID       , &  ! Optional input
    Output_Process_ID) &  ! Optional input
  result( err_stat )
    ! Arguments
    CHARACTER(*),           INTENT(IN) :: filename
    CHARACTER(*), OPTIONAL, INTENT(IN) :: file_path
    LOGICAL     , OPTIONAL, INTENT(IN) :: quiet
    INTEGER     , OPTIONAL, INTENT(IN) :: process_id
    INTEGER     , OPTIONAL, INTENT(IN) :: output_process_id
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_IRwaterCoeff_Load'
    ! Local variables
    CHARACTER(ML) :: msg, pid_msg
    CHARACTER(ML) :: irwatercoeff_file
    LOGICAL :: noisy

    ! Setup
    err_stat = success
    ! ...Assign the filename to local variable
    irwatercoeff_file = adjustl(filename)
    ! ...Add the file path
    IF ( PRESENT(file_path) ) irwatercoeff_file = trim(adjustl(file_path))//trim(irwatercoeff_file)
    ! ...Check Quiet argument
    noisy = .true.
    IF ( PRESENT(quiet) ) noisy = .NOT. quiet
    ! ...Check the MPI Process Ids
    IF ( noisy .AND. PRESENT(process_id) .AND. PRESENT(output_process_id) ) THEN
      IF ( process_id /= output_process_id ) noisy = .false.
    END IF
    ! ...Create a process ID message tag for error messages
    IF ( PRESENT(process_id) ) THEN
      WRITE( pid_msg,'("; Process ID: ",i0)' ) process_id
    ELSE
      pid_msg = ''
    END IF


    ! Read the IR water IRwaterCoeff file
    err_stat = irwatercoeff_readfile( &
                 irwaterc, &
                 irwatercoeff_file, &
                 quiet = .NOT. noisy )
    IF ( err_stat /= success ) THEN
      msg = 'Error reading IRwaterCoeff IRwaterCoeff file '//trim(irwatercoeff_file)//trim(pid_msg)
      CALL load_cleanup(); RETURN
    END IF

   CONTAINS

     SUBROUTINE load_cleanup()
       CALL irwatercoeff_destroy( irwaterc )
       err_stat = failure
       CALL display_message( routine_name, msg, err_stat )
     END SUBROUTINE load_cleanup

  END FUNCTION crtm_irwatercoeff_load


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_IRwaterCoeff_Destroy
!
! PURPOSE:
!       Function to deallocate the public data structure IRwaterC containing
!       the CRTM infrared water surface emissivity data.
!
! CALLING SEQUENCE:
!       Error_Status = CRTM_IRwaterCoeff_Destroy( Process_ID = Process_ID )
!
! OPTIONAL INPUTS:
!       Process_ID:       Set this argument to the MPI process ID that this
!                         function call is running under. This value is used
!                         solely for controlling message output. If MPI is not
!                         being used, ignore this argument.
!                         UNITS:      N/A
!                         TYPE:       INTEGER
!                         DIMENSION:  Scalar
!                         ATTRIBUTES: INTENT(IN), OPTIONAL
!
! FUNCTION RESULT:
!       Error_Status:     The return value is an integer defining the error
!                         status. The error codes are defined in the
!                         Message_Handler module.
!                         If == SUCCESS the deallocation of the public data
!                                       structure was successful
!                            == FAILURE an unrecoverable error occurred.
!                         UNITS:      N/A
!                         TYPE:       INTEGER
!                         DIMENSION:  Scalar
!
! SIDE EFFECTS:
!       This function modifies the contents of the public data
!       structure IRwaterC.
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_irwatercoeff_destroy( Process_ID ) RESULT( err_stat )
    ! Arguments
    INTEGER, OPTIONAL, INTENT(IN) :: process_id
    ! Function result
    INTEGER :: err_stat
    ! Local parameters
    CHARACTER(*), PARAMETER :: routine_name = 'CRTM_IRwaterCoeff_Destroy'
    ! Local variables
    CHARACTER(ML) :: msg, pid_msg

    ! Setup
    err_stat = success
    ! ...Create a process ID message tag for error messages
    IF ( PRESENT(process_id) ) THEN
      WRITE( pid_msg,'("; Process ID: ",i0)' ) process_id
    ELSE
      pid_msg = ''
    END IF

    ! Destroy the structure
    CALL irwatercoeff_destroy( irwaterc )
    IF ( irwatercoeff_associated( irwaterc ) ) THEN
      err_stat = failure
      msg = 'Error deallocating IRwaterCoeff shared data structure'//trim(pid_msg)
      CALL display_message( routine_name, msg, err_stat ); RETURN
    END IF

  END FUNCTION crtm_irwatercoeff_destroy


!------------------------------------------------------------------------------
!:sdoc+:
!
! NAME:
!       CRTM_IRwaterCoeff_IsLoaded
!
! PURPOSE:
!       Function to test if infrared water surface emissivity data has
!       been loaded into the public data structure IRwaterC.
!
! CALLING SEQUENCE:
!       status = CRTM_IRwaterCoeff_IsLoaded()
!
!:sdoc-:
!------------------------------------------------------------------------------

  FUNCTION crtm_irwatercoeff_isloaded() RESULT( IsLoaded )
    LOGICAL :: isloaded
    isloaded = irwatercoeff_associated( irwaterc )
  END FUNCTION crtm_irwatercoeff_isloaded

END MODULE crtm_irwatercoeff